3

我们使用 Perl Moo。

让我们定义了一组属性：

package C;
use Moo;
use Types::Standard qw(Str Int Num Maybe);

has 'x' => (is=>'rw', isa=>Str);
has 'y' => (is=>'rw', isa=>Int);
has 'z' => (is=>'rw', isa=>Int);

# here to insert make_optional() described below

1;

我想编写一个例程，将某些属性的 T 替换为 Maybe[T] 。例如：make_optional(qw(x y))应该使 type ofx Maybe[Str]和 type of y Maybe[Int]。

Moo如何做到这一点？

4

2 回答 2

5

你不能。

Moo 没有元对象协议。没有它，您将无法返回并更改内容。

没有元对象。如果您需要这种复杂程度，您需要 Moose - Moo 很小，因为它明确不提供元协议。

此外，这些类型只是代码参考。

没有内置的类型系统。isa 使用 coderef 进行验证；如果您需要复杂的类型，Type::Tiny 可以提供类型、类型库，并且可以与 Moo 和 Moose 无缝协作。

你可以做的也许是写一个类型来访问其他地方的某种单例来决定它的行为是否像Maybe[Str]or Str，但这是一个很长的镜头，可能丑陋和疯狂，你不应该这样做。

于 2016-09-16T13:25:17.027 回答
2

[[请注意，该Maybe类型并没有真正使属性本身是可选的，而是不容忍的。默认情况下，Moo 属性已经是可选的。但为了便于讨论，我将继续使用可选与必需的术语。]]

因为我不喜欢“你不能”的答案，所以这里有一些代码可以满足你的需求......

use strict;
use warnings;

BEGIN {
    package MooX::MakeOptional;
    use Types::Standard qw( Maybe Any );
    use Exporter::Shiny our @EXPORT = qw( make_optional has );
    use namespace::clean;
    
    sub _exporter_validate_opts {
        my $opts = pop;
        $opts->{orig_has} = do {
            no strict 'refs';
            \&{ $opts->{into} . '::has' };
        };
        $opts->{attributes} = [];
        'namespace::clean'->clean_subroutines( $opts->{into}, 'has' );
    }
    
    sub _generate_has {
        my $opts = pop;
        
        my $attributes = $opts->{attributes};
        
        return sub {
            my ( $name, %spec ) = @_;
            if ( ref($name) eq 'ARRAY' ) {
                push @$attributes, $_, { %spec } for @$name;
            }
            else {
                push @$attributes, $name, \%spec;
            }
        };
    }
    
    sub _generate_make_optional {
        my $opts = pop;
        
        my $attributes = $opts->{attributes};
        my $orig_has   = $opts->{orig_has};
        
        return sub {
            my %optional;
            $optional{$_} = 1 for @_;
            
            while ( @$attributes ) {
                my ( $name, $spec ) = splice( @$attributes, 0, 2 );
                if ( $optional{$name} ) {
                    $spec->{isa} = Maybe[ $spec->{isa} or Any ];
                }
                $orig_has->( $name, %$spec );
            }
        }
    }
}

{
    package C;
    use Moo;
    use MooX::MakeOptional;
    use Types::Standard qw( Str Int );

    has 'x' => ( is => 'rw', isa => Str );
    has 'y' => ( is => 'rw', isa => Int );
    has 'z' => ( is => 'rw', isa => Int );

    make_optional( qw(x y) );
}

这样做是用一个虚拟替换替换 Moo 的has关键字，它除了将属性定义存储到一个数组中之外什么都不做。

然后当make_optional被调用时，它将遍历数组，并将每个属性定义传递给 Moo 的原始has关键字，但如果指定，则更改为可选。

use MooX::MakeOptional 总是需要确保在类定义的末尾调用函数make_optional的类，即使它们没有可选属性。如果他们没有可选属性，他们应该只调用make_optional并传递一个空列表。

于 2020-11-05T16:36:58.150 回答