6

我正在构建一种向用户显示对话框的方法。

data DialogConfig t m b e =
  DialogConfig { _dialogConfig_title :: Dynamic t T.Text
               , _dialogConfig_content :: b -> m (Dynamic t (Maybe b))
               , _dialogConfig_footer :: Dynamic t (Maybe b) -> m (Event t e)
               }
dialog :: MonadWidget t m =>
           DialogConfig t m b e -> Event t b -> m (Event t (DialogEvent e))

我想使用某种“默认”实例来初始化DialogConfig该dialog函数，以便可以将其用作例如defaultConfig{_dialogConfig_content=content}. 但是，我正在与类型推断作斗争。这有效：

confirmDialog :: forall t m. MonadWidget t m =>
                 T.Text -> Event t T.Text -> m (Event t ())
...
evt <- dialog
         (DialogConfig { _dialogConfig_title = constDyn title
                       , _dialogConfig_content = content
                       , _dialogConfig_footer = buttons}
                       ) contentEvt

但是，当我使用一些默认值DialogConfig（例如，这里直接内联它）时，它不会：

evt <- dialog
      (DialogConfig { _dialogConfig_title = constDyn mempty
                    , _dialogConfig_content = const $ return $ constDyn Nothing
                    , _dialogConfig_footer = const $ return never }
                    { _dialogConfig_title = constDyn title
                    , _dialogConfig_content = content
                    , _dialogConfig_footer = buttons}
                    ) contentEvt

错误是：

Could not deduce (Reflex t0) arising from a use of ‘constDyn’ from the context (MonadWidget t m)
Could not deduce (Monad t1) arising from a use of ‘return’ from the context (MonadWidget t m)

我可以在as中使用ScopedTypeVariables并键入默认配置，这样就可以了，但是即使没有它，它也不应该工作吗？在我看来，这些类型相当明确。confirmDialogDialogConfig t m a b

4

1 回答 1

4

正如评论中提到的，问题在于记录更新可以改变记录的类型（起初可能会令人惊讶）。这是 GHCi 中的一个测试：

> data T a = T { tA :: a }
> let x = T "foo"
> :t x
x :: T [Char]
> :t x { tA = True }
x { tA = True } :: T Bool

所以，我们不能定义一个默认值：

> let def :: Read a => T a ; def = T (read "True")
> :t def :: T Bool
def :: T Bool :: T Bool
> :t def { tA = 5 }
   Could not deduce (Read t0) arising from a use of ‘def’
   The type variable ‘t0’ is ambiguous

实际上，上面def可以是任何类型。

一个可能的解决方案可能是通过要求T a -> T a延续函数来强制更新具有相同的类型。

> let defF :: Read a => (T a -> T a) -> T a ; defF f = f (T (read "True"))
> :t defF (\d -> d { tA = False })
defF (\d -> d { tA = False }) :: T Bool

以上d是默认值，通过构造，更新后必须具有相同类型的记录。

使用镜头，可能会有更好的方法。

于 2016-04-27T09:02:04.923 回答