0

我正在使用 Flash CS 5 和 Flex 4，它们都用于构建适用于 android 的 AIR 应用程序。我想知道如何允许用户上下移动内容（图像或文本）（如地图，在这种情况下仅垂直）。

4

1 回答 1

1

目前还没有可用的触摸 UI 控件，因此您需要自己实现它。这里有一些代码可能会帮助您入门。我把它写在时间线上，以便我可以快速测试它。如果您在课堂上使用它，则需要进行一些调整。

变量content是舞台上的 MovieClip。如果它大于舞台的高度，您可以通过用鼠标（或用手指在触摸屏上）拖动它来滚动它。如果它小于舞台的高度，那么它根本不会滚动，因为它不需要。

var maxY:Number = 0;
var minY:Number = Math.min(0, stage.stageHeight - content.height);
var _startY:Number;
var _startMouseY:Number;
addEventListener(MouseEvent.MOUSE_DOWN, mouseDownHandler);

function mouseDownHandler(event:MouseEvent):void
{
    _startY = content.y;
    _startMouseY = mouseY;
    stage.addEventListener(MouseEvent.MOUSE_MOVE, stage_mouseMoveHandler, false, 0, true);
    stage.addEventListener(MouseEvent.MOUSE_UP, stage_mouseUpHandler, false, 0, true);
}

function stage_mouseMoveHandler(event:MouseEvent):void
{
    var offsetY:Number = mouseY - _startMouseY;
    content.y = Math.max(Math.min(maxY, _startY + offsetY), minY);
}

function stage_mouseUpHandler(event:MouseEvent):void
{
    stage.removeEventListener(MouseEvent.MOUSE_MOVE, stage_mouseMoveHandler);
    stage.removeEventListener(MouseEvent.MOUSE_UP, stage_mouseUpHandler);
}

或者，您可以使用该scrollRect属性。那个非常好，因为它会为您将内容屏蔽到一个矩形区域。如果你只是y像上面的代码一样改变，你可以在滚动内容的顶部绘制其他显示对象来模拟遮罩。它也比它快scrollRect。

于 2010-10-01T21:56:01.913 回答