unit-testing - DUnitX 从字符串到整数数组的转换

Question

我的问题与此类似，但我想传递一个整数数组，而不是一个集合。

每个例子：

[TestCase('TestAdd','[1,2,3,4];[1,2,3,4]',';')]
procedure TestAdd(aValue, aResult: array of integer);

修改 DUnitX.Utils 似乎是最干净的方法，但我不确定如何进行转换。我的主要问题是，它怎么知道我需要一个整数数组？PTypeInfo 中有什么我可以利用的东西吗？

Answer 1

您不能使用开放数组，因为 RTTI 缺少使用此类参数调用方法的代码（实际上是由引擎盖下的两个参数实现的）。因此，您需要更改要使用的签名TArray<T>或任何其他动态数组类型。

然后对 DUnitX.Utils 的修改非常简单——只需将此函数添加到 tkUString->tkDynArray 的 Conversions 数组中（任何可能的优化都留给读者练习）：

function ConvStr2DynArray(const ASource: TValue; ATarget: PTypeInfo; out AResult: TValue): Boolean;
var
  s: string;
  values: TStringDynArray;
  i: Integer;
  p: Pointer;
  v1, v2: TValue;
  elType: PTypeInfo;
begin
  s := ASource.AsString;
  if StartsStr('[', s) and EndsStr(']', s) then
    s := Copy(s, 2, Length(s) - 2);
  values := SplitString(s, ',');
  i := Length(values);
  p := nil;
  DynArraySetLength(p, ATarget, 1, @i);
  TValue.MakeWithoutCopy(@p, ATarget, AResult);
  elType := ATarget.TypeData.DynArrElType^;
  for i := 0 to High(values) do
  begin
    v1 := TValue.FromString(values[i]);
    if not v1.TryConvert(elType, v2) then
      Exit(False);
    AResult.SetArrayElement(i, v2);
  end;
  Result := True;
end;