2

我在尝试解析 FParsec 中的类似 json 的同类数组时遇到问题。我已将问题分解为一个重现它的简短示例。

#r @"..\packages\FParsec.1.0.2\lib\net40-client\FParsecCS.dll"
#r @"..\packages\FParsec.1.0.2\lib\net40-client\FParsec.dll"

open System
open FParsec

let test p str =
        match run p str with
        | Success(result, _, _)   -> printfn "Success: %A" result
        | Failure(errormsg, _, _) -> printfn "Failure: %s" errormsg


type CValue = CInt of int64
            | CBool of bool
            | CList of CValue list

let P_WHITESPACE = spaces
let P_COMMA = pstring ","
let P_L_SBRACE = pstring "[" .>> P_WHITESPACE
let P_R_SBRACE = P_WHITESPACE >>. pstring "]"

let P_INT_VALUE = pint64 |>> CInt

let P_TRUE = stringReturn "true" (CBool true)
let P_FALSE = stringReturn "false" (CBool false)
let P_BOOL_VALUE = P_TRUE <|> P_FALSE


let P_LIST_VALUE =
    let commaDelimitedList ptype = sepBy (ptype .>> P_WHITESPACE) (P_COMMA .>> P_WHITESPACE)
    let delimitedList = (commaDelimitedList P_INT_VALUE) <|> (commaDelimitedList P_BOOL_VALUE)
    let enclosedList = between P_L_SBRACE P_R_SBRACE delimitedList
    enclosedList |>> CList

当我使用该test功能进行尝试时，我得到以下结果：

test P_LIST_VALUE "[1,2,3]"
Success: CList [CInt 1L; CInt 2L; CInt 3L]

test P_LIST_VALUE "[true,false]"
Failure: Error in Ln: 1 Col: 2
[true,false]
 ^
Expecting: integer number (64-bit, signed) or ']'

如果我在使用运算符时交换了顺序P_INT_VALUE，则解析成功但失败并出现类似错误。所以基本上，我首先使用的解析器就是它试图使用的。P_BOOL_VALUE<|>[true,false][1,2,3]

我知道<|>如果 LHS 改变用户状态，操作员不会尝试 RHS 解析器 - 但我看不出这是怎么发生的。P_BOOL_VALUE 和 P_INT_VALUE 没有任何共同的起始字符，因此在尝试解析错误的数据类型时两者都应该立即失败。整数从不以“假”或“真”开头，布尔从不以数字开头。

我究竟做错了什么？

4

1 回答 1

2

啊，我想通了。错误消息中的提示是or ']'. 问题是sepBy在空输入上成功，所以当它命中时t，它会成功返回一个空列表，然后控制权传回between尝试找到终止的].

解决方案是将空列表案例从特定于 int/bool 的解析器中移出，如下所示：

let P_LIST_VALUE =
    let commaDelimitedList ptype = sepBy1 (ptype .>> P_WHITESPACE) (P_COMMA .>> P_WHITESPACE)
    let delimitedList = (commaDelimitedList P_INT_VALUE) <|> (commaDelimitedList P_BOOL_VALUE) <|> preturn []
    let enclosedList = between P_L_SBRACE P_R_SBRACE delimitedList
    enclosedList |>> CList

请注意使用sepBy1代替sepBy，以及添加<|> preturn []以仅在 中处理一次空案例delimitedList。

作为旁注，我不知道您的确切应用程序，但在解析器中强制输入通常不是一个好主意；实现这一点的更常见方法是仅解析 a commaDelimitedList (P_INT_VALUE <|> P_BOOL_VALUE)（使用您的原始commaDelimitedList），然后在后续分析阶段检查输入。

于 2016-09-13T10:46:41.717 回答