3

我为 spring 应用程序创建了一个 Gradle 项目。我的 build.gradle 如下：

buildscript {
    ext {
        springBootVersion = '1.3.5.RELEASE'
    }
    repositories {
        mavenCentral()
        jcenter()
    }
    dependencies {
        classpath("org.springframework.boot:spring-boot-gradle-plugin:${springBootVersion}")
        classpath('org.asciidoctor:asciidoctor-gradle-plugin:1.5.3')
    }
}

apply plugin: 'java'
apply plugin: 'spring-boot'

jar {
    baseName = 'edge'
    version = '0.0.1-SNAPSHOT'
}
sourceCompatibility = 1.8
targetCompatibility = 1.8

repositories {
    mavenCentral()
}

bootRepackage {
    excludeDevtools = true
}

dependencies {
    compile('org.springframework.boot:spring-boot-starter-actuator')
    compile('org.springframework.boot:spring-boot-actuator-docs')
    compile('org.springframework.boot:spring-boot-starter-aop')
    compile('org.springframework.cloud:spring-cloud-starter-config')
    compile('org.springframework.cloud:spring-cloud-starter-eureka')
    compile('org.springframework.cloud:spring-cloud-starter-hystrix')
    compile('org.springframework.cloud:spring-cloud-starter-hystrix-dashboard')
    compile('org.springframework.cloud:spring-cloud-starter-ribbon')
    compile('org.springframework.cloud:spring-cloud-starter-zuul')
    compile('org.springframework.boot:spring-boot-starter-hateoas')
    compile('org.springframework.boot:spring-boot-starter-data-jpa')
    compile('org.springframework.boot:spring-boot-starter-redis')
    compile('org.projectlombok:lombok:1.16.6')
    compile('org.springframework.boot:spring-boot-starter-security')
    compile('org.springframework.session:spring-session')
    compile('org.springframework.boot:spring-boot-starter-web') {
        exclude module: 'spring-boot-starter-tomcat'
    }
    compile('org.springframework.boot:spring-boot-starter-undertow')
    compile('org.springframework.boot:spring-boot-starter-websocket')
    compile('com.h2database:h2')
    compile('org.springframework.boot:spring-boot-devtools')
    testCompile('org.springframework.boot:spring-boot-starter-test')
    testCompile('org.springframework.restdocs:spring-restdocs-mockmvc')
}

dependencyManagement {
    imports {
        mavenBom "org.springframework.cloud:spring-cloud-dependencies:Brixton.RELEASE"
    }
}

eclipse {
    classpath {
         containers.remove('org.eclipse.jdt.launching.JRE_CONTAINER')
         containers 'org.eclipse.jdt.launching.JRE_CONTAINER/org.eclipse.jdt.internal.debug.ui.launcher.StandardVMType/JavaSE-1.8'
    }
}

然后每次我gradle build在源代码没有任何更改的情况下运行时，总是执行几个任务，而我认为它们应该是最新的：

➜  octopus git:(master) ✗
➜  octopus git:(master) ✗ gradle :edge:build
:edge:compileJava UP-TO-DATE
:edge:processResources UP-TO-DATE
:edge:classes UP-TO-DATE
:edge:findMainClass
:edge:jar
:edge:bootRepackage
:edge:assemble
:edge:compileTestJava UP-TO-DATE
:edge:processTestResources UP-TO-DATE
:edge:testClasses UP-TO-DATE
:edge:test UP-TO-DATE
:edge:check UP-TO-DATE
:edge:build

BUILD SUCCESSFUL

Total time: 6.773 secs

This build could be faster, please consider using the Gradle Daemon: https://docs.gradle.org/2.13/userguide/gradle_daemon.html
➜  octopus git:(master) ✗ md5 edge/build/libs/edge-0.0.1-SNAPSHOT.jar
MD5 (edge/build/libs/edge-0.0.1-SNAPSHOT.jar) = d0ff71c362d089559bbc627e78e2247a
➜  octopus git:(master) ✗ gradle :edge:build
:edge:compileJava UP-TO-DATE
:edge:processResources UP-TO-DATE
:edge:classes UP-TO-DATE
:edge:findMainClass
:edge:jar
:edge:bootRepackage
:edge:assemble
:edge:compileTestJava UP-TO-DATE
:edge:processTestResources UP-TO-DATE
:edge:testClasses UP-TO-DATE
:edge:test UP-TO-DATE
:edge:check UP-TO-DATE
:edge:build

BUILD SUCCESSFUL

Total time: 6.579 secs

This build could be faster, please consider using the Gradle Daemon: https://docs.gradle.org/2.13/userguide/gradle_daemon.html
➜  octopus git:(master) ✗ md5 edge/build/libs/edge-0.0.1-SNAPSHOT.jar
MD5 (edge/build/libs/edge-0.0.1-SNAPSHOT.jar) = d1c3fc5c9d0c00e0130c8c65f23b6466
➜  octopus git:(master) ✗

如您所见，任务“findMainClass”、“jar”、“bootRepackage”、“assemble”和“build”被认为是非最新的并且始终执行。而且每次生成的jar文件都不一样，因为它们有不同的MD5摘要。

那么，为什么 Gradle 会这样呢？如何使它们全部更新并加快构建过程？

4

1 回答 1

2

默认情况下，Spring Boot 的bootRepackage任务会覆盖由任务创建的 jar jar。这意味着该jar任务始终被认为是过时的。您可以通过配置分类器来避免这种情况，bootRepackage以便将重新打包的 fat jar 写入单独的位置。例如：

bootRepackage  {
    classifier = 'exec'
}

您可能也对这个问题感兴趣，它描述了我们希望对 Boot 的 Gradle 插件进行的一些改进。

于 2016-06-26T08:58:41.517 回答