flowtype - 如何将 flowtype 与 spacemacs 集成

Question

我是spacemacs 的粉丝。我想使用Facebook Flow，但我不知道如何将它与 spacemacs 集成。我正在使用流程，nuclide但我需要重新学习一切才能提高工作效率。存储库中有这个脚本flow可以与 emacs 一起使用。我需要一份关于如何在 spacemacs 中使用它的指南。

谢谢。

Answer 1

我在这里使用了 Bodil 的 flow flycheck 配置：https ://github.com/bodil/emacs.d/blob/d28264cf072bb8a62459a48813d0cb30804b4f5b/bodil/bodil-js.el#L121-L154

我通过将以下内容添加到我的（https://github.com/saltycrane/.spacemacs.d/blob/9d985ace9251529c2b8d7857e2ec9835b103084c/init.el#L383-L414）使其与spacemacsreact-mode和默认的eslint flychecker一起使用：dotspacemacs/user-config

;; Flow (JS) flycheck config (http://flowtype.org)
;; from https://github.com/bodil/emacs.d/blob/master/bodil/bodil-js.el
(require 'f)
(require 'json)
(require 'flycheck)

(defun flycheck-parse-flow (output checker buffer)
  (let ((json-array-type 'list))
    (let ((o (json-read-from-string output)))
      (mapcar #'(lambda (errp)
                  (let ((err (cadr (assoc 'message errp))))
                    (flycheck-error-new
                     :line (cdr (assoc 'line err))
                     :column (cdr (assoc 'start err))
                     :level 'error
                     :message (cdr (assoc 'descr err))
                     :filename (f-relative
                                (cdr (assoc 'path err))
                                (f-dirname (file-truename
                                            (buffer-file-name))))
                     :buffer buffer
                     :checker checker)))
              (cdr (assoc 'errors o))))))

(flycheck-define-checker javascript-flow
  "Javascript type checking using Flow."
  :command ("flow" "--json" source-original)
  :error-parser flycheck-parse-flow
  :modes react-mode
  :next-checkers ((error . javascript-eslint))
  )
(add-to-list 'flycheck-checkers 'javascript-flow)

还要确保安装了 Flow 命令行工具。像这样安装它：

npm install -g flow-bin

我认为 Bodil 打算使消息简短，但我想让 flycheck 显示更详细的消息。如果有人知道如何做到这一点，我将不胜感激。

编辑 2016-08-12：我发布的原始版本Symbol's function definition is void: flycheck-define-checker在初始加载时出错。我更新了上面的代码以添加一个require 'flycheck以消除该错误。

Answer 2

saltycrane的答案对我来说很好。谢谢！正如他指出的那样，该解决方案提供了非常简短的错误消息。我已将错误消息改进为更详细，并且看起来更像来自 flow cli 输出的输出。

对于想要使用此脚本的新用户，请注意确保您flycheck-define-checker在底部对其进行编辑以使用正确的模式。我用这个js2-mode，saltycrane 用react-mode。编辑它以使用您正在使用的任何内容。

(require 'f)
(require 'json)
(require 'flycheck)
(defun flycheck-parse-flow (output checker buffer)
  (let ((json-array-type 'list))
    (let ((o (json-read-from-string output)))
      (mapcar #'(lambda (errp)
                  (let ((err (cadr (assoc 'message errp)))
                        (err2 (cadr (cdr (assoc 'message errp)))))
                    (flycheck-error-new
                     :line (cdr (assoc 'line err))
                     :column (cdr (assoc 'start err))
                     :level 'error
                     :message (concat (cdr (assoc 'descr err)) ". " (cdr (assoc 'descr err2)))
                     :filename (f-relative
                                (cdr (assoc 'path err))
                                (f-dirname (file-truename
                                            (buffer-file-name))))
                     :buffer buffer
                     :checker checker)))
              (cdr (assoc 'errors o))))))

(flycheck-define-checker javascript-flow
  "Static type checking using Flow."
  :command ("flow" "--json" source-original)
  :error-parser flycheck-parse-flow
  :modes js2-mode)
(add-to-list 'flycheck-checkers 'javascript-flow)