43

我有一个 groovy 文件，我想从 Jenkinsfile 运行。

IE。load script.groovy

但是，如果它与 Jenkinsfile 存储在同一目录中，我不确定如何引用该文件。我正在从 git 加载 Jenkinsfile。我注意到它创建了一个名为workspace@script. 它不会将它放在工作区目录中。我可以对文件夹进行硬编码，但我不确定这方面的规则，再次签出代码似乎有点多余。

java.io.FileNotFoundException: /opt/jenkins_home/jobs/my_job/workspace/script.groovy (No such file or directory)

默认情况下，它从工作区加载，而不是workspace@script

我正在尝试将 BuildFlow 脚本转换为管道（工作流）脚本。但我发现，它不像复制和粘贴那么容易。

詹金斯文件

node {

//get parameters from Job
def builds = builds.tokenize(",")
def ip_address_node = ip_address_node.trim()
def port_node = port_node.trim()
def branch = branch.trim()
def workspace = pwd()

stage 'Checking out code from esb repository'
git branch: branch, url: 'ssh://git@giturl/integration_bus.git'

load '../workspace@script/esb_deploybar_pipeline/deploy_esb.groovy'

}

deploy_esb.groovy（这是来自旧的构建流程，试图在管道中运行）

import groovy.transform.ToString
import groovy.transform.EqualsAndHashCode
@EqualsAndHashCode
@ToString
class BarDeploy {
    String barFile
    String app
    String integrationServer
}


//parse csv
def csvItemsApps = new HashSet<BarDeploy>();
def csvItemsLibs = new HashSet<BarDeploy>();
def deploymentMapFile = new File(workspace + "/ESB_Deployment_Map.csv")
def isFirstLine = true

stage 'Parsing ESB Deployment CSV'
deploymentMapFile.withReader { reader ->
    while(line = reader.readLine()) {
        if(isFirstLine)
        {
          isFirstLine = false
          continue
        }

        csvLine = line.split(",")
        app = csvLine[0]
        intServer = csvLine[1]

        def barDeploy = new BarDeploy()
        barDeploy.app = app
        barDeploy.integrationServer = intServer
        csvItemsApps.add(barDeploy)


        //get shared libs
        if(csvLine.length > 2 && csvLine[2] != null)
        {
            def sharedLibs = csvLine[2].split(";")
            sharedLibs.each { libString ->
                if(!libString.isAllWhitespace())
                {
                    def lib = new BarDeploy()
                    lib.app = libString
                    lib.integrationServer = intServer
                    csvItemsLibs.add(lib)
                }
            };
        }
    }
};

//get list of bar files to deploy from html and consolidate bar files to deploy with apps in csv 
for (int i = 0; i < builds.size(); i+=3)
{
    if(builds[i].equals("false"))
    {
        //Don't deploy bar if checkbox isn't selected
        continue
    }

    foundInCSV = false

    appToDeploy = builds[i + 1]
    barFileToDeploy = builds[i + 2]

    iterator = csvItemsApps.iterator()
    while (iterator.hasNext())
    {
        barDeploy = iterator.next()
        if(appToDeploy.equalsIgnoreCase(barDeploy.app))
        {
            barDeploy.barFile = barFileToDeploy
            foundInCSV = true
        }
    }

    iterator = csvItemsLibs.iterator()
    while (iterator.hasNext())
    {
        barDeploy = iterator.next()
        if(appToDeploy.equalsIgnoreCase(barDeploy.app))
        {
            barDeploy.barFile = barFileToDeploy
            foundInCSV = true
        }
    }

    if(foundInCSV == false)
    {
        throw new RuntimeException("App: " + appToDeploy + " not found in ESB_Deployment_Map.csv. Please add CSV Entry.")
    }
}


//Do deploy, deploy shared libs first
deployCSVItemsInParallel(ip_address_node,port_node,branch,env_key,csvItemsLibs)
deployCSVItemsInParallel(ip_address_node,port_node,branch,env_key,csvItemsApps)


def deploy(ip_address_node,port_node,branch,deployItem,env_key)
{
    def integrationServer = deployItem.integrationServer
    def app = deployItem.app
    def barFile = deployItem.barFile

    if(barFile == null)
    {
        return;
    }

    println("Triggering Build -> ESB App = " + app +  ", Branch = " 
            + branch + ", Barfile: " + barFile + ", Integration Server = " + integrationServer + ", IP Address: " + ip_address_node 
            + ", Port: " + port_node + ", Env_Key: " + env_key)

    build_closure = { ->
        build("esb_deploybar", 
                      ip_address_node: ip_address_node, port_node: port_node,
                      integrationServer: integrationServer, branch: branch, app: app, barFile: barFile, env_key: env_key)
    }

    return build_closure
}

