xml - 如何在指定计数后打破 xsl 中的表格行？

Question

我有以下 xsl 按字母顺序对我的 xml 进行排序：

<xsl:template match="/">
  <xsl:apply-templates />
</xsl:template> 

<xsl:key name="rows-by-title" match="Row" use="translate(substring(@Title,1,1),'abcdefghijklmnopqrstuvwxyz','ABCDEFGHIJKLMNOPQRSTUVWXYZ')" />
<xsl:variable name="StartRow" select="string('&lt;tr &gt;')" />

<xsl:template name="Meunchian" match="/dsQueryResponse/Rows">
  <table>
    <tr>
      <xsl:for-each select="Row[count(. | key('rows-by-title', translate(substring(@Title,1,1),'abcdefghijklmnopqrstuvwxyz','ABCDEFGHIJKLMNOPQRSTUVWXYZ'))[1]) = 1]">
        <xsl:sort select="translate(substring(@Title,1,1),'abcdefghijklmnopqrstuvwxyz','ABCDEFGHIJKLMNOPQRSTUVWXYZ')" />
        <!-- Puts out the title -->
        <td>
          <xsl:value-of select="translate(substring(@Title,1,1),'abcdefghijklmnopqrstuvwxyz','ABCDEFGHIJKLMNOPQRSTUVWXYZ')" />
        </td>
        <!-- Now all it's children -->
        <xsl:for-each select="key('rows-by-title', translate(substring(@Title,1,1),'abcdefghijklmnopqrstuvwxyz','ABCDEFGHIJKLMNOPQRSTUVWXYZ'))">
          <xsl:value-of select="@Title" /><br/>
        </xsl:for-each>
      </xsl:for-each>
   </tr>
  </table>
</xsl:template>

XML:

<dsQueryResponse>
  <Rows>
    <Row Title="Agenda" />
    <Row Title="Policy" />
    <Row Title="Policy" />
    <Row Title="Report" />
    <Row Title="Report" />
  </Rows>
</dsQueryResponse>

我现在想打破每 4 列输出的表格行，以便输出看起来像：

ABCD
EFGH
IJKL
MNOP
QRST
UVWX
YZ

谁能建议实现这一目标的最佳方法？

非常感谢

Answer 1

这是我的解决方案。

您可以通过参数决定是要显示空单元格"per-row"还是"show-empty"要隐藏它们。我确信存在一个更优雅的版本，但我想不出一个。;-) 欢迎评论。

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="html" version="4.0" encoding="iso-8859-1" indent="yes"/>

  <xsl:key name="rows-by-title" match="Row" use="translate(substring(@Title, 1, 1), 'abcdefghijklmnopqrstuvwxyz', 'ABCDEFGHIJKLMNOPQRSTUVWXYZ')" />
  <xsl:variable name="alphabet" select="string('ABCDEFGHIJKLMNOPQRSTUVWXYZ')" />
  <xsl:variable name="per-row" select="number(4)" /> 
  <xsl:variable name="show-empty" select="false()" />

  <xsl:template match="/">
    <xsl:apply-templates select="dsQueryResponse/Rows" />
  </xsl:template> 

  <xsl:template match="Rows">
    <table>
      <xsl:call-template name="create-rows" />
    </table>
  </xsl:template>

  <xsl:template name="create-rows">
    <xsl:param name="index" select="1" />

    <xsl:variable name="letters">
      <xsl:call-template name="next-letters">
        <xsl:with-param name="index" select="$index" />
      </xsl:call-template>
    </xsl:variable>

    <xsl:if test="$letters != ''">
      <tr title="{$letters}">
        <xsl:call-template name="create-cells">
          <xsl:with-param name="letters" select="$letters" />
        </xsl:call-template>
      </tr>
    </xsl:if>

    <xsl:if test="string-length($letters) = $per-row">
      <xsl:call-template name="create-rows">
        <xsl:with-param name="index" select="string-length(substring-before($alphabet, substring($letters, string-length($letters), 1))) + 2" />
      </xsl:call-template>
    </xsl:if>
  </xsl:template>

  <xsl:template name="next-letters">
    <xsl:param name="index" />

    <xsl:variable name="letter" select="substring($alphabet, $index, 1)" />

    <xsl:variable name="letters">
      <xsl:if test="$index &lt;= string-length($alphabet)">
        <xsl:if test="$show-empty or key('rows-by-title', $letter)">
          <xsl:value-of select="$letter" />
        </xsl:if>

        <xsl:call-template name="next-letters">
          <xsl:with-param name="index" select="$index + 1" />
        </xsl:call-template>
      </xsl:if>
    </xsl:variable>

    <xsl:value-of select="substring($letters, 1, $per-row)" />
  </xsl:template>

  <xsl:template name="create-cells">
    <xsl:param name="letters" />

    <xsl:variable name="letter" select="substring($letters, 1, 1)" />

    <xsl:if test="$letter != ''">
      <td title="{$letter}">
        <strong>
          <xsl:value-of select="$letter" />
        </strong>
        <xsl:apply-templates select="key('rows-by-title', $letter)">
          <xsl:sort select="@Title" />
        </xsl:apply-templates>
      </td>
      <xsl:call-template name="create-cells">
        <xsl:with-param name="letters" select="substring($letters, 2, string-length($letters) - 1)" />
      </xsl:call-template>
    </xsl:if>
  </xsl:template>

  <xsl:template match="Row">
    <br />
    <xsl:value-of select="@Title" />
  </xsl:template>

