d - D 编程语言中的“收益回报”等价物是什么？

Question

这是一个简单的 C# 生成器。

    IEnumerable<int> Foo()
    {
        int a = 1, b = 1;
        while(true)
        {
            yield return b;
            int temp = a + b;
            a = b;
            b = temp;
        }
    }

如何在Digital Mars D 中编写类似的生成器？

（问题是关于产量回报声明）

谢谢！

---

更新。那很有意思。由于我只是在生成一个数学序列，因此使用递归可能是一个不错的选择。

auto fib = recurrence!("a[n-1] + a[n-2]")(1, 1);

foreach (e; take(fib, 10)) // <- prints first ten numbers from the sequence
{ 
    writeln(e); 
}

Answer 1

D 中没有精确的等价物。以下是一些粗略的等价物：

使用 opApply 风格的内部迭代。但是，这不允许以锁步方式迭代两个迭代器：

struct Foo {
    int opApply(int delegate(ref int) dg) {
        int a = 1, b = 1;
        int result;
        while(true) {
            result = dg(b);
            if(result) break;
            int temp = a + b;
            a = b;
            b = temp;
        }

        return result;
    }
}

void main() {
    // Show usage:
    Foo foo;
    foreach(elem; foo) {
        // Do stuff.
    }
}

使用范围。在某些情况下，它们稍微难以编写，但非常有效并且允许锁步迭代。这也可以通过foreach循环进行迭代，就像opApply版本一样：

struct Foo {
    int a = 1, b = 1;

    int front() @property {
        return b;
    }

    void popFront() {
        int temp = a + b;
        a = b;
        b = temp;
    }

    // This range is infinite, i.e. never empty.
    enum bool empty = false;

    typeof(this) save() @property { return this; }
}

如果您真的需要协程风格的东西，您可以使用 将 range 和 opApply 组合在一起core.thread.Fiber，但您可能会发现 range 或 opApply 几乎一直都能满足您的需求。

Answer 2

见这里；下面的示例摘录：

module main;

import std.stdio;
import generators;

void genSquares(out int result, int from, int to)
{
    foreach (x; from .. to + 1)
        yield!result(x * x);
}

void main(string[] argv)
{
    foreach (sqr; generator(&genSquares, 10, 20))
        writeln(sqr);
}

Answer 3

该std.concurrency模块现在有一个Generator类，使这变得更加容易（并且您不需要第三方库）。

该类是一个输入范围，因此它可以与 for 循环和所有标准std.range/std.algorithm函数一起使用。

import std.stdio;
import std.range;
import std.algorithm;
import std.concurrency : Generator, yield;

void main(string[] args) {
    auto gen = new Generator!int({
        foreach(i; 1..10)
            yield(i);
    });

    gen
        .map!(x => x*2)
        .each!writeln
    ;
}