delphi - Delphi：避免在 TDBgrid 中编辑列

Question

我知道使用列的只读属性，我可以避免编辑其字段值。但这并不能阻止就地编辑器展示自己。我需要一种方法来使列不仅受到保护而且“不可触碰”。请问有办法吗？

Answer 1

如果我正确理解您想要的内容，您可以通过创建自定义 TDBGrid 后代并覆盖其CanEditShow方法来非常简单地执行此操作，因为这决定了是否InplaceEditor可以创建网格：

type
  TMyDBGrid = class(TDBGrid)
  private
    FROColumn: Integer;
  protected
    function CanEditShow : Boolean; override;
  public
    property ROColumn : Integer read FROColumn write FROColumn;
  end;

function TMyDBGrid.CanEditShow: Boolean;
begin
  Result := Inherited CanEditShow;
  Result := Result and (Col <> ROColumn);
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  MyDBGrid := TMyDBGrid.Create(Self);
  MyDBGrid.ROColumn := 1;
  MyDBGrid.DataSource := DataSource1;
  MyDBGrid.Parent := Self;
[...]

这个极简主义的例子只是将一个网格列按数字定义为InplaceEditor不允许的网格列；显然，您可以使用任何您喜欢的机制来识别CanEditShow返回 False 的列。

请注意，上面的代码没有说明如果关闭Indicator列（即设置Options.dgIndicator为 False），网格的列编号会发生变化；

显然，通过使用可分配事件，您可以更灵活地自定义允许 InplaceEditor 的列，如

type

  TAllowGridEditEvent = procedure(Sender : TObject; var AllowEdit : Boolean) of object;

  TMyDBGrid = class(TDBGrid)
  private
    FOnAllowEdit: TAllowGridEditEvent;
  protected
    function CanEditShow : Boolean; override;
    procedure DoAllowEdit(var AllowEdit : Boolean);
  public
    property OnAllowEdit : TAllowGridEditEvent read FOnAllowEdit write FOnAllowEdit;
  end;

function TMyDBGrid.CanEditShow: Boolean;
begin
  Result := Inherited CanEditShow;
  if Result then
    DoAllowEdit(Result);
end;

procedure TMyDBGrid.DoAllowEdit(var AllowEdit: Boolean);
begin
  if Assigned(FOnAllowEdit) then
    FOnAllowEdit(Self, AllowEdit);
end;

procedure TForm1.AllowEdit(Sender: TObject; var AllowEdit: Boolean);
var
  Grid : TMyDBGrid;
begin
  Grid := Sender as TMyDBGrid;
  AllowEdit := Grid.Col <> 1;
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  MyDBGrid := TMyDBGrid.Create(Self);
  MyDBGrid.ROColumn := 1;
  MyDBGrid.DataSource := DataSource1;
  MyDBGrid.Parent := Self;
  MyDBGrid.OnAllowEdit := AllowEdit;
  [...]

如果您不喜欢在代码中创建网格，您可以将它放在自定义包中并安装在 IDE 中，或者，如果您的 Delphi 版本足够新，请 CanEditShow在class helper.