2

我是 SparkQL 和 wikidata 的新手，我正在尝试查询以下内容：

  • 男歌手（艺人/表演者）
  • 谁还活着
  • 名字 = 6 个字符
  • 给定名称不包含 ("e","i","u")

我在使用给定名称的过滤器时遇到问题（我相信这是因为它们引用了“SERVICE wikibase:label”）。我试过使用 HAVING 无济于事。嵌套查询和过滤器的正确操作是正确的，还是有更优雅的方法？

#-- Male artists
SELECT DISTINCT ?m ?givennameLabel (STRLEN(?givennameLabel)AS ?Namechars)
 ?mLabel ?plLabel WHERE {
 ?m wdt:P31 wd:Q5.
 ?m wdt:P21 wd:Q6581097.
 ?m wdt:P735 ?givenname.
 ?m wdt:P27 ?pl.
 ?m (wdt:P106/wdt:P279*) wd:Q483501.
 OPTIONAL { ?m wdt:P175 ?performer. }
 OPTIONAL {?m wdt:P570 ?d } 
 FILTER (!bound(?d))
 SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
FILTER (!regex(?givennameLabel,"(e|i|u)")). #no records
FILTER (STRLEN(?givennameLabel) = 6)        #no records
} #HAVING (!regex(?givennameLabel,"(e|i|u)")) #returns "Bad aggregate"
LIMIT 50

试试看！

我认为这样的事情应该有效，尽管它没有成功。

BIND(STRLEN(str(?givennameLabel)) as ?NL)
FILTER (?NL = 6)
4

1 回答 1

3

好的，我认为找到了问题：看起来您调用了一些“魔术”服务，它创建了一些变量givennameLabel。对我来说听起来很奇怪，但这可能导致变量不受过滤时间的限制。如果将整个查询放在子选择中，它可以工作：

#Male artists
SELECT * WHERE {

     {
     SELECT DISTINCT ?m ?givennameLabel (STRLEN(?givennameLabel)AS ?Namechars)
       ?mLabel ?plLabel WHERE {
       ?m wdt:P31 wd:Q5.
       ?m wdt:P21 wd:Q6581097.
       ?m wdt:P735 ?givenname.
       ?m wdt:P27 ?pl.
       ?m (wdt:P106/wdt:P279*) wd:Q483501.
       OPTIONAL { ?m wdt:P175 ?performer. }
       OPTIONAL {?m wdt:P570 ?d } 
       FILTER (!bound(?d))
       SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
    } 
    LIMIT 50
    }
  FILTER (!regex(?givennameLabel,"(e|i|u)")).
  FILTER (STRLEN(?givennameLabel) = 6)       
}

更新

建议的查询只考虑 50 个资源，没有 LIMIT 会导致超时。如 user3240704 所述，另一种解决方案是避免使用该SERVICE子句并rdfs:label改用：

#Male artists
 SELECT DISTINCT ?m ?givennameLabel (STRLEN(?givennameLabel)AS ?Namechars) 
                 ?mLabel ?plLabel 
 WHERE {
   ?m wdt:P31 wd:Q5.
   ?m wdt:P21 wd:Q6581097.
   ?m wdt:P735 ?givenname.
   ?m wdt:P27 ?pl.
   ?m (wdt:P106/wdt:P279*) wd:Q483501.
   OPTIONAL { ?m wdt:P175 ?performer. }
   OPTIONAL {?m wdt:P570 ?d } 
   FILTER (!bound(?d))
   ?givenname rdfs:label ?label 
   FILTER(LANG(?label) ="en"). 
   FILTER (!regex(?label,"(e|i|u)")). 
   FILTER (STRLEN(?label) = 6)}
} 
LIMIT 50
于 2016-08-08T02:40:06.873 回答