5

我正在使用 XSLT1.0 来转换我的 XML。

我在 Tabs.xml 下面

<?xml version="1.0"?>
<tcm:ListItems xmlns:tcm="http://www.tridion.com/ContentManager/5.0" ID="tcm:481-87289-4" Managed="68">
  <tcm:Item ID="tcm:481-596728-64" Title="T000. Brisbane" pageURL="/australia/brisbane/index.aspx" componentTitle="Overview"/>
  <tcm:Item ID="tcm:481-598671-64" Title="Tabs XML"/>
  <tcm:Item ID="tcm:481-598672-64" Title="T030 Special Offers" pageURL="/australia/brisbane/specialoffers.aspx" componentTitle="Special Offers"/>
  <tcm:Item ID="tcm:481-598673-64" Title="020 Flight Schedules" pageURL="/australia/brisbane/flightschedules.aspx" componentTitle="Flight Schedules"/>
  <tcm:Item ID="tcm:481-598674-64" Title="T010 Guide" pageURL="/australia/brisbane/guide.aspx" componentTitle="Guide"/>
</tcm:ListItems>

我正在使用下面的 xslt 来改造它！

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:tcm="http://www.tridion.com/ContentManager/5.0" xmlns:xlink="http://www.w3.org/1999/xlink" xmlns:em="http://www.emirates.com/tridion/schemas" xmlns:tcmse="http://www.tridion.com/ContentManager/5.1/TcmScriptAssistant" exclude-result-prefixes="em xlink tcmse tcm">
  <xsl:output method="xml" version="1.0" encoding="UTF-16" indent="yes"/>
  <xsl:template match="tcm:ListItems">
    <list type="Tabs">
      <xsl:apply-templates select="tcm:Item">
        <xsl:sort select="@Title" order="ascending"/>
      </xsl:apply-templates>
    </list>
  </xsl:template>
  <!-- add field values for each item-->
  <xsl:template match="tcm:Item">
    <xsl:if test="@componentTitle != ''">
      <xsl:element name="tab">
        <xsl:attribute name="id">
          <xsl:value-of select="substring-after(@ID, '-')"/>
        </xsl:attribute>
        <xsl:attribute name="title">
          <xsl:value-of select="@componentTitle"/>
        </xsl:attribute>
        <xsl:attribute name="url">
          <xsl:value-of select="@pageURL"/>
        </xsl:attribute>
      </xsl:element>
    </xsl:if>
  </xsl:template>
</xsl:stylesheet>

以前，它工作正常，但现在需要进行另一项更改，现在我需要渲染那些@Title 以'T'或't'开头的节点，以及下一个3字符应该是数字，例如上面的xml“航班时刻表”不应该出现，我想我只需要再写一个和条件<xsl:if test="@componentTitle != ''">，

请建议！怎么办！

4

5 回答 5

2

这是进行匹配的最简单的表达式：

translate(substring(@Title, 1, 4), 't12345679', 'T000000000') = 'T000'

这是模板：

<xsl:template match="
 tcm:Item[translate(substring(@Title, 1, 4), 't12345679', 'T000000000') = 'T000'
 and @componentTitle != '' "/>
于 2010-09-09T12:33:35.967 回答
1

选择逻辑最好放在模板的匹配模式中——也可以稍微简化一下。

<xsl:template match=
 "tcm:Item[contains('tT', substring(@Title,1,1))
         and
           number(substring(@Title,2,3)) 
          =    
           number(substring(@Title,2,3)) 
          ]
 ">

要记住的一条规则：总是测试某个字符串是否$s代表一个数字——像这样：

number($s) = number($s)

于 2010-09-05T14:25:40.727 回答
1

您应该在元素的模板中选择要操作的节点：apply-templates

<xsl:apply-templates select="tcm:Item[@componentTitle != '' 
                           and (starts-with(translate(@Title, 't', 'T'), 'T') 
                           and string(number(substring(@Title,2,3))) != 'NaN')]">

我已经使用了@solution 为此生成的测试 - 它适用于要求（在此处测试）。

这比选择所有tcm:Item节点并在模板中一次测试一个要好。

于 2010-09-05T07:49:39.757 回答
0

只是偶尔使用 XSLT，我想出了以下解决方案：

<xsl:if test="@componentTitle != ''">
  <xsl:if test="starts-with(@Title,'T') or starts-with(@Title,'t')"> 
    <xsl:if test="string-length(@Title) &gt; 3">
      <xsl:if test="string(number(substring(@Title,2,3))) != 'NaN'"> 
...
      </xsl:if>
    </xsl:if>
  </xsl:if>
</xsl:if>

我注意到还有一些函数lower-case/upper-case可用于测试第一个字符是 a torT但它们似乎仅在 XSLT2.0 中可用。

于 2010-09-05T07:15:11.697 回答
-1

我想出了以下解决方案，请建议是否可以！

<xsl:template match="tcm:Item">
    <xsl:if test="@componentTitle != '' and (starts-with(translate(@Title, 't', 'T'), 'T')and string(number(substring(@Title,2,3))) != 'NaN')">
      <xsl:element name="tab">
        <xsl:attribute name="id">
          <xsl:value-of select="substring-after(@ID, '-')"/>
        </xsl:attribute>
        <xsl:attribute name="title">
          <xsl:value-of select="@componentTitle"/>
        </xsl:attribute>
        <xsl:attribute name="url">
          <xsl:value-of select="@pageURL"/>
        </xsl:attribute>
      </xsl:element>
    </xsl:if>
  </xsl:template>

您的所有输入都是必需的！

于 2010-09-05T07:25:19.020 回答