def deployCSVItemsInParallel(ip_address_node,port_node,branch,env_key,csvItems)
{
    def build_closures = []
    iterator = csvItems.iterator()
    while (iterator.hasNext())
    {
      barDeploy = iterator.next()
      def build_closure = deploy(ip_address_node,port_node,branch,barDeploy,env_key)

      if(build_closure != null)
      {
          build_closures.add(build_closure)
      }
    }

    if(build_closures?.size() > 0)
    {
         parallel(build_closures)
    }
}
4

6 回答 6

18

有一种情况我没有看到任何人提到。当作业应该在 Jenkins agent/slave上而不是在master上运行时，这是如何加载 Groovy 脚本的。

由于 master 是从 SCM 签出 Jenkins 管道项目的那个，Groovy 脚本只能在 master 的文件系统中找到。所以虽然这会起作用：

node {       
    def workspace = pwd() 
    def Bar = load "${workspace}@script/Bar.groovy"
    Bar.doSomething()
}

这只是一个快乐的巧合，因为从 SCM 克隆管道的节点与尝试在其中加载 groovy 脚本的节点相同。但是，只需添加要在其上执行的不同代理的名称：

node("agent1"){
    def workspace = pwd() 
    def Bar = load "${workspace}@script/Bar.groovy"
    Bar.doSomething()
}

将失败，导致：

java.io.IOException: java.io.FileNotFoundException: /Jenkins/workspace/Foo_Job@script/Bar.groovy (No such file or directory)

这是因为这条路径：

/Jenkins/workspace/Foo_Job@script/

仅存在于主 Jenkins 盒子上。不在运行agent1的框中。

因此，如果您遇到此问题，请确保将 groovy 脚本从 master 加载到全局声明的变量中，以便代理可以使用它们：

def Bar
node {       
    def workspace = pwd() 
    if(isUnix()){
        Bar = load "${workspace}@script/Bar.groovy"
    }
    else{
        Bar = load("..\\workspace@script\\Bar.groovy")
    }
}
node("agent1"){
    Bar.doSomething()
}

注意：用于在节点之间传递模块的变量必须在节点块之外声明。

于 2016-12-20T09:21:49.353 回答
13

如果 deploy_esb.groovy 文件存储在与 Jenkinsfile 相同的 SCM 中，您可以执行以下操作：

node {       
   def workspace = pwd() 
   load "${workspace}@script/esb_deploybar_pipeline/deploy_esb.groovy"
}
于 2016-06-29T19:44:06.360 回答
1

如果此 script.groovy 文件位于项目的根目录中，例如 Jenkinsfile，它将从 git 提取到与 Jenkinsfile 相同的文件夹中。因此，您使用的命令应该可以正常工作。

你有什么错误吗？如果有，请提供更多细节。

编辑：现在我可以看到你的 Jenkinsfile 中有什么，我可以看到你正在检查一个名为 integration_bus 的 git 项目，它是 groovy 脚本所在的位置。您可以像这样指定签出的位置：

checkout([$class: 'GitSCM', branches: [[name: '*/master']], doGenerateSubmoduleConfigurations: false, extensions: [[$class: 'RelativeTargetDirectory', relativeTargetDir: 'esb_deploy']], submoduleCfg: [], userRemoteConfigs: [[url: 'ssh://git@giturl/integration_bus.git']]])

与你所拥有的相反

git branch: branch, url: 'ssh://git@giturl/integration_bus.git'

然后你应该能够像这样引用 esb_deploy 文件夹中的 groovy 脚本

load 'esb_deploy/esb_deploybar_pipeline/deploy_esb.groovy'
于 2016-05-23T15:35:11.263 回答
0

您可以假设 中的所有文件操作Jenkinsfile都相对于当前工作区（这是load在 a中使用时的默认工作区node）。

因此，如果目标文件（例如deploy_esb.groovy）位于fooSCM 的文件夹中，则无需额外配置即可使用：

git branch: branch, url: 'ssh://git@giturl/integration_bus.git'
load 'foo/deploy_esb.groovy'

或者，如果要加载的文件与以下文件位于同一存储库中，则为Jenkinsfile：

checkout scm
load 'foo/deploy_esb.groovy'
于 2016-05-26T16:16:55.100 回答
0

这应该工作

load "${WORKSPACE}/../${JOB_NAME}@script/esb_deploy/esb_deploybar_pipeline/deploy_esb.groovy"
于 2018-07-17T14:40:39.897 回答
-1

有同样的问题。结束了额外的克隆操作以获取工作区目录下的脚本 repo 副本，因此我可以可靠地访问其中的 groovy 文件：

dir ('SCRIPTS_DIR') {
    checkout scm
    commonScripts = load 'subdir/Common.groovy' // no def, so script is global
}
于 2018-12-05T13:47:22.577 回答