haskell - 如何用 GHC.Generics 替换 Data.Generics？

Question

所以我用syb很久了，经常有这样的功能

friendlyNames :: Data a => a -> a
friendlyNames = everywhere (mkT (\(Name x _) -> Name x NameS))

假设 Generic a，使用 GHC.Generics 的等价物是什么？

Answer 1

这可能是使用 GHC.Generics 解决的错误问题，但现在你可以这样做了！

{-# Language TypeOperators #-}
{-# Language DeriveGeneric #-}
{-# Language DefaultSignatures #-}
{-# Language FlexibleContexts #-}
module Demo where

import GHC.Generics
import Language.Haskell.TH
import Language.Haskell.TH.Syntax

data Record = Record { field0 :: Int, field1 :: Maybe Record, field2 :: Name } deriving Generic

instance FriendlyNames Record -- body omitted and derived with GHC.Generics
instance FriendlyNames a => FriendlyNames (Maybe a)
instance FriendlyNames Int where friendlyNames = id -- no-op

------------------------------------------------------------------------

-- | Class for types that can be made friendly
class FriendlyNames a where
  friendlyNames :: a -> a
  default friendlyNames :: (GFriendlyNames (Rep a), Generic a) => a -> a
  friendlyNames = to . gfriendlyNames . from

-- | Replaces the second component of a name with 'NameS'
instance FriendlyNames Name where
  friendlyNames (Name x _) = Name x NameS

------------------------------------------------------------------------

-- | Class for generic structures that can have names made friendly
class GFriendlyNames f where
  gfriendlyNames :: f p -> f p

-- | Case for metadata (type constructor, data constructor, field selector)
instance GFriendlyNames f => GFriendlyNames (M1 i c f) where
  gfriendlyNames (M1 x) = M1 (gfriendlyNames x)

-- | Case for product types
instance (GFriendlyNames f, GFriendlyNames g) => GFriendlyNames (f :*: g) where
  gfriendlyNames (x :*: y) = gfriendlyNames x :*: gfriendlyNames y

-- | Case for sum types
instance (GFriendlyNames f, GFriendlyNames g) => GFriendlyNames (f :+: g) where
  gfriendlyNames (L1 x) = L1 (gfriendlyNames x)
  gfriendlyNames (R1 y) = R1 (gfriendlyNames y)

-- | Case for datatypes without any data constructors (why not?)
instance GFriendlyNames V1 where
  gfriendlyNames v1 = v1 `seq` error "gfriendlyNames.V1"

-- | Case for datatypes without any fields
instance GFriendlyNames U1 where
  gfriendlyNames U1 = U1

-- | Case for data constructor fields
instance FriendlyNames a => GFriendlyNames (K1 i a) where
  gfriendlyNames (K1 x) = K1 (friendlyNames x)

GHC.Generics 方法更适合这种复杂性可以编写一次并隐藏在库中的情况。虽然 SYB 方法依赖于运行时检查，但请观察为友好名称生成的 GHC 核心，它使记录值变得友好

-- RHS size: {terms: 14, types: 18, coercions: 0}
recordFriendlyNames
recordFriendlyNames =
  \ w_s63w ->
    case w_s63w of _ { Record ww1_s63z ww2_s63A ww3_s63B ->
    case $recordFriendlyNames ww1_s63z ww2_s63A ww3_s63B
    of _ { (# ww5_s63H, ww6_s63I, ww7_s63J #) ->
    Record ww5_s63H ww6_s63I ww7_s63J
    }
    }

-- RHS size: {terms: 19, types: 19, coercions: 0}
$recordFriendlyNames
$recordFriendlyNames =
  \ ww_s63z ww1_s63A ww2_s63B ->
    (# ww_s63z,
       case ww1_s63A of _ {
         Nothing -> Nothing;
         Just g1_a601 -> Just (recordFriendlyNames g1_a601)
       },
       case ww2_s63B of _ { Name x_a3Z3 ds_d5Z5 -> Name x_a3Z3 NameS } #)

Answer 2

好吧，我终于对这个问题有了满意的答案。它的内容取自上面glguy的答案，但我将添加一些包装和解释来帮助我连接这些点。我还将使其更通用，以便与Data.Data.

该函数将对参数值中某种类型的everywhere每次出现应用一个函数，该参数值表示为 type 。该实例用于确定递归期间的时间。请注意，因为是类的方法并且提供了默认实例，所以它将接受任何满足类约束的类型TypeablebaTypeablea ~ beverywhereEverywhere

{-# LANGUAGE UndecidableInstances #-}

import Data.Typeable (cast, Typeable)
import GHC.Generics
import Data.Ratio (Ratio)
import Data.Word (Word8)

class (Typeable b, Typeable a) => Everywhere b a where
  everywhere :: (b -> b) -> a -> a

这是 的基本实例Everywhere，它可以应用于满足其约束的任何类型，特别GEverywhere是下面为 的任何实例定义的类型Generic。这OVERLAPPABLE让我们可以为其他类型提供实例，这些类型不是Generic.

instance {-# OVERLAPPABLE #-} (Typeable b, Typeable a, Generic a, GEverywhere b (Rep a))
  => Everywhere b a where
  everywhere f = to . geverywhere f . from

现在我们编写一个GEverywhere包含覆盖类型表示的实例的类。最终，这段代码的工作是递归这个值内的字段值。

class GEverywhere b f where
  geverywhere :: (b -> b) -> f p -> f p
instance GEverywhere b f => GEverywhere b (M1 i c f) where
  geverywhere f (M1 x) = M1 (geverywhere f x)
instance (GEverywhere b f, GEverywhere b g) => GEverywhere b (f :*: g) where
  geverywhere f (x :*: y) = geverywhere f x :*: geverywhere f y
instance (GEverywhere b f, GEverywhere b g) => GEverywhere b (f :+: g) where
  geverywhere f (L1 x) = L1 (geverywhere f x)
  geverywhere f (R1 y) = R1 (geverywhere f y)
instance GEverywhere b V1 where geverywhere _ v1 =
  v1 `seq` error "geverywhere.V1"
instance GEverywhere b U1 where geverywhere _ U1 = U1

最后一个实例是遇到子类型的地方。cast我们使用以下函数检查它是否是我们正在寻找的类型Data.Typeable：

instance Everywhere b a => GEverywhere b (K1 i a) where
  geverywhere f (K1 x) =
    case cast x :: Maybe b of
      Nothing -> K1 (everywhere f x)
      Just x' -> case cast (f x') :: Maybe a of
                   -- This should never happen - we got here because a ~ b
                   Nothing -> K1 (everywhere f x)
                   Just x'' -> K1 x''

最后，在我们感兴趣的类型中可能存在没有通用实例的原始类型。

instance (Typeable b, Typeable a) => Everywhere b (Ratio a) where everywhere _ r = r
instance (Typeable b) => Everywhere b Char where everywhere _ r = r
instance (Typeable b) => Everywhere b Integer where everywhere _ r = r
instance (Typeable b) => Everywhere b Word8 where everywhere _ r = r
instance (Typeable b) => Everywhere b Int where everywhere _ r = r

就是这样，现在我们可以使用任何地方进行泛型修改：

λ> everywhere (succ :: Char -> Char) ("abc", 123)
("bcd",123)
λ> everywhere @Int succ ("abc", 123 :: Int)
("abc",124)