1

我有一张地图清单

 ( {:path "first" :size "1 gb"}  
   {:path "second" :size "500 mb"}
  ...)

和另一个地图列表

 ( {:path "first" :size "1 gb" :date "1"}
   {:path "second" :size "500 mb" :date "1"}
   {:path "first" :size "0.9 gb" :date "2"}...
   {:path "second" :size "400 mb" :date "2"}...
 ...)

我想将第一个地图列表转换为类似

( {:path "first" :sizeon1 "1 gb" :sizeon2 "0.9 gb"...}
  {:path "second" :sizeon1 "500 mb" :sizeon2 "400 mb"...}
  ....)

我是 Clojure 菜鸟，很难做到这一点。你能帮帮我吗？

4

3 回答 3

2

当您将任务分解为更小的部分时，一切都会变得清晰。

首先，定义一个助手来:sizeon1在结果数据集中创建这些键：

(defn date-key
  [date]
  (keyword (str "sizeon" date)))

接下来，您希望将单个路径数据的集合减少到聚合地图中，假设这样的集合看起来如您所描述的：

[{:path "first" :size "1 gb" :date "1"}
 {:path "first" :size "0.9 gb" :date "2"}
 ;; ...
 ]

reduce只是工具：

(defn reduce-path
  [path-data]
  (reduce
    ;; A function that takes an accumulator map and an element in the collection
    ;; from which you take date and size and assoc them under the appropriate keys
    (fn [acc el]
      (let [{:keys [date size]} el]
        (assoc acc (date-key date) size)))
    ;; A starting value for the accumulator containing the common path
    ;; for this collection
    {:path (:path (first path-data))}
    ;; The collection of single path data to reduce
    path-data))

最后，获取包含不同路径的原始数据集，按路径对其进行分区，并将reduce-path函数映射到其上。

(def data
  [{:path "first" :size "1 gb" :date "1"}
   {:path "first" :size "0.9 gb" :date "2"}
   {:path "second" :size "500 mb" :date "1"}
   {:path "second" :size "400 mb" :date "2"}])

(->> data
     (partition-by :path)
     (map reduce-path))

请注意，此代码假定您的初始data集合已按 排序:path。否则，partition-by将无法按预期工作，并且必须相应地准备数据。

于 2016-07-20T08:15:13.333 回答
2 
(def data '({:path "first" :size "1 gb" :date "1"}
            {:path "second" :size "500 mb" :date "1"}
            {:path "first" :size "0.9 gb" :date "2"}
            {:path "second" :size "400 mb" :date "2"}))

(defn- reduce-group [g]
  (reduce (fn [acc m] (assoc acc
                             (keyword (str "sizeon" (:date m)))
                             (:size m)))
          (first g) g))

(let [groups (group-by :path data)]
  (map reduce-group (vals groups)))
于 2016-07-20T08:27:50.810 回答
2

我会做什么，是重新考虑生成的数据结构：我不知道您将如何使用生成的集合，但命名键:sizeonX，特别是当注册日期的数量可能可变或者其中一些可能丢失时（例如，如果您有日期1和3第一个路径，而1 2 3 5第二个路径）会导致结果映射中出现一堆不可预测的命名键，这会使检索这些键变得更加困难。在我看来，使用这种结构会更好：

{:path "first" :sizes {"1" "500" "2" "1g" "10" "222"}}

所以这个尺寸图很容易迭代和处理。

这就是我将如何做到的：

(def data '({:path "first" :size "1 gb" :date "1"}
            {:path "first" :size "0.9 gb" :date "3"}
            {:path "second" :size "500 mb" :date "1"}
            {:path "second" :size "700 mb" :date "2"}
            {:path "second" :size "400 mb" :date "3"}
            {:path "second" :size "900 mb" :date "5"}))

(map (fn [[k v]] {:path k
                  :sizes (into {} (map (juxt :date :size) v))})
     (group-by :path data))

;; ({:path "first", :sizes {"1" "1 gb", "3" "0.9 gb"}} 
;;  {:path "second", :sizes {"1" "500 mb", 
;;                           "2" "700 mb", 
;;                           "3" "400 mb", 
;;                           "5" "900 mb"}})

更新

但由于您仍然需要问题的结构，我会这样做：

(map (fn [[k v]]
       (into {:path k}
             (map #(vector (keyword (str "sizeon" (:date %)))
                           (:size %))
              v)))
     (group-by :path data))

;;({:path "first", :sizeon1 "1 gb", :sizeon3 "0.9 gb"} 
;; {:path "second", 
;;  :sizeon1 "500 mb", :sizeon2 "700 mb", 
;;  :sizeon3 "400 mb", :sizeon5 "900 mb"})

这基本上类似于@superkonduktr 变体。

于 2016-07-20T11:13:24.083 回答