3

我正在尝试使用 Antlr 3.2 和 Java1.6 匹配英文输入文本中的测量值。我有如下的词汇规则：

fragment
MILLIMETRE
    :   'millimetre' | 'millimetres'
    |   'millimeter' | 'millimeters'
    |   'mm'
    ;

MEASUREMENT
    :   MILLIMETRE | CENTIMETRE | ... ;

我希望能够接受大小写输入的任何组合，并且更重要的是，只需为 MILLIMETRE 的所有变体返回一个词法标记。但目前，我的 AST 包含“毫米”、“毫米”、“毫米”等，就像在输入文本中一样。

阅读http://www.antlr.org/wiki/pages/viewpage.action?pageId=1802308后，我认为我需要执行以下操作：

tokens {
    T_MILLIMETRE;
}

fragment
MILLIMETRE
    :   ('millimetre' | 'millimetres'
    |   'millimeter' | 'millimeters'
    |   'mm') { $type = T_MILLIMETRE; }
    ;

但是，当我这样做时，我在 Antlr 生成的 Java 代码中得到以下编译器错误：

cannot find symbol
_type = T_MILLIMETRE;

我尝试了以下方法：

MEASUREMENT
    :   MILLIMETRE  { $type = T_MILLIMETRE; }
    |   ...

但随后 MEASUREMENT 不再匹配。

带有重写规则的更明显的解决方案：

MEASUREMENT
    :   MILLIMETRE  -> ^(T_MILLIMETRE MILLIMETRE)
    |   ...

导致 NPE：

java.lang.NullPointerException at org.antlr.grammar.v2.DefineGrammarItemsWalker.alternative(DefineGrammarItemsWalker.java:1555).

将 MEASUREMENT 变成解析器规则会给我带来可怕的“以下标记定义永远无法匹配，因为先前的标记匹配相同的输入”错误。

通过创建解析器规则

measurement :  T_MILLIMETRE | ...

我收到警告“没有对应于令牌的词法分析器规则：T_MILLIMETRE”。虽然 Antlr 运行，但它仍然给我 AST 中的输入文本，而不是 T_MILLIMETRE。

我显然还没有像 Antlr 那样看待这个世界。任何人都可以给我任何提示或建议吗？

史蒂夫

4

2 回答 2

1

这是一种方法：

grammar Measurement;

options {
  output=AST;
}

tokens {
  ROOT;
  MM;
  CM;
}

parse
  :  measurement+ EOF -> ^(ROOT measurement+)
  ;

measurement
  :  Number MilliMeter -> ^(MM Number)
  |  Number CentiMeter -> ^(CM Number)
  ;

Number
  :  '0'..'9'+
  ;

MilliMeter
  :  'millimetre'
  |  'millimetres'
  |  'millimeter'
  |  'millimeters'
  |  'mm'
  ;

CentiMeter
  :  'centimetre'
  |  'centimetres'
  |  'centimeter'
  |  'centimeters'
  |  'cm'
  ;

Space
  :  (' ' | '\t' | '\r' | '\n'){$channel=HIDDEN;}
  ;

可以使用以下类进行测试：

import org.antlr.runtime.*;
import org.antlr.runtime.tree.*;
import org.antlr.stringtemplate.*;

public class Main {
    public static void main(String[] args) throws Exception {
        ANTLRStringStream in = new ANTLRStringStream("12 millimeters 3 mm 456 cm");
        MeasurementLexer lexer = new MeasurementLexer(in);
        CommonTokenStream tokens = new CommonTokenStream(lexer);
        MeasurementParser parser = new MeasurementParser(tokens);
        MeasurementParser.parse_return returnValue = parser.parse();
        CommonTree tree = (CommonTree)returnValue.getTree();
        DOTTreeGenerator gen = new DOTTreeGenerator();
        StringTemplate st = gen.toDOT(tree);
        System.out.println(st);
    }
}

生成以下 DOT 文件：

digraph {

    ordering=out;
    ranksep=.4;
    bgcolor="lightgrey"; node [shape=box, fixedsize=false, fontsize=12, fontname="Helvetica-bold", fontcolor="blue"
        width=.25, height=.25, color="black", fillcolor="white", style="filled, solid, bold"];
    edge [arrowsize=.5, color="black", style="bold"]

  n0 [label="ROOT"];
  n1 [label="MM"];
  n1 [label="MM"];
  n2 [label="12"];
  n3 [label="MM"];
  n3 [label="MM"];
  n4 [label="3"];
  n5 [label="CM"];
  n5 [label="CM"];
  n6 [label="456"];

  n0 -> n1 // "ROOT" -> "MM"
  n1 -> n2 // "MM" -> "12"
  n0 -> n3 // "ROOT" -> "MM"
  n3 -> n4 // "MM" -> "3"
  n0 -> n5 // "ROOT" -> "CM"
  n5 -> n6 // "CM" -> "456"

}

对应于树：

替代文字

（图片由http://graph.gafol.net/创建）

编辑

请注意以下事项：

measurement
  :  Number m=MilliMeter {System.out.println($m.getType() == MeasurementParser.MilliMeter);}
  |  Number CentiMeter
  ;

将始终打印true，无论（毫米）标记的“内容”是否为mm, millimetre, millimetres, ...

于 2010-09-29T11:08:40.417 回答
0

请注意，fragment规则仅“存在”在词法分析器中，而不再存在于解析器中。例如：

grammar Measurement;

options {
  output=AST;
}

parse
  :  (m=MEASUREMENT {
       String contents = $m.text;
       boolean isMeasurementType = $m.getType() == MeasurementParser.MEASUREMENT;
       System.out.println("contents="+contents+", isMeasurementType="+isMeasurementType);
     })+ EOF
  ;

MEASUREMENT
  :  MILLIMETRE
  ;

fragment
MILLIMETRE
  :  'millimetre' 
  |  'millimetres'
  |  'millimeter' 
  |  'millimeters'
  |  'mm'
  ;

SPACE
  :  (' ' | '\t' | '\r' | '\n'){$channel=HIDDEN;}
  ;

带输入文本：

"millimeters mm"

将打印：

contents=millimeters, isMeasurementType=true
contents=mm, isMeasurementType=true

换句话说：类型MILLIMETRE不存在，它们都是 type MEASUREMENT。

于 2010-09-30T14:34:57.597 回答