</xsl:stylesheet>

使用此输入：

<dsQueryResponse>
  <Rows>
    <Row Title="Agenda" />
    <Row Title="Policy" />
    <Row Title="Policy" />
    <Row Title="Report" />
    <Row Title="Report" />
    <Row Title="Test2" />
    <Row Title="Test1" />
    <Row Title="Boo" />
    <Row Title="Foo" />
  </Rows>
</dsQueryResponse>

生成此输出（title属性仅用于调试。我将它们留在里面，随时删除它们）：

<table>
  <tr title="ABFP">
    <td title="A">
      <strong>A</strong>
      <br>Agenda
    </td>
    <td title="B">
      <strong>B</strong>
      <br>Boo
    </td>
    <td title="F">
      <strong>F</strong>
      <br>Foo
    </td>
    <td title="P">
      <strong>P</strong>
      <br>Policy
      <br>Policy
    </td>
  </tr>
  <tr title="RT">
    <td title="R">
      <strong>R</strong>
      <br>Report
      <br>Report
    </td>
    <td title="T">
      <strong>T</strong>
      <br>Test1
      <br>Test2
    </td>
  </tr>
</table>

Answer 2

必须编辑此问题，以便任何人了解问题的真正含义。Tomalak 的评论表明，OP“想要按字母顺序排列的网格中的项目列表。每个字母一个列表。水平四个字母，与垂直方向一样多”

以下转换：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:ext="http://exslt.org/common"
 extension-element-prefixes="ext"
 >

 <xsl:variable name="vDoc" select="/"/>
 <xsl:variable name="vNumCols" select="4"/>

 <xsl:variable name="vLower"
  select="'abcdefghijklmnopqrstuvwxyz'"
  />

 <xsl:variable name="vUpper"
  select="'ABCDEFGHIJKLMNOPQRSTUVWXYZ'"
  />

  <xsl:key name="rows-by-FirstLetter" match="Row"
  use="translate(substring(@Title,1,1),
                 'abcdefghijklmnopqrstuvwxyz',
                 'ABCDEFGHIJKLMNOPQRSTUVWXYZ')" />

  <xsl:variable name="vrtfStartLetters">
    <xsl:for-each select=
    "/*/*/Row
           [count(.
               |
                key('rows-by-FirstLetter',
                   translate(substring(@Title,1,1),
                             $vLower,
                             $vUpper)
                  )[1]
                  )
              = 1
           ]">

         <startLetter>
           <xsl:value-of select=
             "translate(substring(@Title,1,1),
                      $vLower,
                      $vUpper)"/>
         </startLetter>
      </xsl:for-each>
    </xsl:variable>

    <xsl:variable name="vStartLetters" select=
      "ext:node-set($vrtfStartLetters)"/>

  <xsl:template match="Rows">
    <table>
      <xsl:apply-templates select=
       "$vStartLetters/*[position() mod $vNumCols = 1]">
        <xsl:with-param name="pDoc" select="$vDoc"/>
        <xsl:with-param name="pNumCols" select="$vNumCols"/>
      </xsl:apply-templates>
    </table>
  </xsl:template>

  <xsl:template match="startLetter">
    <xsl:param name="pDoc"/>
    <xsl:param name="pNumCols" select="10"/>
    <tr>
      <xsl:apply-templates mode="copy" select=
      ". | following-sibling::*
               [not(position() >= $pNumCols)]">
         <xsl:with-param name="pDoc" select="$pDoc"/>
         <xsl:sort/>

      </xsl:apply-templates>
    </tr>
  </xsl:template>

  <xsl:template match="startLetter" mode="copy">
    <xsl:param name="pDoc"/>

    <xsl:variable name="pThis" select="."/>

    <td>
      <xsl:value-of select="."/>
      <br />
      <table>
     <xsl:for-each select="$pDoc">
      <xsl:for-each select="key('rows-by-FirstLetter', $pThis)">
        <tr><td><xsl:value-of select="@Title"/></td></tr>
      </xsl:for-each>
     </xsl:for-each>
    </table>
    </td>
  </xsl:template>
