偶尔我想在其他软件的repl中戳一个结果。有没有一种方便的方法可以将 repl 中运行的函数的结果复制到系统剪贴板？我知道我可以spit将结果保存到文件中。我正在使用 mac os x。
问问题
474 次
1 回答
8
您始终可以重新绑定*out*特殊变量，以指向新位置。例如，您可以将所有输出收集到字符串：
user> (def result (java.io.StringWriter.))
#'user/result
user> (binding [*out* result]
(println :aaa)
(println :bbb))
nil
user> (str result)
":aaa\n:bbb\n"
这是一个临时绑定，beaning*out*在块外是完整的binding：
user> (println :aaa)
:aaa
nil
您也可以使用以下方法在线程级别重置输出set!：
user> (def result (java.io.StringWriter.))
#'user/result
user> (set! *out* result)
#object[java.io.StringWriter 0x66c129d9 ""]
user> (println :aaa)
nil
user> (println :bbb)
nil
user> (str result)
":aaa\n:bbb\n"
然后，您可以使用 java.awt 类将此字符串放入剪贴板：
user> (import 'java.awt.Toolkit)
java.awt.Toolkit
user> (import 'java.awt.datatransfer.StringSelection)
java.awt.datatransfer.StringSelection
user> (.. Toolkit
(getDefaultToolkit)
(getSystemClipboard)
(setContents (StringSelection. (str result)) nil))
nil
而已。现在只需粘贴它。应该在mac上正常工作。
然后你可以用一个宏来概括它：
(defmacro with-clipboard [& body]
`(binding [*out* (java.io.StringWriter.)]
(let [result# (do ~@body)]
(.. Toolkit
(getDefaultToolkit)
(getSystemClipboard)
(setContents (StringSelection. (str *out*)) nil))
result#)))
并像这样使用它：
user> (with-clipboard
(println :hello)
(println :clipboard)
(+ 10 20))
;; => 30
剪贴板将包含：
:hello
:clipboard
于 2016-07-20T16:59:10.517 回答