1

我有一个尺寸为 1024*1024 的图像存储在 HDF5 文件中，该文件被视为切片厚度为 1 的数据立方体，（因此存储的尺寸为 1024*1024*1）。我使用 Niermann HDF5 插件 ( https://github.com/niermann/gms_plugin_hdf5 ) 导入数据。导入后数据立方体变为1*1024*1024，显示为1像素宽、1024像素高、1024个切片图像。

在考虑重新实现插件之前，我想问一下，有没有办法“重塑”数据（如“Numpy.reshape”中），以便可以正确处理维度？

谢谢！

4

3 回答 3

1

如果你不喜欢 icol、irow 和这些表达式，另一个优雅的解决方案是只使用流对象。

image ReShape3D( image input, number sx, number sy, number sz )
{
    // Perform testing
    number nPix=1
    for ( number d=0; d<input.ImageGetNumDimensions(); d++ )
        nPix *= input.ImageGetDimensionsize(d)

    if ( sx*sy*sz < nPix ) Throw( "Input image larger than provided shape." )
    if ( sx*sy*sz > nPix ) Throw( "Input image smaller than provided shape." )

    image reShaped := input.Imageclone()
    reShaped.ImageResize(3,sx,sy,sz)
    object dStream = NewStreamFromBuffer(0)
    ImageWriteImageDataToStream(input,dStream,0)
    dStream.StreamSetPos(0,0)
    ImageReadImageDataFromStream(reShaped,dStream,0)
    return reshaped
}

Image before := RealImage("Before",4,10,20,30)
before = random()
Image after := ReShape3D( before,20,10,30 )
before.ShowImage()
after.ShowImage()
于 2016-09-27T19:49:14.587 回答
1

如果您的输入/输出数组大小在维度上不匹配（这样slice不起作用），那么您还可以使用以下命令将数据“流式传输”进出 1D：

number sx = 4   
number sy = 5   
number sz = 2   

image oneLine := RealImage( "1D",4, sx*sy*sz )
oneLine = icol
oneLine.ShowImage()

image reShape1Dto3D := RealImage( "1D->3D", 4, sx, sy, sz )
reShape1Dto3D = oneLine[icol + iwidth*irow + iwidth*iheight*iplane, 0 ]
reShape1Dto3D.ShowImage()

image reShape3Dto1D := RealImage( "3D->1D", 4, sx*sy*sz )
reShape3Dto1D[icol + iwidth*irow + iwidth*iheight*iplane, 0 ] = reShape1Dto3D
reShape3Dto1D.ShowImage()

这里的技巧是，您可以使用方括号来处理图像表达式中的单个值。在 3D 图像中为 [X,Y,Z]，在 2D 图像中为 [X,Y]，在 1D 图像中为 [X,0]。[*]

内部变量icol, irow,iplane被计算表达式的 X,Y,Z 坐标替换，而 iwidth,iheight和idepth被计算表达式的维度大小替换。

评估表达式的大小是多少？它由该行中唯一的“已知大小”图像定义 - 左侧或右侧，因此

reShape1Dto3D = oneLine[ icol + iwidth*irow + iwidth*iheight*iplane, 0 ]

成为表达式左侧所有reShape1Dto3D像素的 X/Y/Z 上的循环。对于每个三元组 (X/Y/Z)，该值取自oneLine的计算位置。

完全相同的用于

reShape3Dto1D[ icol + iwidth*irow + iwidth*iheight*iplane, 0 ] = reShape1Dto3D

但是这里的循环再次超过了reShape1Dto3D的大小，因为那是行中“已知大小”的图像，即使它在右侧。

* 这种方式不支持更高的维度，因为 [T,L,B,R] 已经用于子区域。

于 2016-09-26T13:38:05.130 回答
0

在对“DM脚本手册”中的示例进行了几次尝试之后，找到了一种方法：

image out = in.slice2(0,0,0, 1,1024,1, 2,1024,1)

也就是说，xy 中的输出 2d 图像使用 Slice2() 命令对输入图像的 yz 平面进行投影。

于 2016-09-26T12:41:59.277 回答