2

我遇到了一个使用 call/cc 解释 Continuations 的片段。在下面提供的代码段中，由 call/cc 调用的 fn 的延续是整个 let 块，还是 call/cc 下面的行？也有人可以解释为什么不提供整个 let 块作为延续？

#lang racket
(define resume-test-3 #f)

(define test-3 (lambda ()
   ; the let defines a variable i local to the lambda, and 
   ; sets its value to 0
   (let ((i 0))
     ;
     (call/cc (lambda (k) (set! resume-test-3 k)))
     ;
     ; The next time the-continuation is called, we start here.
     (displayln "I am back ")
     (set! i (+ i 1))
     ; and return the value i
     i
     )
    ))

(test-3)
(resume-test-3)
(resume-test-3)
4

2 回答 2

2

表达式的继续call/cc由表达式之后的call/cc表达式组成。如果我们添加(displayln "Entering let")，我们可以看到调用延续不会导致打印“Entering let”。

#lang racket
(define resume-test-3 #f)

(define test-3 (lambda ()
   ; the let defines a variable i local to the lambda, and 
   ; sets its value to 0
   (let ((i 0))
     (displayln "Entering let")
     ;
     (call/cc (lambda (k) (set! resume-test-3 k)))
     ;
     ; The next time the-continuation is called, we start here.
     (displayln "I am back ")
     (set! i (+ i 1))
     ; and return the value i
     (displayln "Leaving let")
     i)))

(test-3)
(resume-test-3)
(resume-test-3)

输出：

Entering let
I am back 
Leaving let
1
I am back 
Leaving let
2
I am back 
Leaving let
3
于 2016-09-14T16:12:58.150 回答
2

实现将整个内容重写为继续传递样式（=CPS）：

(define resume-test-3-cps #f)
(define test-3-cps
  (lambda (k)
    ((lambda (kl i) ; this is the "let"
       ((lambda (tk1) (tk1 (set! resume-test-3-cps tk1)))
        (lambda (not-used)
          ((lambda (tk2) (tk2 (displayln "I am back ")))
           (lambda (not-used)
             ((lambda (tk3) (tk3 (set! i (+ i 1))))
              (lambda (not-used)
                ((lambda (tk4) (tk4 (displayln "Leaving let")))
                 (lambda (not-used)
                   ((lambda (tk5) (tk5 i))
                    kl))))))))))
     k 0))) ; variables to "let"

;; top level have barriers, don't know how to simulate them
;; doing full CPS here will make an infinite loop
(test-3-cps values)
(resume-test-3-cps values)
(resume-test-3-cps values)

请注意，即使不使用call/cc. 那是因为这call/cc只是一种无需在 CPS 中编写即可获得 CPS 功能的方法。当你知道它是如何工作的时候，就没有多少魔法了。

于 2016-09-14T17:25:25.790 回答