3

我有一个用于构建信息亭环境的 HTML 应用程序。在每个会话结束时（当用户单击“注销”或超时后）我希望 HTA 自行关闭并重新启动*。我想知道如何使用 VBScript 以编程方式实现这一目标。

这个过程应该是这样的

  • 用户点击“退出”或如果 5 分钟没有输入
  • 删除临时 Internet 文件
  • 关闭 HTA
  • 重新打开 HTA

这是我遇到麻烦的重新开放部分。

我确实考虑过的一件事是；在关闭应用程序之前，设置一个只运行一次的计划任务以再次运行 HTA。我不认为这是一个非常优雅的解决方案:(

谢谢你们的帮助！

干杯

伊恩

.* 我希望 HTA 自行重启的原因是，在长时间使用后，开始发生奇怪的事情，我认为这与 mshta.exe 或 IE 引擎中的错误有关。我的 HTA 非常依赖于动态创建的 IFRAME，并且由于某种原因，HTA 无法在它们关闭后正确清理它们。详细解释这个错误有点困难，但奇怪的一个例子是；我生成了一个新的 IFRAME，当我询问 DOM 时，一切看起来都应该如此，但浏览器呈现的是之前关注的 IFRAME 中的任何内容。

4

2 回答 2

3

注销或超时时，HTA 会运行重新启动脚本，然后退出。重新启动脚本等待 MSHTA 进程消失，然后重新启动它并自行退出。

这可以通过使用 WMI 扫描正在运行的进程并查找命令行参数包含 HTA 名称的 MSHTA.EXE 实例来完成。

这是一个小例子来证明这一点。

这是一个准系统 HTA，将其保存为 RestartTest.hta：

<html> <!-- RestartTest.hta -->
<head>
<title>Self Restarting HTA Test</title>

<script language="VBScript">
sub RunApp(sApp)
  CreateObject("WScript.Shell").Run(sApp)
end sub
sub LogOff()
  RunApp "cscript.exe RestartHTA.vbs"
  MsgBox "simulating delayed exit - click to close"
  window.close()
end sub
</script>
</head>

<body >
<input type="button" value="Log off" onClick="LogOff()" />
</body>
</html>

这是重启脚本，另存为RestartHTA.vbs：

' RestartHTA.vbs'
' wait until RestartTest.hta is not running and restart it.'

MSHTA = "mshta.exe"
sHTA = "RestartTest.hta"

say "waiting for process " & MSHTA & " with param " & sHTA & " to end"
secs = 2000

bRunning = vbTrue
do while bRunning
  if ProcessRunning(MSHTA, sHTA) then
    say "still running, wait a few seconds"
    WScript.Sleep secs
  else
    bRunning = vbFalse
  end if
loop

say "HTA not found, proceding to restart"
WScript.Sleep secs

CreateObject("WScript.Shell").Run(sHTA)
WScript.Quit

'---'

function ProcessRunning(sProcess, sParam)
  set oWMI = GetObject( _
    "winmgmts:{impersonationLevel=impersonate}!\\.\root\cimv2")
  set cProcs = oWMI.ExecQuery( _
    "select * from Win32_Process where Name = '" & sProcess & "'")

  bFound = vbFalse
  for each oProc in cProcs
    say oProc.Name & ": " & oProc.CommandLine
    if (InStr(oProc.CommandLine, sParam) > 0) then
      say "found"
      bFound = vbTrue
    else
      say "wrong param"
    end if
  next

  ProcessRunning = bFound
end function

sub Say(s)
  WScript.Echo s
end sub

'==='

您可以运行任何一个来启动循环，然后只需使用 X 按钮关闭 HTA 即可中断它。请注意，我使用 CScript 显式运行重启脚本。这只是为了演示目的而显示它的控制台输出（并且由于某种原因，我在设置和将 CScript 保持为我的机器上的默认值时遇到了麻烦）。

于 2010-09-18T15:09:08.317 回答
2

看看下面的代码：

<html>
    <title>HTA Restart</title>
    <head>
    <HTA:APPLICATION
        Id="oHTA"
        Border="thick"
        InnerBorder="no"
        Scroll="no"/>
    </head>
    <script language="vbscript">
        Sub Restart()
            CreateObject("WScript.Shell").Run "mshta " & oHTA.commandLine
            window.close
        End Sub
    </script>
    <body style="background-color: buttonface;">
        <input type="button" value="Logout" onclick="Restart()" />
    </body>
</html>
于 2016-09-29T17:01:39.143 回答