</xsl:stylesheet>

应用于此 XML 文档时：

<dsQueryResponse>
  <Rows>
    <Row Title="Agenda" />
    <Row Title="Accrual" />
    <Row Title="Ads" />
    <Row Title="Averages" />
    <Row Title="Bindings" />
    <Row Title="Budget" />
    <Row Title="Cars" />
    <Row Title="Categories" />
    <Row Title="Costs" />
    <Row Title="Policy" />
    <Row Title="Politics" />
    <Row Title="Reevaluations" />
    <Row Title="Report" />
  </Rows>
</dsQueryResponse>

产生想要的结果：

<table>
  <tr>
    <td>A
      <br/>
      <table>
        <tr>
          <td>Agenda</td>
        </tr>
        <tr>
          <td>Accrual</td>
        </tr>
        <tr>
          <td>Ads</td>
        </tr>
        <tr>
          <td>Averages</td>
        </tr>
      </table>
    </td>
    <td>B
      <br/>
      <table>
        <tr>
          <td>Bindings</td>
        </tr>
        <tr>
          <td>Budget</td>
        </tr>
      </table>
    </td>
    <td>C
      <br/>
      <table>
        <tr>
          <td>Cars</td>
        </tr>
        <tr>
          <td>Categories</td>
        </tr>
        <tr>
          <td>Costs</td>
        </tr>
      </table>
    </td>
    <td>P
      <br/>
      <table>
        <tr>
          <td>Policy</td>
        </tr>
        <tr>
          <td>Politics</td>
        </tr>
      </table>
    </td>
  </tr>
  <tr>
    <td>R
      <br/>
      <table>
        <tr>
          <td>Reevaluations</td>
        </tr>
        <tr>
          <td>Report</td>
        </tr>
      </table>
    </td>
  </tr>
</table>

请注意三件事：

• 我们正在使用 ( exslt ) ext:node-set()扩展函数将中间结果从 RTF（结果树片段）转换为临时树。

• 必须将<xsl:for-each select="$pDoc">原始 XML 文档再次变为当前 XML 文档，以便 key() 函数将使用为该文档而不是临时树创建的索引。

• 每个必须开始新行 (4) 个起始字母的起始字母都在一个特殊的模板中进行处理，在该模板中<tr>生成 。然后在“复制”模式的主体内处理该行和剩余的 (3) 个起始字母<tr>，只创建一个<td>each。

在这里，我们介绍并演示了一些高级 XSLT 技术：

• 使用mod运算符按数量分组。
• 对与当前文档不同的文档使用key()函数。
• 模式
• 将RTF转换为临时树

享受:)

Answer 3

这是第二种解决方案，它不需要任何扩展功能。请注意，它不是递归的，并且可能比递归更有效。

这种转变：

