5

场景是这样的：我有一个包含项目的 ArangoDB 集合，以及另一个包含标签的集合。我正在使用图表，并且我有一个名为“包含”的边缘集合连接项目和标签。一个项目有多个标签。

现在我正在尝试搜索包含多个标签的项目。例如，包含标签“photography”、“portrait”和“faces”的项目。

我的一般方法是从每个标签顶点开始一个图遍历，并找到与该标签相关的项目。那部分工作正常。我得到一个项目清单。

但我任务的最后一部分是对所有列表进行交集，以便找到包含所有指定标签的项目。我无法弄清楚如何做到这一点。

我想做的是这样的：

let tagnames = SPLIT(@tagnames,',')
let tagcollections = (
    FOR tagname IN tagnames
    LET atag = (FOR t IN tags FILTER LOWER(t.text)==LOWER(tagname) RETURN t)
    let collections = (FOR v IN 1..1 INBOUND atag[0] Contains RETURN v)

    RETURN { tag: atag, collections: collections }
)

RETURN INTERSECTION(tagcollections)

但是，它不起作用：INTERSECTION 函数不适用于单个列表，而是适用于多个项目，例如：INTERSECTION(listA, listB, listC...)。

如何使 FOR .. RETURN 块中的列表相交？

4

3 回答 3

5

ArangoDB 3.0 引入了特殊的数组比较运算符( ANY, ALL, NONE)。ALL IN可用于测试左侧数组中的每个元素是否也在右侧数组中：

[ "red", "green", "blue" ] ALL IN [ "purple", "red", "blue", "green" ]
// true

请注意，这些运算符还不能使用索引。给定一个将标签直接嵌入到文档中的数据模型，一种解决方法是使用索引来查找包含一个标签的所有文档（例如，获取第一个元素，["red","green","blue"][0]）以减少结果集而无需完整的集合扫描，然后ALL IN如果其他标签也在列表中，则进行后过滤：

LET tagsToSearchFor = [ "red", "green", "blue" ]
FOR doc IN coll
  FILTER tagsToSearchFor[0] IN doc.tags[*] // array index
  FILTER tagsToSeachFor ALL IN doc.tags
  RETURN doc

ALL IN也可以用于带有单独标签集合的数据模型，但您将无法使用上述索引。例如：

FOR doc IN documents
    LET tags = (
        FOR v IN INBOUND doc contains
            RETURN v._key
    )
    FILTER ["red", "green", "blue"] ALL IN tags
    RETURN MERGE(doc, {tags})

或者，如果您想使用标签开始遍历并使用基于交集的方法：

LET startTags = ["red", "green", "blue"] // must exist
LET ids = (
    FOR startTag IN DOCUMENT("tags", startTags)
        RETURN (
            FOR v IN OUTBOUND startTag contains
                RETURN v._id
        )
)
LET docs = APPLY("INTERSECTION", ids)

FOR doc IN DOCUMENT(docs)
    RETURN MERGE(doc, {
        tags: (FOR tag IN INBOUND doc contains RETURN tag._key)

    })
于 2016-07-20T14:45:14.163 回答
3

我会考虑将您的标签作为属性存储在您的物品上。ArangoDB 2.8 包含完全针对您的场景的数组索引。从他们的博客文章中：

{ 
  text: "Here's what I want to retrieve...",
  tags: [ "graphdb", "ArangoDB", "multi-model" ]   
}

FOR doc IN documents 
  FILTER "graphdb" IN doc.tags[*] 
    RETURN doc

这应该更高效，并消除对上述 AQL 的需求，从而简化您的应用程序。

于 2016-02-26T22:40:02.870 回答
0

DISTINCT您可以确保在使用关键字的 AQL 查询结果中不会两次获取文档。

让我们使用 know graph 示例在图查询中证明这一点：

var examples = require("org/arangodb/graph-examples/example-graph.js");

var g = examples.loadGraph("knows_graph");
db._query("FOR oneGuy IN persons " +
  "FOR v IN 1..1 OUTBOUND oneGuy GRAPH 'knows_graph' RETURN v.name").toArray()
[ 
  "Charlie", 
  "Dave", 
  "Alice", 
  "Bob", 
  "Bob" 
]

我们看到您的情况，Bob 被退回两次。现在让我们添加 distinct 关键字：

db._query("FOR oneGuy IN persons " +
  "FOR v IN 1..1 OUTBOUND oneGuy GRAPH 'knows_graph' RETURN DISTINCT v.name"
  ).toArray()
[ 
  "Bob", 
  "Alice", 
  "Dave", 
  "Charlie" 
]
于 2016-03-29T09:33:13.563 回答