2

尝试编写将在 WinPE 中运行的脚本，该脚本实质上获取 localhost 的 IP 地址并根据 IP 范围选择操作。

在 Windows 中，脚本运行完美。但是，在 WinPE 中，我收到以下错误：

script.vbs(1,1) Microsoft VBScript 运行时错误：下标超出范围

Google-fu 告诉我这与我的数组超出范围有关。在这里，我以为我有一个不错的理解，但显然不是。

在 Windows 上按原样运行的代码：

Option Explicit

Dim sIP, sHostname,sPingBat
Dim aIP
Dim iOct1, iOct2, iOct3, iOct4, iReturn
Dim oWMIService, oCmd, oAdapter
Dim cAdapters

iReturn = 999
sHostname = "."
Set oWMIService = GetObject("winmgmts:{impersonationLevel=impersonate}!\\" & sHostname & "\root\cimv2")
Set cAdapters = oWMIService.ExecQuery("Select IPAddress from Win32_NetworkAdapterConfiguration Where IPEnabled = True")
Set oCmd = CreateObject("Wscript.Shell")

For Each oAdapter in cAdapters
    If Not IsNull(oAdapter.IPAddress) Then 
        sIP = Trim(oAdapter.IPAddress(0))
    Else
        iReturn = 404
        WScript.Quit iReturn
    End If
Next

sIP = CStr(sIP)

aIP = Split(sIP, ".")

iOct1 = CInt(aIP(0))
iOct2 = CInt(aIP(1))
iOct3 = CInt(aIP(2))
iOct4 = CInt(aIP(3))

现在，如果我将 aIP 数组的声明更改为以下任一：

aIP()
aIP(4)

并运行

aIP = Split(sIP, ".")

我明白了

script.vbs(26, 1) Microsoft VBScript 运行时错误：类型不匹配

将数组分配/分割线更改为

aIP() = Split(sIP,".")

结果是

script.vbs(26, 1) Microsoft VBScript 运行时错误：下标超出范围

所以我显然做错了什么。

我的原始错误消息也完全有可能与我的数组范围完全无关，而 WinPE 只是不喜欢我的脚本（在这种情况下，如果有人有任何指针，将不胜感激）

目前，我正在安装我的 wim 以获取安装包，以确保从 ADK 安装 WMI 和脚本包。

4

2 回答 2

1

除了假设Win32_NetworkAdapterConfiguration返回的内容之外，代码没有任何问题。

来自MSDN - Win32_NetworkAdapterConfiguration 类
与当前网络适配器关联的所有 IP 地址的数组。此属性可以包含 IPv6 地址或 IPv4 地址。有关详细信息，请参阅WMI 中的 IPv6 和 IPv4 支持。

因为sIP可能包含 IPv6 地址，所以Split()无法按预期工作。IPv6 地址不包含.分隔符，因此Split()将返回一个仅包含原始字符串作为第一个索引的数组。因此，尝试阅读其他内容aIP(0)将导致

Microsoft VBScript 运行时错误：
下标超出范围

错误。

为了避免这种使用InStr()首先检查变量是否存在.，sIP您还需要遍历oAdapter.IPAddress数组以检查每个地址以获得正确的地址，您不能假设IPAddress(0)总是正确的。

尝试这个

Dim ips, ip

For Each oAdapter in cAdapters
    ips = oAdapter.IPAddress
    If IsArray(ips) Then
        For Each ip In ips
            If InStr(1, ip, ".") > 0 Then
                sIP = Trim(ip)
                Exit For
            End If
        Next
        If Len(sIP) > 0 Then Exit For
    Else
        iReturn = 404
        WScript.Quit iReturn
    End If
Next

在 iPad 上未经测试抱歉

于 2016-04-28T09:23:01.970 回答
0

我猜sIP变量包含一些不能用分隔符分割的字符串"."（例如：“somestringwithNoDOT”）

所以在第一种情况下

aIP = Split(sIP,".")   ' Split("somestringwithNoDOT",".")

语句只返回 1 个字符串，不能转换为 Integer。所以我在下面的行中返回了类型不匹配错误

iOct1 = CInt(aIP(0))  ' returns Type mismatch error

在第二种情况下

aIP() = Split(sIP,".")  ' Split("somestringwithNoDOT",".")

上面的语句将返回 1 个元素，但 aIParray没有元素。所以这个语句 rturned "Subscript out of range"错误

此问题的解决方法是检查是否将正确的值传递给sIP

于 2016-04-27T23:47:18.760 回答