1

我在业余时间学习汇编，因为我对低级操作感兴趣。 我尝试运行本教程中的代码。

代码可以在这里和下面找到：

/******************************************************************************
* @file float.s
* @brief simple example of scalar multiplication using the FPU
*
* Simple example of using the ARM FPU to compute the multiplication result of
* two float values
*
* @author Christopher D. McMurrough
******************************************************************************/

    .global main
    .func main

main:

    LDR R0, =val1           @ load variable address
    VLDR S0, [R0]           @ load the value into the VFP register

    LDR R0, =val2           @ load variable address
    VLDR S1, [R0]           @ load the value into the VFP register

    VMUL.F32 S2, S0, S1     @ compute S2 = S0 * S1

    VCVT.F64.F32 D4, S2     @ covert the result to double precision for printing
    VMOV R1, R2, D4         @ split the double VFP register into two ARM registers
    BL  _printf_result      @ print the result

    B   _exit               @ branch to exit procedure with no return

_exit:  
    MOV R7, #4              @ write syscall, 4
    MOV R0, #1              @ output stream to monitor, 1
    MOV R2, #21             @ print string length
    LDR R1, =exit_str       @ string at label exit_str:
    SWI 0                   @ execute syscall
    MOV R7, #1              @ terminate syscall, 1
    SWI 0                   @ execute syscall

_printf_result:
    PUSH {LR}               @ push LR to stack
    LDR R0, =result_str     @ R0 contains formatted string address
    BL printf               @ call printf
    POP {PC}                @ pop LR from stack and return

.data
result_str:     .asciz      "Multiplication result = %f \n"
exit_str:       .ascii      "Terminating program.\n"
val1:           .float      3.14159
val2:           .float      0.100

我在 Raspberry Pi 中编译代码：

gcc -o float float.s

它编译没有任何问题，但是当我运行它时，我收到以下错误：

程序收到信号 SIGBUS，总线错误。
main() 中的 0x00010428

我已经对导致 SIGBUS 错误的原因进行了一些研究，在这里我唯一能想到的是访问未对齐的内存，但是十进制的 0x00010428 = 66,600 可以被 4 整除，所以我不确定问题是什么.

跑步

cat/proc/cpuinfo

我得到以下信息：

处理器：0
型号名称：ARMv6 兼容处理器 rev 7 (v6l)
BogoMIPS：2.00
特点：half thumb fastmult vfp edsp java tls
CPU 实现者：0x41
CPU 架构：7
CPU 变体：0x0
CPU 部分：0xb76
CPU 修订：7

硬件：BCM2708
修订：0002

4

1 回答 1

1

在 gdb 下运行代码显示问题：

(gdb) b main
Breakpoint 1 at 0x10424: file float.s, line 16.
(gdb) r
Starting program: /home/pi/a.out 

Breakpoint 1, main () at float.s:16
16          VLDR S0, [R0]           @ load the value into the VFP register
(gdb) p /x $r0
$1 = 0x2064e
(gdb) n

Program received signal SIGBUS, Bus error.
main () at float.s:18
18          LDR R0, =val2           @ load variable address

SIGBUS 被引发是因为地址0x2064e不是 4 字节对齐的。

val1并且val2不是 4 个字节对齐，因为它们的声明跟随长度不是 4 的倍数的字符串。
解决此问题的一种方法是将浮点声明移动到这样的字符串之前：

.data
val1:           .float      3.14159
val2:           .float      0.100
result_str:     .asciz      "Multiplication result = %f \n"
exit_str:       .ascii      "Terminating program.\n"

通过此修改运行程序打印：

乘法结果 = 0.314159
终止程序。

于 2016-07-14T12:12:53.807 回答