0

我仍在学习如何在 gdb 中使用 python 调试 C（在我的例子中是 arm-none-eabi-gdb）。我正在尝试使用此工具来获取在 ARM Cortex-M 上运行的实时操作系统的线程信息。阅读一些操作系统结构，我可以访问操作系统的线程控制块。我知道每个线程的 PC 和 SP。如何使用 gdb 的 Python 转储线程的回溯。给定 PC 和 SP 时，是否有可以遍历堆栈的通用 API？

我已阅读https://sourceware.org/gdb/current/onlinedocs/gdb/Unwinding-Frames-in-Python.html#Unwinding-Frames-in-Python，我觉得可能有办法实现这一点，但我需要一些帮助。

另外，如果可能的话，我可以让 gdb 了解操作系统的不同线程吗？此链接： https ://sourceware.org/gdb/current/onlinedocs/gdb/Threads-In-Python.html#Threads-In-Python涉及线程但依赖于操作系统信息。这些是否会因我对各自控制块中不同操作系统线程的了解而过载？

谢谢！

4

2 回答 2

0

经过更多阅读并尝试利用我多年来积累的旧调试器知识，我设法让它工作。它缺乏优化，但现在，我很高兴。这可以被认为是一个穷人的调试器，它利用 GDB 的 Python 支持来跟踪系统中的活动线程。我认为它是通用的，但实现的目标是 RTX（Keil 的操作系统）。它适用于 Cortex-M0。它可能需要一些调整以适应其他操作系统或不同的内核。

主要思想：

  1. 使用 OS 结构来识别线程控制块所在的位置。
  2. 从线程控制块识别不同的线程堆栈在哪里。
  3. 从堆栈中读取所有重要的寄存器；SP、LR 和 PC
  4. 为当前正在运行的线程保存相同的寄存器。
  5. 循环不同的线程，将重要寄存器更改为与线程匹配的寄存器，然后打印回溯。
  6. 享受穷人的操作系统感知调试器。

该脚本可以在这里找到：

https://gitlab.com/hesham/gdb-rtx-thread-backtrce/blob/master/rtx-threads-bt.py

探索 GDB 的 Python 扩展的强大功能是一个很好的练习！

于 2016-09-29T22:19:36.477 回答
0

对于 FreeRTOS，我使用以下 gdb 脚本：

define printtasklist
  # $arg0 is a pointer to an uxList of tasks.
  set $plist = (List_t*)$arg0
  printf ": %d tasks\n", $plist->uxNumberOfItems
  set $iter = $plist->xListEnd.pxNext
  while ($iter != &$plist->xListEnd)
    set $vtask = ($iter->pvOwner)
    set $task = (tskTCB*)$vtask
    print $task
    print $task->pcTaskName
    set $iter = $iter->pxNext
  end
end

define printtasks
  printf "%d tasks:\n", uxCurrentNumberOfTasks
  printf "pending ready"
  printtasklist &xPendingReadyList
  printf "suspended"
  printtasklist &xSuspendedTaskList
  printf "delayedW"
  printtasklist pxDelayedTaskList
  printf "delayedO"
  printtasklist pxOverflowDelayedTaskList
  set $prio = 0
  set $maxprio = sizeof(pxReadyTasksLists) / sizeof(pxReadyTasksLists[0])
  while ($prio < $maxprio)
    printf " ready at prio"
    printf "%d", $prio
    printtasklist &pxReadyTasksLists[$prio]
    set $prio = $prio + 1  
  end
end

define savestate
  set $svpc = $pc
  set $svsp = $sp
  set $svlr = $lr
end

define restorestate
  set $pc = $svpc
  set $sp = $svsp
  set $lr = $svlr
end

define cm3bttask
       # arg0: task handle (pointer to tskTCB)
  savestate
  set $ptsk = (tskTCB*)$arg0
  set $tskstk = (uint32_t*)$ptsk->pxTopOfStack
  set $lr = $tskstk[13]
  set $pc = $tskstk[14]
  set $sp= $tskstk + 16
  bt
end

这个想法是我printtasks用来获取任务控制块的列表，然后cm3bttask $26如果我感兴趣的任务在 GDB 历史记录中具有打印为 $26 行的控制块指针，则使用它。我可以在 printtasks 的输出中看到这一点。

于 2018-06-19T08:44:40.413 回答