0

我为 Standard ML 编写了一个非常简单的 Emacs 模式：

;; sml syntax
(require 'generic-x)

(define-generic-mode
    'sml-mode                          ;; name of the mode
  '(("(*" . "*)"))                           ;; comments delimiter
  '("fun" "fn" "let" "val" "datatype" "type" "case" "of" "end" "structure" "struct" "signature" "sig")
  '(("=" . 'font-lock-builtin-face)
    ("|" . 'font-lock-builtin-face)
    (">" . 'font-lock-builtin-face)
    ("<" . 'font-lock-builtin-face)
    ("-" . 'font-lock-builtin-face)
    ("+" . 'font-lock-builtin-face)
    (";" . 'font-lock-builtin-face)
    ("," . 'font-lock-builtin-face)
    ("{" . 'font-lock-builtin-face)
    ("}" . 'font-lock-builtin-face)
    ("(" . 'font-lock-builtin-face)
    (")" . 'font-lock-builtin-face)
    (":" . 'font-lock-builtin-face)
    ("[" . 'font-lock-builtin-face)
    ("]" . 'font-lock-builtin-face))     ;; a built-in
  '("\\.sml$")                    ;; files that trigger this mode
  nil                              ;; any other functions to call
  "SML highlighting mode"     ;; doc string
  )

但是，它不会一致地缩进。我无法准确描述它是如何缩进的，但它在制表符和空格以及空格长度之间的切换不一致。我能想到的最简单的规则是始终在同一列上开始一个新行，并且制表符总是将您带到下一列是 4 的倍数。制表符应该是空格。如何使用通用模式执行此操作？

作为模式定义的注释，我错误地使用了内置面，因为操作员面没有着色。不过现在看起来确实很丑。

4

1 回答 1

1

首先要做的事情：我强烈建议您从开始define-derived-mode而不是从开始，define-generic-mode因为前者将无缝地增长以适应功能齐全的主要模式，而define-generic-mode会迅速施加不方便解决的限制。

例如，您可以将代码重写为：

(defvar sml-mode-syntax-table
  (let ((st (make-syntax-table)))
    ;; Make (*...*) a comment.
    (modify-syntax-entry ?\( "()1" st)
    (modify-syntax-entry ?\) ")(4" st)
    (modify-syntax-entry ?\* ". 23n" st)
    st))

(defvar sml-font-lock-keywords
  `((,(concat "\\_<" 
              (regexp-opt '("fun" "fn" "let" "val" "datatype" "type" "case" "of" "end" "structure" "struct" "signature" "sig"))
              "\\_>")
     (0 font-lock-keyword-face))
    ("[][=|><-+;,{}():]" (0 font-lock-builtin-face))))

;;;###autoload
(define-derived-mode sml-mode prog-mode "SML"
  "SML major mode."
  (set (make-local-variable 'comment-start) "(* ")
  (set (make-local-variable 'comment-end) " *)")
  (set (make-local-variable 'font-lock-defaults)
       '(sml-font-lock-keywords)))

;;;###autoload
(add-to-list 'auto-mode-alist '("\\.sml\\'" . sml-mode))

对于 TAB 和 SPC，“在它们之间切换”是 Emacs 的默认行为（态度是 TAB 只是我们在适用时使用的优​​化）。如果您不喜欢它，请(setq-default indent-tabs-mode nil)输入您的 ~/.emacs而不是您的主要模式的定义，因为这是与 SML 无关的个人选择（与 Haskell 之类的相反，它不区分 TAB 和 SPC）。

至于您建议的缩进，您可以从添加(set (make-local-variable 'indent-line-function) #'indent-relative)which 开始，以确保默认情况下缩进与上一行相同；并且对于“TAB 应该提前 4 列”，也许类似的东西(set (make-local-variable 'tab-stop-list '(4 8 12 16 20 24 28 32 36 40 44 48 52 56 60 64))可以解决问题（在最近的 Emacsen 中，'(4 8)就足够了，因为 Emacs 终于学会了“自动扩展列表”。

但我很好奇：为什么不直接使用sml-modeGNU ELPA 中的现有内容呢？

于 2016-02-25T13:37:47.197 回答