8

我有一个类层次结构，这个：

type
TMatrix = class
    protected
      //...
    public
      constructor Create(Rows, Cols: Byte);
    //...
type
  TMinMatrix = class(TMatrix)
    private
      procedure Allocate;
      procedure DeAllocate;
    public
      constructor Create(Rows, Cols: Byte);
      constructor CreateCopy(var that: TMinMatrix);
      destructor Destroy;
  end;

如您所见，派生类和基类构造函数都具有相同的参数列表。我从派生的一个显式调用基类构造函数：

constructor TMinMatrix.Create(Rows, Cols: Byte);
begin
   inherited;
   //...
end;

Delphi中是否需要显式调用基类构造函数？可能我需要超载或覆盖以清除我打算做什么？我知道如何在 C++ 中做到这一点——只有当你想向它传递一些参数时，你才需要显式调用基类构造函数——但我在 Delphi 编程方面没有太多经验。

4

4 回答 4

14

据我所知，这里有两个不同的问题：

确保子类的构造函数调用基类的构造函数

您必须显式调用基类的构造函数：

constructor TMinMatrix.Create(Rows, Cols: Byte);
begin
   inherited;
   //...
end;

确保子类的构造函数覆盖基类的构造函数

您还必须创建子类的构造函数override和基类的构造函数virtual，以确保编译器看到两者之间的关系。如果您不这样做，编译器可能会警告您 TMinMatrix 的构造函数“隐藏”了 TMatrix 的构造函数。所以，正确的代码是：

type
TMatrix = class
    protected
      //...
    public
      constructor Create(Rows, Cols: Byte); virtual;    // <-- Added "virtual" here
      //...
type
  TMinMatrix = class(TMatrix)
    private
      //...
    public
      constructor Create(Rows, Cols: Byte); override;   // <-- Added "override" here
      constructor CreateCopy(var that: TMinMatrix);
      destructor Destroy; override;                     // <-- Also make the destructor "override"!
  end;

请注意，您还应该使您的析构函数override。

引入具有不同参数的构造函数

请注意，您只能覆盖具有相同参数列表的构造函数。如果子类需要不同参数的构造函数，并且你想防止基类的构造函数被直接调用，你应该写：

type
TMyMatrix = class(TMatrix)
//...
public
  constructor Create(Rows, Cols, InitialValue: Byte); reintroduce; virtual;
//...
end

implementation

constructor TMyMatrix.Create(Rows, Cols, InitialValue: Byte);
begin
  inherited Create(Rows, Cols);   // <-- Explicitly give parameters here
  //...
end;

我希望这能让事情更清楚......祝你好运！

于 2008-12-11T20:04:23.610 回答
3

重载，告诉编译器一个方法同名但参数不同。

Override，告诉编译器一个方法覆盖它在基类中声明的虚拟或动态。

重新引入，将隐藏基类中声明的虚拟或动态方法。

这些定义来自 Ray Lischner 的书 {Delphi in a nutshell}

type
  TFirst = class
  private
    FValue: string;
    FNumber: Integer;
  public
    constructor Create(AValue: string; ANumber: integer);

    property MyValue: string read FValue write FValue;
    property MyNumber: Integer read Fnumber write FNumber; 
  end;

  TSecond = class(TFirst)
  public
    constructor Create(AValue: string; ANumber: Integer);
  end;

constructor TFirst.Create(AValue: string; ANumber: integer);
begin
  MyValue := AValue;
  MyNumber := ANumber;
end;

{ TSecond }

constructor TSecond.Create(AValue: string; ANumber: Integer);
begin
  inherited;
end;

声明的 TSecond 将调用 TFirst 的创建，如果没有继承，TSecond 成员将保持为空。

于 2008-12-11T20:07:08.237 回答
3

您需要显式调用继承的方法；德尔福不会为你做这件事。这是设计使然，因为在某些情况下您正在使用虚拟方法，例如，当您不想调用继承的行为时。

另外，出于个人喜好，我喜欢完整地写出继承的调用。(继承Create(Rows, Cols); 而不是仅仅继承;原因很简单：它使遍历代码变得更加容易。如果你写出了一个方法调用，你可以控制并单击它并获取到祖先方法。

于 2008-12-12T18:42:08.680 回答
2

如果两个构造函数具有相同的名称，则它们需要重载。

type
  TMatrix = class
  protected
    //...
  public
    constructor Create(Rows, Cols: Byte);
    //...
type
  TMinMatrix = class(TMatrix)
  public
    constructor Create(Rows, Cols: Byte); overload;
    constructor Create(var that: TMinMatrix); overload;
  end;

调用继承的构造函数是个好习惯。

constructor TMinMatrix.Create(Rows, Cols: Byte);
begin
   inherited Create(Rows, Cols); // Need to call the full name if the parameters are changed.
   //...
end;
于 2008-12-11T20:02:34.940 回答