1

我在 Windows 10 中使用柏林。我尝试保存tList<string>到文件。

我知道如何处理 tStringlist、tStreamWriter 和 tStreamReader，但我需要使用 tFileStream，因为应该添加其他类型的数据。

在以下代码中，读取数据的 Button2Click 循环引发了 eOutOfMemory 异常。当我将简单的字符串值分配给 _String 时，它运行良好，但如果我将 tList 值分配给相同的 _String ，似乎文件中写入了错误的数据。我无法理解 和 之间的_String := _List.List[i]区别_String := 'qwert'。

我如何写信tList<string>给 tFileSteam？

procedure TForm1.Button1Click(Sender: TObject);
var
  _List: TList<string>;
  _FileStream: TFileStream;
  _String: string;
  i: Integer;
begin
  _List := TList<string>.Create;

  _List.Add('abcde');
  _List.Add('abcde12345');

  _FileStream := TFileStream.Create('test', fmCreate);

  for i := 0 to 1 do
  begin
    _String := _List.List[i]; // _String := 'qwert' works well

    _FileStream.Write(_string, 4);
  end;

  _FileStream.Free;
  _List.Free;
end;

procedure TForm1.Button2Click(Sender: TObject);
var
  _FileStream: TFileStream;
  _String: string;
  i: Integer;
begin
  _FileStream := TFileStream.Create('test', fmOpenRead);

  for i := 0 to 1 do
  begin
    _FileStream.Read(_String, 4);

    Memo1.Lines.Add(_String);
  end;

  _FileStream.Free;
end;
4

1 回答 1

3

如果您在文档中查找是做什么TFileStream.Write的，它会告诉您（继承自THandleStream.Write）：

function Write(const Buffer; Count: Longint): Longint; override;
function Write(const Buffer: TBytes; Offset, Count: Longint): Longint; override;

将 Count 个字节从 Buffer 写入资源中的当前位置。

现在，Buffer是无类型的，因此预计是要写入的数据的内存地址。您正在传递一个字符串变量，它是对实际字符串数据的引用，变量的地址包含一个指向字符串数据的指针。因此，您正在编写指向该文件的指针。

要更正它传递缓冲区的字符串第一个字符，....write(_string[1], ... 如果您有编译器指令 {$ZEROBASEDSTRINGS ON} 您将使用索引 0。或者，将字符串类型转换为PChar并取消引用它：....write(PChar(_String)^, ...

然后看第二个参数，Count。正如文档所说，它表示要写入的字节数，特别是字符数。在 Delphi 2009 及更高版本中，字符串为UnicodeString，因此每个字符为 2 个字节。您需要以字节为单位传递字符串大小。

这会将 4 个字符（8 个字节）写入文件流：

_FileStream.Write(_String[1], 4 * SizeOf(Char));

或更好

_FileStream.Write(PChar(_String)^, 4 * SizeOf(Char));

对于阅读，您需要进行相应的更改，但最值得注意的是，您需要在阅读之前设置字符串长度（长度以字符计）。

  SetLength(_String, 4);
  for i := 0 to 1 do
  begin
    _FileStream.Read(_String[1], 4 * SizeOf(Char));

    Memo1.Lines.Add(_String);
  end;

要继续使用这种低级方法，您可以按如下方式概括字符串的写入和读取：添加一个变量来保存字符串的长度

var
  _String: string;
  _Length: integer;

然后写

begin
  ...
  for ....
  begin
    _String := _List.List[i];
    _Length := Length(_String);
    _FileStream.Write(_Length, SizeOf(Integer));
    _FileStream.Write(PChar(_List.List[i])^, _Length * SizeOf(Char));
  end;

和阅读

begin
  ...
  for ....
  begin
    _FileStream.Read(_Length, SizeOf(Integer));
    SetLength(_String, _Length);
    _FileStream.Read(_String[1], _Length * SizeOf(Char));
    Memo1.Lines.Add(_String);
  end;

IOW，你先写长度，然后写字符串。在阅读时，您先阅读长度，然后再阅读字符串。

于 2016-08-27T18:27:16.933 回答