0

我有一个 SAS DS2 程序，它从如下数据步骤在屏幕上打印输出，我想将输出引导到文件中。AFAIK，“文件”是 DS2 中缺少的功能，因为 DS2 当前读取和写入表，有人可以告诉我如何将 ds2 程序的输出流式传输到文件吗？谢谢。

 put '********* Body (html contents from a stream) **********/';
 put _body;

问候， AKS

4

1 回答 1

2

DS2 不具备 SAS 或 SQL 或类似目标之外的文件 i/o 功能。DS2 的存在主要是为了实现与 Hadoop 和 Teradata 以及其他一些大数据目标的轻松连接；希望它会在未来得到扩展，但它现在还很年轻，没有很好地利用。

也就是说，有一些……创造性的解决方法。一种可能的答案涉及使用日志。这不是一个很好的解决方案，但它确实有效。

基本上，关闭注释和源，然后 PROC PRINTTO 将日志重定向到您想要的文件，PUT 到日志，然后重定向回来并重新打开。警告和错误仍然会进入日志，所以不要有任何这些。

对于生产代码，这绝对不是一个很好的解决方案。对于生产代码，我强烈建议写入 SQL 表或 SAS 数据集，然后使用老式数据步骤生成输出。DS2 目前不适合这类事情。即使语言没有扩展为具有此功能，将来也可能会编写包以更有帮助地执行此操作；JSON 包是一个很好的起点，尽管我认为它现在还没有这个功能。

这是一个使用日志的例子（一个非常做作的例子）：

proc sql;
  select name into :namestr
    separated by ' '
    from sashelp.class
  ;
  select age into :agestr
    separated by ' '
    from sashelp.class;
quit;

%let namestr = %str(%')&namestr%str(%');
%let agestr  = %str(%')&agestr%str(%');

options nonotes nosource;
proc printto log="c:\temp\testds2.txt" new;
proc ds2;
  data _null_;
    method init();        
        dcl int rc;
        dcl nvarchar(15) name;
        dcl int age;
        dcl double iter;
        dcl nvarchar(1000) namestr;
        dcl nvarchar(500) agestr;
        name ='';
        age  = .;
        namestr= &namestr.;
        agestr = &agestr.;
        do iter = 1 to countw(namestr);
          name = scan(namestr,iter);
          age  = scan(agestr,iter);
          put name  age;
        end;
    end;

  enddata;
  run;
quit;
proc printto; run;
options notes source;
于 2016-06-06T15:33:21.687 回答