1

我需要为函数声明解析这个语法

foo x = 1 
Func "foo" (Ident "x") = 1

foo (x = 1) = 1 
Func "foo" (Label "x" 1) = 1

foo x = y = 1 
Func "foo" (Ident "x") = (Label "y" 1)

我写了这个解析器

module SimpleParser where
import Text.Parsec.String (Parser)
import Text.Parsec.Language (emptyDef)
import Text.Parsec
import qualified Text.Parsec.Token as Tok
import Text.Parsec.Char
import Prelude

lexer :: Tok.TokenParser ()
lexer = Tok.makeTokenParser style
  where
    style = emptyDef {
              Tok.identLetter    = alphaNum
             }

parens :: Parser a -> Parser a
parens = Tok.parens lexer

commaSep :: Parser a -> Parser [a]
commaSep = Tok.commaSep1 lexer

commaSep1 :: Parser a -> Parser [a]
commaSep1 = Tok.commaSep1 lexer


identifier :: Parser String
identifier = Tok.identifier lexer

reservedOp :: String -> Parser ()
reservedOp = Tok.reservedOp lexer

data Expr = IntLit Int | Ident String | Label String Expr | Func String Expr Expr | ExprList [Expr] deriving (Eq, Ord, Show)


integer :: Parser Integer
integer = Tok.integer lexer

litInt :: Parser Expr
litInt = do
  n <- integer
  return $ IntLit (fromInteger n)

ident :: Parser Expr
ident = Ident <$> identifier

paramLabelItem = litInt <|> paramLabel

paramLabel :: Parser Expr
paramLabel = do
  lbl <- try (identifier <* reservedOp "=")
  body <- paramLabelItem
  return $ Label lbl body

paramItem :: Parser Expr
paramItem = parens paramRecord <|> litInt <|> try paramLabel <|> ident

paramRecord :: Parser Expr
paramRecord = ExprList <$> commaSep1 paramItem

func :: Parser Expr
func = do
  name <- identifier
  params <- paramRecord
  reservedOp "="
  body <- paramRecord
  return $ (Func name params body)


parseExpr :: String -> Either ParseError Expr
parseExpr s = parse func "" s

我可以解析foo (x) = 1但我无法解析foo x = 1

parseExpr "foo x = 1"
Left (line 1, column 10):
unexpected end of input
expecting digit, "," or "="

我知道它会尝试解析此代码Func "foo" (Label "x" 1)并失败。但是在失败之后为什么它不能尝试解析它Func "foo" (Ident "x") = 1

有什么办法吗？

我也尝试过交换ident和paramLabel

paramItem = parens paramRecord <|> litInt <|> try paramLabel <|> ident
paramItem = parens paramRecord <|> litInt <|> try ident <|> paramLabel

在这种情况下，我可以解析foo x = 1但我无法解析foo (x = 1) = 2

parseExpr "foo (x = 1) = 2"
Left (line 1, column 8):
unexpected "="
expecting "," or ")"
4

1 回答 1

2

以下是我如何理解 Parsec 回溯的工作原理（并且不起作用）：

在：

(try a <|> try b <|> c)

如果a失败，b将被尝试，如果b随后失败c将被尝试。

但是，在：

(try a <|> try b <|> c) >> d

如果a成功但d失败，Parsec 不会返回并尝试b。一旦a成功，Parsec 将整个选择视为已解析，然后继续执行d. 它永远不会回去尝试b或c。

出于同样的原因，这也不起作用：

(try (try a <|> try b <|> c)) >> d

一旦a或b成功，整个选择成功，因此外部try成功。然后解析继续进行d。

一个解决方案是分发d到选择范围内：

try (a >> d) <|> try (b >> d) <|> (c >> d)

现在如果a成功但d失败，b >> d将被尝试。

于 2016-05-30T16:28:33.330 回答