7

我有一个带有 CHM 帮助文件的 Delphi 2006 应用程序。一切正常，除了我无法获得连接到 TOpenDialog 和 TSaveDialog 上的“帮助”按钮的任何帮助。

下面显示了一个简单的程序来演示这一点。单击按钮 2 打开帮助文件并显示正确的页面。单击按钮 1 打开对话框，但单击对话框中的帮助按钮无效。

unit Unit22;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls,
  HTMLHelpViewer ;

type
  TForm22 = class(TForm)
    OpenDialog1: TOpenDialog;
    Button1: TButton;
    Button2: TButton;
    procedure Button1Click(Sender: TObject);
    procedure FormCreate(Sender: TObject);
    procedure Button2Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form22: TForm22;

implementation

{$R *.dfm}

procedure TForm22.Button1Click(Sender: TObject);
begin
OpenDialog1.HelpContext := 10410 ;
OpenDialog1.Execute ;
end;

procedure TForm22.Button2Click(Sender: TObject);
begin
Application.HelpContext  (10410) ;
end;

procedure TForm22.FormCreate(Sender: TObject);
begin
Application.HelpFile := 'c:\help.chm' ;
end;

end.
4

1 回答 1

13

使用默认设置 TOpenDialog 的帮助消息处理不起作用（您应该将其提交到 Quality Central）。

具体原因是因为 Windows 将帮助消息发送给对话框的父级，而不是对话框本身，所以除非您的表单设置为处理它，否则它只会被忽略。

解决方法是将Application.ModalPopupMode设置为 pmAuto 而不是默认的 pmNone。您可以在正常启动代码期间或在显示对话框之前执行一次。设置好之后，Delphi 会创建一个中间窗口 (Dialogs.pas::TRedirectorWindow) 来正确处理消息。

如果由于某种原因您无法更改 ModalPopupMode 那么，正如我所说，您需要处理表单上的消息：

TForm22 = class(TForm)
...
  procedure WndProc(var Message: TMessage); override;
end;

initialization

var
  HelpMsg: Cardinal;

procedure TForm22.WndProc(var Message: TMessage);
begin
  inherited;
  if (Message.Msg = HelpMsg) and (OpenDialog1.Handle <> 0) then
    Application.HelpContext(OpenDialog1.HelpContext);
end;

initialization
  HelpMsg := RegisterWindowMessage(HelpMsgString);
end.
于 2010-10-15T02:41:28.650 回答