7

如何在 Delphi 中模拟OnDestroy事件？TFrame

我在我的框架中添加了一个constructorand destructor，认为这就是TForm：

TframeEditCustomer = class(TFrame)
...
public
   constructor Create(AOwner: TComponent); override;
   destructor Destroy; override;
   ...
end;

constructor TframeEditCustomer.Create(AOwner: TComponent)
begin
    inherited Create(AOwner);

    //allocate stuff
end;

destructor TframeEditCustomer.Destroy;
begin
   //cleanup stuff

   inherited Destroy;
end;

这样做的问题是，当我的析构函数运行时，框架上的控件已被破坏并且不再有效。

原因在于包含表单的析构函数，它用于触发OnDestroy事件：

destructor TCustomForm.Destroy;
begin
   ...
   if OldCreateOrder then DoDestroy; //-->fires Form's OnDestroy event; while controls are still valid
   ...
   if HandleAllocated then DestroyWindowHandle; //-->destroys all controls on the form, and child frames
   ...
   inherited Destroy; //--> calls destructor of my frame
   ...
end;

当窗体的析构函数运行时，我的框架对象的析构函数被调用。问题在于为时已晚。窗体调用DestroyWindowHandle，它要求 Windows 销毁窗体的窗口句柄。这会递归地破坏所有子窗口 - 包括我框架上的那些。

因此，当我的框架destructor运行时，我尝试访问不再处于有效状态的控件。

如何在 Delphi 中模拟OnDestroy事件？TFrame

也可以看看

4

4 回答 4

11

您需要添加一个 WM_DESTROY 处理程序并检查 ComponentState 中的 csDestroying，以便它仅在实际销毁时被捕获，而不是在重新创建句柄时被捕获。

type
  TCpFrame = class(TFrame)
  private
    FOnDestroy: TNotifyEvent;
    procedure WMDestroy(var Msg: TWMDestroy); message WM_DESTROY;
  published
    property OnDestroy: TNotifyEvent read FOnDestroy write FOnDestroy;
  end;

procedure TCpFrame.WMDestroy(var Msg: TWMDestroy);
begin
  if (csDestroying in ComponentState) and Assigned(FOnDestroy) then
    FOnDestroy(Self);
  inherited; 
end;

只有在实际创建了框架的窗口句柄时，这才有效。没有另一个好的钩子点，所以如果你想确保它总是被调用，你需要在 WMDestroy 中设置一个标志，如果没有命中，则回退到在析构函数中调用它。

窗口句柄本身在 WM_NCDESTROY 中全部清除，在所有后代 WM_DESTROY 消息返回后调用，因此此时窗体及其所有子句柄应该仍然有效（忽略在窗体的 OnDestroy 中释放的任何句柄） .

于 2010-10-20T16:37:19.520 回答
1

听起来更像OnClose是OnDestroy。

无论如何，我只是从一个基本祖先继承了我所有的框架和表单，然后表单的 onclose 调用了组件层次结构中的所有框架。

于 2010-10-20T15:21:35.963 回答
0

（这只是一个想法，但我现在没有时间构建概念证明，但我会分享它：）

如果 Windows 句柄有问题，您应该检查是否能够附加 Windows 的事件回调指针，当框架的 Windows 句柄不再存在时，该指针会被调用。也许使用像RegisterWaitForSingleObject这样的函数

于 2010-10-20T16:33:28.043 回答
0

另一种选择是覆盖AfterConstruction和BeforeDestruction

像这样的东西：

  TMyFrame = class(TFrame)
  private
    FOnCreate: TNotifyEvent;
    FOnDestroy: TNotifyEvent;
  protected
    procedure DoCreate; virtual;
    procedure DoDestroy; virtual;
  public
    procedure AfterConstruction; override;
    procedure BeforeDestruction; override;
    property OnCreate: TNotifyEvent read FOnCreate write FOnCreate;
    property OnDestroy: TNotifyEvent read FOnDestroy write FOnDestroy;
  end;

  implementation

  procedure TMyFrame.AfterConstruction;
  begin
    inherited;
    DoCreate;
  end;

  procedure TMyFrame.BeforeDestruction;
  begin
    inherited;
    DoDestroy;
  end;

  procedure TMyFrame.DoCreate;
  begin
    if Assigned(FOnCreate) then
      FOnCreate(Self);
  end;

  procedure TMyFrame.DoDestroy;
  begin
    if Assigned(FOnDestroy) then
      FOnDestroy(Self);
  end;
于 2010-10-20T21:14:33.170 回答