31

我有一个 dataprovider 和一个分配给我的 dataprovider 的数组的 filter 函数。

当数据提供者 (item.data) 传递给过滤器函数时，如何获取其每一行中的属性列表？

例如，如果我的对象包含：

  • 目的
    • 姓名
    • 电子邮件
    • 地址

然后我希望在我的过滤器功能中能够查看姓名、电子邮件和地址。不幸的是，我事先不知道这些属性是什么。

有任何想法吗？

4

8 回答 8

55

如果它是一个动态对象，我相信你可以这样做：

var obj:Object; // I'm assuming this is your object

for(var id:String in obj) {
  var value:Object = obj[id];

  trace(id + " = " + value);
}

这就是它在 AS2 中的完成方式，我相信这仍然适用于 AS3 中的动态对象。我认为它将显示的属性在非动态对象上更加有限。

于 2008-12-16T19:40:36.777 回答
10

flash.utils.describeType(value:*)还将为您提供对象的属性列表。

于 2009-10-28T22:36:59.240 回答
7

for-in 仅适用于动态对象。对于类型化的对象，您需要使用某种反射来获取属性名称（例如http://www.as3commons.org/as3-commons-reflect/index.html）

/安德烈。

于 2009-07-17T14:08:43.003 回答
7

您可能正在寻找

ObjectUtil.getClassInfo(object)

，看：

http://livedocs.adobe.com/flex/3/langref/mx/utils/ObjectUtil.html#getClassInfo%28%29

请注意，其中存在一个错误，导致它将 XML 视为非动态数据类型。有关该错误的更多信息：bugs.adobe.com/jira/browse/SDK-17712

于 2009-10-28T22:26:34.213 回答
4

对我来说只有这个有用：

trace('obj = '+getProperties(obj));

        public static function getProperties(obj:*):String  {
            var p:*;
            var res:String = '';
            var val:String;
            var prop:String;
            for (p in obj) {
                prop = String(p);
                if (prop && prop!=='' && prop!==' ') {
                    val = String(obj[p]);
                    if (val.length>10) val = val.substr(0,10)+'...';
                    res += prop+':'+val+', ';
                }
            }
            res = res.substr(0, res.length-2);
            return res;
        }

你会得到这样的东西：

obj = m:email@ra..., r:true
于 2012-09-11T23:14:07.040 回答
2 
// this method will work for retrieving properties of a *non-dynamic* (typed) object

// @return - all object properties
public function getProperties(_obj : *) : Array
{
        var _description : XML = describeType(_obj);
        var _properties : Array = new Array();
        for each (var prop:XML in _description.accessor)
        {
                var _property : Object = new Object();
                _property.name = String(prop.@name);
                _property.type = String(simple_type(prop.@type));
                _property.access = String(prop.@access);
                _property.declaredBy = String(prop.@declaredBy);
                try
                {
                   _property.value = _obj[_property.name];
                }
                catch (e : Error)
                {
                   _property.value = "";
                }
                _properties.push(_property)
        }
        _properties.sortOn("name");
        return _properties;
}

// better format for object class information
private function simple_type(_type : String) : String
{
        var lastIndex : int = _type.lastIndexOf("::");
        _type = lastIndex > 0 ? _type.substr(lastIndex + 2) : _type;
        return _type;
}
于 2012-05-11T23:24:43.827 回答
1

您可以使用 for .. in 循环来获取属性名称，或者使用 for each .. in 循环来获取属性值...


for( var o : * in object){
    trace( o + " = " + object[o] );
}
/************* OR ******************/
for each( var o : * in object ){
    trace( "object has property: " + o );
}
于 2008-12-23T21:21:35.507 回答
1

这也将帮助您..
1. for 循环 - 将基于索引
2. for each - 递归调用，长度
不超过 3. for in - 用于读取属性值

     for( var obj : String in objectData ) //here objectData is your object
     {
        trace( "Object Name Is : " + obj );
        var data : Object = objectData[obj]; //here we get the object value by using the property name
        trace( "Value Is : " + data ); //Converts object to string
     }
于 2015-02-13T05:52:45.373 回答