<xsl:stylesheet 版本="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:my="my:namespace"
 排除结果前缀=“我的”
 >
 <xsl:输出方法="html"/>

  <我的：阿尔法>
    <l>A</l><l>B</l><l>C</l><l>D</l><l>E</l>
    <l>F</l><l>G</l><l>H</l><l>I</l><l>J</l>
    <l>K</l><l>L</l><l>M</l><l>N</l><l>O</l>
    <l>P</l><l>Q</l><l>R</l><l>S</l><l>T</l>
    <l>U</l><l>V</l><l>W</l><l>X</l><l>Y</l>
    <l>Z</l>
  </my:alpha>
    <xsl:variable name="vDoc" select="/"/>
    <xsl:variable name="vNumCols" select="4"/>
    <xsl:变量名="vLower" select="'abcdefghijklmnopqrstuvwxyz'" />
    <xsl:variable name="vUpper" select="'ABCDEFGHIJKLMNOPQRSTUVWXYZ'" />

    <xsl:key name="rows-by-FirstLetter" match="Row"
      使用="翻译(子字符串(@Title,1,1),
                     'abcdefghijklmnopqrstuvwxyz',
                     'ABCDEFGHIJKLMNOPQRSTUVWXYZ')" />

  <xsl:variable name="vStartingLetters">
    <xsl:for-每个选择=
        “/*/*/排
           [生成-id()
           =
            生成-id(key('rows-by-FirstLetter',
                             翻译（子字符串（@Title,1,1），
                                                 $v下，
                                                 $vUpper)
                             )[1]
                         )
            ]">
      <xsl:value-of 选择=
         “翻译（子字符串（@Title,1,1），
                    $v下，
                    $vUpper)"/>
    </xsl:for-each>
  </xsl:变量>

  <xsl:variable name="vMyLetters" 选择=
   “文档（''）/*/my:alpha/l[包含（$vStartingLetters,.）]”
   />

    <xsl:template match="行">
        <表格>
          <xsl:for-每个选择=
            "$vMyLetters[position() mod $vNumCols = 1]">
            <xsl:变量名="vPos"
               select="(position()-1)*$vNumCols+1"/>

              <tr>
                 <xsl:应用模板选择=
                  "$vMyLetters[位置() >= $vPos
                              和
                               不是（位置（）> $vPos+$vNumCols -1）
                              ]">
            <xsl:with-param name="pDoc" select="$vDoc"/>
                 </xsl:apply-templates>
              </tr>
             </xsl:for-each>
        </table>
    </xsl:模板>

    <xsl:template match="l">
        <xsl:param name="pDoc"/>

        <xsl:variable name="pThis" select="."/>

        <td>
            <xsl:value-of select="."/>
            <br />
            <表格>
                <xsl:for-each select="$pDoc">
                    <xsl:for-每个选择=
                            "key('rows-by-FirstLetter', $pThis)">
                <tr>
                  <td>

                    <xsl:value-of select="@Title"/>
                  </td>
                </tr>
                    </xsl:for-each>
                </xsl:for-each>
            </table>
        </td>
    </xsl:模板>
</xsl:样式表>

应用于以下 XML 文档时：

<dsQueryResponse>
    <行>
        <Row Title="议程" />
        <Row Title="策略" />
        <Row Title="策略" />
        <行标题="报告" />
        <行标题="报告" />
        <Row Title="Test2" />
        <Row Title="Test1" />
        <Row Title="嘘" />
        <Row Title="Foo" />
    </行>
</dsQueryResponse>

产生想要的结果：

<表格>
   <tr>
      <td>A<br><表>
            <tr>
               <td>议程</td>
            </tr>
         </table>
      </td>
      <td>B<br><表>
            <tr>
               <td>嘘</td>
            </tr>
         </table>
      </td>
      <td>F<br><表>
            <tr>
               <td>美食</td>
            </tr>
         </table>
      </td>
      <td>P<br><表>
            <tr>
               <td>政策</td>
            </tr>
            <tr>
               <td>政策</td>
            </tr>
         </table>
      </td>
   </tr>
   <tr>
      <td>R<br><表格>
            <tr>
               <td>报告</td>
            </tr>
            <tr>
               <td>报告</td>
            </tr>
         </table>
      </td>
      <td>T<br><表>
            <tr>
               <td>测试2</td>
            </tr>
            <tr>
               <td>测试1</td>
            </tr>
         </table>
      </td>
   </tr>
</table>

请注意，我的第一个答案中的大多数解释也适用于此解决方案，唯一的例外是我们不使用模式。

Answer 4

我对这个问题有点困惑，但我认为你正在寻找的是一个 xsl:if 测试与position()和mod的组合