1

我想要一个分派异步任务并立即返回的方法。我不需要等待结果。我想要这样的工作：

/**
* runs a job and return job id for later montoring.
*/
def int runJob(){
  int jobId = createJob() // returns immediately
  task{
    doSomthingThatTakesSomeTime()
  }.then {stepResult-> doSmtgElse(stepResult)}
  return jobId
}

在上述情况下，任务不会运行，因为没有调用 .get() ，但是，如果我执行 .get() ，该方法将不会返回 jobId 直到任务完成。

我怎样才能分派任务并仍然立即返回？

4

2 回答 2

1

您可以将此示例作为 Groovy 脚本运行：

    @Grapes(
        @Grab(group='org.codehaus.gpars', module='gpars', version='1.2.1')
    )

    import java.util.concurrent.*
    import groovyx.gpars.*

    def doSomethingThatTakesSomeTime(){
        println "calculating..."
        for(long i: 0..100){
            Thread.sleep(i)
        }

        println "*done*"
        "Done with doSomethingThatTakesSomeTime"
    }

    def doSomethingElse(){
        for(int x:0..1000) print "."
        println "doSomethingElse done."
    }


    /**
    * runs a job and return job id for later montoring.
    */
    def runJob(){
        GParsPool.withPool(){
            Future future = createJob() // returns immediately
            doSomethingElse() //Do someting else while the async process is running
            //Ok, thats done, but the longer runningprocess is still running, return the future
            future
        }
    }

    Future createJob(){
        //create a new closure, which starts the original closure on a thread pool
        Closure asyncFunction = { doSomethingThatTakesSomeTime() }.async()

        //Invoke the function, return a Future
        asyncFunction()
    }

    def job = runJob()
    //println "\n\nResult is: " + job.get()

如果您“按原样”运行脚本，您将看到它运行并且长时间运行的作业确实打印*done*表明它确实运行到完成，即使底部调用的行Future.get()被注释掉并且从未调用过。

如果您取消注释最后一行，您将看到由于调用完成而打印的结果Future.get()

于 2016-03-06T16:14:05.053 回答
1

在阅读了@pczeus 的回答和 Jérémie B 的评论后，我想到了这个：

import static groovyx.gpars.dataflow.Dataflow.task

def int longTask(){
    def counter = 0
    10.times {
        println "longTask_${counter}"
        counter++
        sleep 10
    }
    counter
}

def int getSomeString() {
    def jobId=55
    task {
        longTask()

    }.then { num -> println "completed running ${num} times" }
    return  jobId
}
println getSomeString()

sleep 2000

这打印：

longTask_0
55
longTask_1
longTask_2
longTask_3
longTask_4
longTask_5
longTask_6
longTask_7
longTask_8
longTask_9
completed running 10 times

这就是我的意图：longTask() 在后台运行，getSomeString() 在不等待长任务的情况下重新运行，并且只要程序仍在运行（因此 sleep 2000），即使是 '然后'部分被执行

于 2016-03-06T19:10:59.167 回答