2

显然我之前的问题太宽泛了。所以这里又是一个简化的问题，并带有示例源代码。

我正在尝试编译一个包含多个文件的 Chicken Scheme 项目：

测试-a.scm：

#!/usr/bin/csi -script

(declare (unit test-a))
(declare (uses test-b))

(load "test-b.scm")
(use test-b)

(test-syntax)

测试-b.scm：

(declare (unit test-b))

(module test-b *
 (import scheme chicken)
 (define-syntax test-syntax
  (syntax-rules ()
   ((_)
    (print "In test-syntax")))))

根据官方手册，我应该这样做：

csc -c test-b.scm
csc -c test-a.scm
csc test-a.o test-b.o -o test

我实际得到的是：

语法错误（导入）：无法从未定义的模块导入

注意事项：

  • 我正在调用一个宏。
  • 我有一个(declare (uses条款，但 csc 找不到我的来源。
  • csc test-a.scm test-b.o -o test也不行。
  • 如果我删除load，该程序将无法在 csi 中运行。
  • 如果我删除use，该程序将无法在 csi 中运行。
  • 我需要该程序在 csi 中工作。

如何在不破坏与 csi的兼容性的情况下进行编译？

4

1 回答 1

2

这里有四个（！）问题：

  • test-a.scm包含一个单元声明。这是不正确的；总有一个文件需要编译才能具有main()C 函数。那是没有单元声明的文件。如果您更仔细地研究您链接的手册页，它会说“在这种情况下foo.scm是主模块，因为它没有单元声明”。
  • 由于您决定使用模块，因此您需要编译test-b.scm如下：csc -c -j test-b test-b.scm. 该-j开关将导致编译器发出一个模块库test-b.import.scm，这是编译器在编译时要寻找的test-a.scm。当缺少导入库时，它会抱怨模块未定义。在解释器中这没有问题，因为您load在导入它定义的模块之前的文件。
  • 您正在使用load，即使在程序的编译版本中也是如此。这意味着它会test-b.scm在任何情况下读取和评估文件（如果丢失则抱怨）。
  • 您正在使用use，它将在运行时需要该库。这意味着加载和导入由动态链接库定义的模块。

所以，要解决这个问题，你可以这样做：

测试a.scm

#!/usr/bin/csi -script

;; Declare that this uses test-b, so that its toplevel is initialised
(declare (uses test-b))
;; No (declare (unit test-a)) because this file should generate main().

;; Because we tell the compiler what to link together and we want to
;; avoid passing all the .scm files on the csi command line, we can load
;; the test-b.scm file here, but only when interpreting:
(cond-expand
  ((not compiling) (load "test-b.scm"))
  (else))

;; Only import the module; we take care of loading the code above,
;; or in the linking step when compiling.  If we had (use test-b),
;; the library would be searched for at runtime.
;; Alternatively, (use test-b) here, but add (register-feature! 'test-b)
;; to test-b.scm, which prevents the runtime from attempting to load test-b.
(import test-b)

(test-syntax)

test-b.scm （不变）

(declare (unit test-b))

(module test-b *
 (import scheme chicken)
 (define-syntax test-syntax
  (syntax-rules ()
   ((_)
    (print "In test-syntax")))))

并且，要编译它：

csc -c -j test-b test-b.scm
csc -c test-a.scm
csc test-a.o test-b.o -o test

我意识到这是很多东西要知道，而且也很棘手，而且像use加号这样的东西register-feature!根本没有多大意义。我们试图在 CHICKEN 5 中让这变得不那么繁琐，而且我们还将在 wiki 中添加一个常见问题解答，因为这真的不明显而且有点常见问题解答。

您链接的手册页很长时间没有更改：例如，它完全忽略了模块的存在。这就是为什么您无法编译它，-j因为手册页中的示例文件没有定义模块，所以缺少开关。

编辑：

这可以稍微清理一下，因为declare无论如何只有编译器才会尊重。所以我们也可以把它移到cond-expand：

测试a.scm

#!/usr/bin/csi -script
(cond-expand
  (compiling (declare (uses test-b)))
  (else (load "test-b.scm")))

(import test-b)

(test-syntax)
于 2016-08-17T07:13:58.530 回答