perl - Perl Anyevent，非阻塞redis推送

Question

我有下面的代码来执行非阻塞 rpush 到 redis 服务器当我只运行 1 rpush 时，代码工作正常但是当我在 while 循环中运行它时，脚本在第一次执行后挂起。为什么 ？

#!/usr/bin/perl                                                                                                                                                          
use AnyEvent;
use AnyEvent::Redis::RipeRedis;
use strict;
#my $cv = AE::cv();                                                                                                                                                      

my $redis = AnyEvent::Redis::RipeRedis->new(
  host     => 'localhost',
  port     => '6379',
    );

my $i=0;

my $cv;
while($i++ < 5) {
    $cv = AnyEvent->condvar;
    $redis->rpush( 'list', "1","2","3",
                   { on_done => sub {
                   my $data = shift;
                   print "$data\n";
                     },
                   }
        );
    $cv->recv();
}
$redis->quit(
    sub {$cv->send();}
    );
$cv->recv();

Answer 1

当您在 while 循环中调用 $cv->recv() 并且脚本正在等待 $cv->send 或 $cv->croak 时，您会阻止脚本执行，但在回调中您不会调用 $cv->send()。

$cv->recv

等待（必要时阻塞）直到 $cv 上调用了 ->send 或 ->croak 方法，同时正常为其他观察者提供服务。

如果您想发送不同的非阻塞请求，请尝试使用 AnyEvents 开始和结束方法。

#!/usr/bin/perl
use AnyEvent;
use AnyEvent::Redis::RipeRedis;
use strict;

my $redis = AnyEvent::Redis::RipeRedis->new(
  host     => 'localhost',
  port     => '6379',
);

my $i=0;

my  $cv = AnyEvent->condvar;
while($i++ < 5) {
   $cv->begin;
   $redis->rpush( 'list', "1","2","3",
               { 
                  on_done => sub {
                    my $data = shift;
                    print "$data\n";
                    $cv->end();
                  },
               }
    );
}

$cv->recv();

Answer 2

请注意，您尚未定义 connection_timeout：

my $redis = AnyEvent::Redis::RipeRedis->new(
  host     => 'localhost',
  port     => '6379',
    );

应该看起来像：

  my $redis = AnyEvent::Redis::RipeRedis->new(
    host => 'localhost',
    port => '6379',
    password => 'your_password',
    connection_timeout => 5,
    reconnect => 1,
    encoding => 'utf8');

从：

ftp://ftp.uni-siegen.de/pub/CPAN/authors/id/I/IP/IPH/AnyEvent-Redis-RipeRedis-1.002.readme