3

我有一个如下所示的 XML 文件...

    <states>
 <state>
  <name>North Carolina</name>
  <city>Charlotte</city>
 </state>
 <state>
  <name>Alaska</name>
  <city>Fairbanks</city>
 </state>
 <state>
  <name>Virginia</name>
  <city>Leesburg</city>
 </state>
 <state>
  <name>Alaska</name>
  <city>Coldfoot</city>
 </state>
 <state>
  <name>North Carolina</name>
  <city>Harrisburg</city>
 </state>
 <state>
  <name>Virginia</name>
  <city>Ashburn</city>
 </state>  
</states>

我需要生成一份列出每个州的报告，按字母顺序排列，每个城市都在后面.. 例如..

Alaska - Fairbanks, Coldfoot
North Carolina - Charlotte, Harrisburg
Virginia - Leesburg, Ashburn

（城市不必按字母顺序排列，只有州）

我试图通过在状态/状态上执行一个 for-each 来解决这个问题，按名称对其进行排序并进行处理。像这样....

    <xsl:for-each select="states/state">
       <xsl:sort select="name" data-type="text" order="ascending"/>
       <xsl:value-of select="name"/>-<xsl:value-of select="city"/>
    </xsl:for-each>

这给了我......

 Alaska - Fairbanks
 Alaska - Coldfoot
 North Carolina - Charlotte
 North Carolina - Harrisburg
 Virginia - Leesburg
 Virginia - Ashburn

排序工作，现在我想分组。我唯一能想到的就是与之前的状态进行比较，因为它是排序的，它应该识别状态值是否没有改变。像这样...

<xsl:for-each select="states/state">
             <xsl:sort select="name" data-type="text" order="ascending"/>
  <xsl:variable name="name"><xsl:value-of select="name">
  <xsl:variable name="previous-name"><xsl:value-of select="(preceding-sibling::state)/name">
  <xsl:if test="$name != $previous-name">
   <br/><xsl:value-of select="name"/>-
  </xsl:if>
  <xsl:value-of select="city"/>
 </xsl:for-each>

可悲的是，前同级特征似乎不适用于排序，因此，第一次通过（在第一个阿拉斯加）它看到第一个北卡罗来纳州作为前同级。这会导致一些奇怪的结果，这根本不是我喜欢的。

所以，我正在使用 XSLT1.0... 有什么想法/建议吗？

谢谢

4

3 回答 3

5

这个样式表：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:key name="kStateByName" match="state" use="name"/>
    <xsl:output method="text"/>
    <xsl:template match="/">
        <xsl:apply-templates
                   select="/*/state[count(.|key('kStateByName',name)[1])=1]">
            <xsl:sort select="name"/>
        </xsl:apply-templates>
    </xsl:template>
    <xsl:template match="state">
        <xsl:value-of select="concat(name,' - ')"/>
        <xsl:apply-templates select="key('kStateByName',name)/city"/>
    </xsl:template>
    <xsl:template match="city">
        <xsl:value-of select="concat(.,substring(', ', 
                                                 1 div (position()!=last())),
                                       substring('&#xA;',
                                                 1 div (position()=last())))"/>
    </xsl:template>
</xsl:stylesheet>

输出：

Alaska - Fairbanks, Coldfoot
North Carolina - Charlotte, Harrisburg
Virginia - Leesburg, Ashburn

注：按州名分组。分隔符子字符串表达式仅适用于拉式样式（将模板应用于城市）

XSLT 2.0 解决方案：

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text"/>
    <xsl:template match="states">
        <xsl:for-each-group select="state" group-by="name">
            <xsl:sort select="name"/>
            <xsl:value-of select="concat(name,
                                         ' - ',
                                         string-join(current-group()/city,', '),
                                         '&#xA;')"/>
        </xsl:for-each-group>
    </xsl:template>
</xsl:stylesheet>

只是为了好玩，这个 XPath 2.0 表达式：

string-join(for $state in distinct-values(/*/*/name)
            return concat($state,
                          ' - ',
                          string-join(/*/*[name=$state]/city,
                                      ', ')),
            '&#xA;')
于 2010-09-23T20:52:35.980 回答
1

对于 XSLT 1.0 中的分组，您可能必须使用Muenchian 方法。这可能很难理解，但一旦你让它工作，你应该很高兴。

于 2010-09-23T20:23:46.107 回答
0

这将返回一个不同的状态列表：

  <xsl:for-each select="states/state">
     <xsl:sort select="name" />
     <xsl:if test="not(name = preceding-sibling::state/name)" >
         <xsl:value-of select="name" />
     </xsl:if>
  </xsl:for-each>

我使用了您的示例 XML，用上面的内容构建了一个小样式表，通过 Xalan-j 运行它，它返回：

阿拉斯加北卡罗来纳弗吉尼亚

因此，您应该能够从那里应用模板或另一个 for-each 循环来提取每个不同州的城市列表。

克里斯

于 2010-09-23T22:10:41.703 回答