2

我网站的 URI 结构最近发生了巨大变化，我需要将所有旧页面重定向到相应的新页面。我有一个所有新旧 URI 对的点列表。目前我正在尝试为每个循环定义简单的处理程序：

(let ((redirects '(("/old/uri/example-1" . "/new/uri/example-1"))))
  (dolist (redirect redirects)
    (hunchentoot:define-easy-handler (???? :uri (first redirect)) ()
       (redirect (rest redirect)))
    ))

也许有更好的方法。假设 define-easy-handler 是正确的，它需要每个简单处理程序的函数符号。我尝试了以下方法无济于事：

  1. 将 (gensym) 放置在需要函数符号的位置
  2. 使用列表而不是点列表并在需要符号的地方调用（第一次重定向）
  3. 在整个事物周围放置一个 quasiquote 并在周围放置一个 unquote（第一个重定向）

什么是实现这一目标的好方法？

4

3 回答 3

5

让我们猜猜：DEFINE-EASY-HANDLER是一个宏。

解决该问题的三种典型方法：

  • 调用底层而不使用宏 - 如果底层可供程序员使用

  • 编写并使用一个宏

扩展(defredirects (a . a1) (b . b1) (c . c1)))到

(progn
  (hunchentoot:define-easy-handler (f-a ... a) () (... a1))
  (hunchentoot:define-easy-handler (f-b ... b) () (... b1))
  (hunchentoot:define-easy-handler (f-c ... c) () (... c1)))
  • 在每个表单的循环中生成您想要调用和使用eval（或compile如果可能）的表单。funcall
于 2016-04-10T21:15:55.940 回答
2

虽然你已经解决了这个问题，但我想我可以添加这个作为替代方案。如果你不想制作一个完整的自定义接受器，你可以在HUNCHENTOOT:ACCEPTOR-DISPATCH-REQUESTfor上添加一个 around-method HUNCHENTOOT:EASY-HANDLER。

让我们先做一个接受者和一个页面：

(defparameter *acceptor* (make-instance 'hunchentoot:easy-acceptor :port 4242))

(hunchentoot:define-easy-handler (foo :uri "/foo") ()
  (format nil "<html><body><h1>Test</h1><p>foo</p></body></html>"))

(hunchentoot:start *acceptor*)

然后重定向/bar到/quux：/foo

;; A simple helper to create prefix dispatchers.
(defun make-redirect-list (redirects)
  (mapcar (lambda (redirect)
            (destructuring-bind (from . to) redirect
              (hunchentoot:create-prefix-dispatcher from
                                                    (lambda ()
                                                      (hunchentoot:redirect to)))))
          redirects))

(defparameter *redirects* (make-redirect-list
                           '(("/bar" . "/foo")
                             ("/quux" . "/foo"))))

(defmethod hunchentoot:acceptor-dispatch-request :around
    ((acceptor hunchentoot:easy-acceptor) request)
  (dolist (redirect *redirects*)
    ;; Match the request against the prefix dispatchers in *REDIRECTS*...
    (let ((handler (funcall redirect request)))
      (when handler
        ;; and call the corresponding handler if a match is found.
        (return-from hunchentoot:acceptor-dispatch-request
          (funcall handler)))))
    ;; Unless a handler was found, call next method to 
    ;; handle the request normally.
  (call-next-method))

编辑：使用 around 方法而不是 before。我最初认为让它正常调用 main 方法对于任何日志记录/等都是必要的。在那里发生，但经过进一步测试后似乎没有。

于 2016-04-12T04:38:36.203 回答
1

此解决方案有效。我非常感谢有关这是否是最佳实践的反馈。

(defun add-redirect (name from to)
  (eval `(hunchentoot:define-easy-handler (,name :uri ,from) ()
    (redirect ,to))))

(defun add-redirects (redirects)
  (dolist (redirect redirects)
    (add-redirect (first redirect) (second redirect) (third redirect))
    ))

(add-redirects
 '(
   (redirect-1 "/redirect-1/" "/destination-1/")
   (redirect-2 "/redirect-2/" "/destination-2/")
   (redirect-3 "/redirect-3/" "/destination-3/")
   ))
于 2016-04-12T01:22:37.847 回答