0

我evil-mode在 emacs 上使用，最近我开始使用eshell，我真的很喜欢如何离开插入模式并在eshell缓冲区上移动以复制内容或其他好东西，但是当再次进入插入模式时，它会在光标当前位置执行它，我会就像当我进入插入模式时自动将光标移动到提示行（最后一行，行尾）。

我所做的是：

(add-hook 'eshell-mode-hook
      (lambda()
         (define-key evil-normal-state-map (kbd "i") (lambda () (interactive) (evil-goto-line) (evil-append-line nil)))))

但是，它将此映射应用于所有其他缓冲区，我只想使其在 eshell 缓冲区上处于活动状态。

如何定义在 eshell 中工作方式不同的键绑定？

4

2 回答 2

2

感谢@lawlist 为我指明了正确的方向，解决方案非常简单：

;; Insert at prompt only on eshell
(add-hook 'eshell-mode-hook
      '(lambda ()
         (define-key evil-normal-state-local-map (kbd "i") (lambda () (interactive) (evil-goto-line) (evil-append-line nil)))))

谢谢！

于 2016-05-14T22:09:03.623 回答
2

当前接受的答案满足规定的要求，但有两个主要限制：

  1. 它仅在使用 进入插入模式时触发i。I使用、A、或任何自定义函数/键绑定跳转到最后一行a需要额外的脚本。
  2. 如果point已经在最后一行（例如，在编辑当前命令时），则无法在当前位置进入插入模式； i有效反弹至A。

第一个限制可以通过先上钩eshell-mode然后再上钩来消除evil-insert-state-entry。

第二个限制可以通过设置point位置来解决，首先基于行号，其次基于只读文本属性：

  1. 如果point不在最后一行，则将其移至point-max（始终为读写）。
  2. 否则，如果文本 atpoint是只读的，point则移动到当前行中只读文本属性更改的位置。

以下代码否定了已接受答案的限制。

(defun move-point-to-writeable-last-line ()
  "Move the point to a non-read-only part of the last line.
If point is not on the last line, move point to the maximum position
in the buffer.  Otherwise if the point is in read-only text, move the
point forward out of the read-only sections."
  (interactive)
  (let* ((curline (line-number-at-pos))
         (endline (line-number-at-pos (point-max))))
    (if (= curline endline)
        (if (not (eobp))
            (let (
                  ;; Get text-properties at the current location
                  (plist (text-properties-at (point)))
                  ;; Record next change in text-properties
                  (next-change
                   (or (next-property-change (point) (current-buffer))
                       (point-max))))
              ;; If current text is read-only, go to where that property changes
              (if (plist-get plist 'read-only)
                  (goto-char next-change))))
      (goto-char (point-max)))))

(defun move-point-on-insert-to-writeable-last-line ()
  "Only edit the current command in insert mode."
  (add-hook 'evil-insert-state-entry-hook
        'move-point-to-writeable-last-line
        nil
        t))

(add-hook 'eshell-mode-hook
      'move-point-on-insert-to-writeable-last-line)
于 2017-10-25T16:45:11.643 回答