delphi - Delphi - 如何向 TDataModule 发送 Windows 消息？

Question

TDataModule我需要在我的 Delphi 2010 应用程序中向 a 发送一条 Windows 消息。

我想用

PostMessage(???.Handle, UM_LOG_ON_OFF, 0,0);

问题：

TDataModule没有Handle. _ 如何向它发送 Windows 消息？

Answer 1

你可以很容易地给它一个把手。AllocateHWND在 Classes 单元中查看。调用它为您的数据模块创建一个句柄，并定义一个简单的消息处理程序来处理 UM_LOG_ON_OFF。

Answer 2

这是一个示例，演示如何TDataModule使用Handle

uses
  Windows, Winapi.Messages,
  System.SysUtils, System.Classes;

const
  UM_TEST = WM_USER + 1;

type
  TMyDataModule = class(TDataModule)
  private
    FHandle: HWND;
  protected
    procedure   WndProc(var Message: TMessage); virtual;
  public
    constructor Create(AOwner : TComponent); override;
    destructor  Destroy(); override;
    property    Handle : HWND read FHandle;
  end;

...

uses
  Vcl.Dialogs;

constructor TMyDataModule.Create(AOwner : TComponent);
begin
  inherited;

  FHandle := AllocateHWND(WndProc);
end;

destructor  TMyDataModule.Destroy();
begin
  DeallocateHWND(FHandle);

  inherited;
end;

procedure   TMyDataModule.WndProc(var Message: TMessage);
begin
  if(Message.Msg = UM_TEST) then
  begin
    ShowMessage('Test');
  end;
end;

然后我们可以向数据模块发送消息，如下所示：

procedure TForm1.Button1Click(Sender: TObject);
begin
  PostMessage(MyDataModule.Handle, uMyDataModule.UM_TEST, 0, 0);
end;