5

我正在尝试解析一个包含一百万行的文件，每一行都是一个 json 字符串，其中包含有关一本书的一些信息（作者、内容等）。我正在使用iota加载文件，因为OutOfMemoryError如果我尝试使用slurp. 我也在使用cheshire来解析字符串。该程序只需加载一个文件并计算所有书籍中的所有单词。

我的第一次尝试包括pmap做繁重的工作，我认为这基本上会利用我所有的 cpu 内核。

(ns multicore-parsing.core
  (:require [cheshire.core :as json]
            [iota :as io]
            [clojure.string :as string]
            [clojure.core.reducers :as r]))


(defn words-pmap
  [filename]
  (letfn [(parse-with-keywords [str]
            (json/parse-string str true))
          (words [book]
            (string/split (:contents book) #"\s+"))]
    (->>
     (io/vec filename)
     (pmap parse-with-keywords)
     (pmap words)
     (r/reduce #(apply conj %1 %2) #{})
     (count))))

虽然它似乎确实使用了所有核心，但每个核心很少使用超过 50% 的容量，我的猜测是它与 pmap 的批量大小有关，所以我偶然发现了一些相对较老的问题，其中一些评论引用了clojure.core.reducers库.

我决定使用以下方法重写函数reducers/map：

(defn words-reducers
  [filename]
  (letfn [(parse-with-keywords [str]
            (json/parse-string str true))
          (words [book]
            (string/split (:contents book) #"\s+"))]
  (->>
   (io/vec filename)
   (r/map parse-with-keywords)
   (r/map words)
   (r/reduce #(apply conj %1 %2) #{})
   (count))))

但是 cpu 使用率更差，与之前的实现相比，它甚至需要更长的时间才能完成：

multicore-parsing.core=> (time (words-pmap "./dummy_data.txt"))
"Elapsed time: 20899.088919 msecs"
546
multicore-parsing.core=> (time (words-reducers "./dummy_data.txt"))
"Elapsed time: 28790.976455 msecs"
546

我究竟做错了什么？解析大文件时，mmap loading + reducers 是正确的方法吗？

编辑：这是我正在使用的文件。

EDIT2：以下是使用iota/seq而不是的时间iota/vec：

multicore-parsing.core=> (time (words-reducers "./dummy_data.txt"))
"Elapsed time: 160981.224565 msecs"
546
multicore-parsing.core=> (time (words-pmap "./dummy_data.txt"))
"Elapsed time: 160296.482722 msecs"
546
4

1 回答 1

3

我不相信 reducer 会成为适合您的解决方案，因为它们根本不能很好地处理惰性序列（reducer 会通过惰性序列给出正确的结果，但不会很好地并行化）。

您可能想看看这本书中的示例代码七周内的七个并发模型（免责声明：我是作者），它解决了一个类似的问题（计算每个单词在维基百科上出现的次数）。

给定一个 Wikipedia 页面列表，此函数按顺序计算单词（get-words从页面返回单词序列）：

(defn count-words-sequential [pages]
  (frequencies (mapcat get-words pages)))

这是一个并行版本，使用pmap它运行速度更快，但速度只有大约 1.5 倍：

(defn count-words-parallel [pages]
  (reduce (partial merge-with +)
    (pmap #(frequencies (get-words %)) pages)))

它只快 1.5 倍的原因是因为它reduce成为瓶颈——它(partial merge-with +)为每个页面调用一次。在 4 核机器上合并 100 个页面的批次可将性能提高到大约 3.2 倍：

(defn count-words [pages]
  (reduce (partial merge-with +)
    (pmap count-words-sequential (partition-all 100 pages))))
于 2016-05-16T16:24:32.877 回答