1

为了理解 Genie 中的类继承，我创建了两个类（Kitten 和 Puppy），它们应该从 Pet 类继承属性。目的是让 minou 喵喵叫和 duke 吠叫，但是 _name 似乎超出了子类的范围。如何将此属性传递给子类？

这是代码：

[indent=4]

// Experimenting with classes in Genie

class Pet

    _name:string

    construct ( name:string? )

        _name = name

class Kitten : Pet

    def meow()
        print self._name + " meowed!"

class Puppy : Pet

    def bark()
        print self._name + " barked!"

init
    var minou = new Kitten("Minou")
    var duke = new Puppy("Duke")

    minou.meow()
    duke.bark()

错误信息是：

Test78.gs:16.15-16.24: error: Access to private member `Pet._name' denied
        print self._name + " meowed!"
4

2 回答 2

2

互联网上有很多关于继承的教程，它们经常使用动物或车辆的一部分创建复杂的层次结构。从概念上讲，这些继承层次结构是严格的，这就是为什么在构造函数中传递协作对象（优先于继承而不是组合）和针对接口（多态性）检查协作者的类型通常更好的原因。这会创建解耦对象，并为您的程序提供更大的灵活性、可维护性和可测试性。所以学习继承，还要从批判的角度来做。

Genie 确实支持子类型和继承。您的程序遇到两个问题。第一个是作用域，第二个是在构造函数链上传递参数。

首先是范围问题。Genie 中的下划线表示类成员是私有的。它只能由该类的实例访问。要允许从子类型计算机语言访问它，请使用protected访问修饰符。这在 Genie 解析器中当前没有实现。请参阅错误 690848 - 添加对“受保护”类成员的支持。所以我们必须name公开这个领域。这允许从子类型访问它，也可以从程序的实例Pet在范围内的任何部分访问它。在 Genie 中，我们只需删除下划线即可将其公开。

一旦你的范围工作，你会得到一个错误“无法链接到需要参数的基本构造函数”。您将需要为您的子类型添加构造函数，并且这些构造函数需要设置name字段。这可以直接完成，例如name = pet_name，或者通过使用正确的参数调用超类型的构造函数，例如super( pet_name )。显示两种方式的工作示例如下：

[indent=4]
init
    var minou = new Kitten( "Minou" )
    var duke = new Puppy( "Duke" )
    minou.meow()
    duke.bark()


class Pet
    name:string

    construct( pet_name:string = "Anonymous" )
        name = pet_name


class Kitten:Pet
    construct( pet_name:string = "Anonymous" )
        name = pet_name

    def meow()
        print name + " meowed!"


class Puppy:Pet
    construct( pet_name:string = "Anonymous" )
        super( pet_name )

    def bark()
        print name + " barked!"
于 2016-09-04T12:08:26.707 回答
1 
[indent=4]

class Pet

    prop  name:string

class Kitten : Pet

    def meow(name : string)
        print self.name + " meowed!"

class Puppy : Pet

    def bark(name : string)
        print self.name + " barked!"

init
    var minou = new Kitten()
    var duke = new Puppy()

    minou.meow(minou.name="Minou")
    duke.bark(duke.name="Duke")
于 2016-12-27T11:53:26.760 回答