57

在阅读了解释Pipeline插件的Jenkins教程后，似乎插件应该可以实现Post-Build步骤。然而，关于具体说明的文档相当有限。

例如我想知道如何实现：

  • 仅在构建成功时运行
  • 仅在构建成功或不稳定时运行
  • 不管构建结果如何运行

  • 仅在构建成功时运行

    stage 'build'
... build
... tests
stage 'post-build'
...

    （或添加-Dmaven.test.failure.ignore=false到MAVEN_OPTS）

  • 仅在构建成功或不稳定时运行

    stage 'build'
... build
try {
    ... tests
} catch {
    ...
}
stage 'post-build'
...

    （或添加-Dmaven.test.failure.ignore=true到MAVEN_OPTS）

  • 无论构建结果如何都运行- 可以使用try / catch / finally吗？

    try {
    stage 'build'
    ...
} catch {
    ...
} finally {
    stage 'post-build'
    ...
}

（我注意到最终构建状态设置为成功，即使某些阶段，即“构建”，由于它基于最后阶段设置而失败。这是否意味着最终构建状态需要明确设置，即。currentBuild.result = 'UNSTABLE'？）

4

4 回答 4

47

最好的方法是在管道脚本中使用构建后操作。

处理失败
声明式管道默认通过其 post 部分支持健壮的失败处理，该部分允许声明许多不同的“后置条件”，例如：always、unstable、success、failure 和 changed。Pipeline Syntax 部分提供了有关如何使用各种后置条件的更多详细信息。

Jenkinsfile（声明式管道）

pipeline {
    agent any
    stages {
        stage('Test') {
            steps {
                sh 'make check'
            }
        }
    }
    post {
        always {
            junit '**/target/*.xml'
        }
        failure {
            mail to: team@example.com, subject: 'The Pipeline failed :('
        }
    }
}

文档在 https://jenkins.io/doc/book/pipeline/syntax/#post下面

于 2017-03-22T10:14:56.070 回答
6

FWIW，如果您使用的是脚本化管道而不是声明性的，则应使用try/catch/finally其他答案中建议的块。在finally块中，如果您想模仿声明性管道的功能，您可以将以下内容直接放入块中，或者将其设为函数并从finally块中调用该函数：

def currResult = currentBuild.result ?: 'SUCCESS'
def prevResult = currentBuild.previousBuild?.result ?: 'NOT_BUILT'

// Identify current result
boolean isAborted = (currResult == 'ABORTED')
boolean isFailure = (currResult == 'FAILURE')
boolean isSuccess = (currResult == 'SUCCESS')
boolean isUnstable = (currResult == 'UNSTABLE')

boolean isChanged = (currResult != prevResult)
boolean isFixed = isChanged && isSuccess && (prevResult != 'ABORTED') && (prevResult != 'NOT_BUILT')
boolean isRegression = isChanged && currentBuild.resultIsWorseOrEqualTo(prevResult)

onAlways()
if (isChanged) {
    onChanged()
    if (isFixed) {
        onFixed()
    } else if (isRegression) {
        onRegression()
    }
}
if (isSuccess) {
    onSuccess()
} else {
    if (isAborted) {
        onAborted()
    }
    onUnsuccessful()
    if (isFailure) {
        onFailure()
    }
    if (isUnstable) {
        onUnstable()
    }
}
onCleanup()

各种onXYZ()调用是您定义的用于处理该特定条件的函数，而不是使用更好的声明性post块语法。

于 2019-01-17T21:45:10.710 回答
5

如果您正在使用 try/catch 并且希望将构建标记为不稳定或失败，那么您必须使用 currentBuild.result = 'UNSTABLE' 等。我相信像 JUnit Report 插件这样的插件会在发现失败时为您设置在junit结果中进行测试。但在大多数情况下，如果你发现错误，你必须自己设置它。

如果您不想继续，第二个选项是重新抛出错误。 

stage 'build'
... build
try {
    ... tests
} catch(err) {
    //do something then re-throw error if needed.
    throw(err)
}
stage 'post-build'
...
于 2016-06-21T17:30:58.103 回答
2

try-catch可以设置块来处理实际应用程序代码中的错误。

例如：

try {
    node {
        sh 'sleep 20' // <<- can abort here
    }
} catch (Exception e) {
    println 'catch'
} finally {
    println 'finally'
}

node {
    println 'second'
}

try {
    node {
        sh 'sleep 20' // <<- can abort here again
    }
} catch (Exception e) {
    println 'catch'
} finally {
    println 'finally'
}

这是一个带有两个中止的示例输出。

Started by user me
Replayed #3
[Pipeline] node
Running on my-node in /var/lib/jenkins-slave/workspace/my-job
[Pipeline] {
[Pipeline] sh
[my-job] Running shell script
+ sleep 20

Aborted by me

Sending interrupt signal to process

/var/lib/jenkins-slave/workspace/my-job@tmp/durable-9e1a15e6/script.sh: line 2: 10411 Terminated              sleep 20
[Pipeline] }
[Pipeline] // node
[Pipeline] echo
catch
[Pipeline] echo
finally
[Pipeline] node
Running on my-node in /var/lib/jenkins-slave/workspace/my-job
[Pipeline] {
[Pipeline] echo
second
[Pipeline] }
[Pipeline] // node
[Pipeline] node
Running on my-node in /var/lib/jenkins-slave/workspace/my-job
[Pipeline] {
[Pipeline] sh
[my-job] Running shell script
+ sleep 20

Aborted by me

Sending interrupt signal to process
/var/lib/jenkins-slave/workspace/my-job@tmp/durable-d711100c/script.sh: line 2: 10416 Terminated              sleep 20
[Pipeline] }
[Pipeline] // node
[Pipeline] echo
catch
[Pipeline] echo
finally
[Pipeline] End of Pipeline
Finished: ABORTED

当然，这适用于执行期间发生的任何异常。

于 2016-11-07T14:58:27.090 回答