35

在 Terraform 中，我正在尝试创建一个模块，其中包含一个带有变量键的地图。我不确定这是否可能，但我尝试了以下但没有成功。

resource "aws_instance" "web" {
    ami = "${var.base_ami}"
    availability_zone = "${var.region_a}"
    instance_type = "${var.ec2_instance_size}"
    security_groups = ["sec1"]
    count = "${var.ec2_instance_count}"
    tags {
        Name = "${var.role} ${var_env}"
        role = "${var.app_role}"
        ${var.app_role} = "${var_env}"
    }
}

还有这个：

tags {
   Name = "${var.role} ${var_env}"
}
tags."${var.role}" = "${var.env}"

有任何想法吗？目前这对 Terraform 是不可能的吗？

4

5 回答 5

38

terraform 插值语法中支持（现在）一个lookup函数，它允许您在地图中查找动态键。

使用它，我现在可以执行以下操作：

output "image_bucket_name" {
  value = "${lookup(var.image_bucket_names, var.environment, "No way this should happen")}"
}

在哪里：

variable "image_bucket_names" {
  type = "map"

  default = {
    development = "bucket-dev"
    staging = "bucket-for-staging"
    preprod = "bucket-name-for-preprod"
    production = "bucket-for-production"
  }

}

并且environment是一个简单的字符串变量。

于 2017-02-14T14:13:26.320 回答
16

更新

接受的答案描述了如何在现有地图中进行动态查找。对于使用动态键构建映射，在 HCL2 (0.12) 中，您可以在键中使用带引号的插值表达式：

resource "aws_instance" "web" {
  count = "${var.ec2_instance_count}"
  
  ami = "${var.base_ami}"
  availability_zone = "${var.region_a}"
  instance_type = "${var.ec2_instance_size}"
  security_groups = ["sec1"]

  tags = {
    Name              = "${var.role} ${var.env}"
    role              = "${var.app_role}"
    "${var.app_role}" = "${var.env}"               # <------ like this
  }
}

一旦问题 #21566得到修复，您可以替换"${var.app_role}"为(var.app_role)，这是文档中描述的方法。

（以下同样的警告也适用于此处：如果var.app_role包含这些文字键之一作为其值，则它将替换它。）

旧答案

接受的答案描述了如何在现有地图中进行动态查找。对于使用动态键构建映射，在 HCL2 (0.12) 中，您有两种方法：

对于表达式+merge

您可以使用for 表达式从您的键的一个或多个变量动态构建映射，然后将其与merge函数结合使用来构建具有静态和动态键组合的新映射：

variable "app_role" {
  type = string
}

locals {
  tags = merge(
    {
      Name = "${var.role} ${var.env}"
      role = "${var.app_role}"
    },
    {
      for k in [var.app_role]: k => "${var.env}"
    }
  )
}

zipmap

或者，您可以使用zipmap一次性构建它：

locals {
  tags = zipmap(
    [
       "Name",
       "role",
       var.app_role
    ],
    [
       "${var.role} ${var.env}",
       var.app_role,
       var.env
    ]
  )
}

然后，您可以在资源中使用此地图：

resource "aws_instance" "web" {
  count = "${var.ec2_instance_count}"
  
  ami = "${var.base_ami}"
  availability_zone = "${var.region_a}"
  instance_type = "${var.ec2_instance_size}"
  security_groups = ["sec1"]

  tags = local.tags // or inline the above here
}

一个警告是，如果var.app_role等于"Name"or "role"，那么它将覆盖您的静态值。merge您可以通过在 中交换参数或重新排序列表来避免这种情况zipmap，尽管这种冲突更可能是配置错误，应该在应用之前捕获并修复。

于 2019-08-07T20:16:52.090 回答
7

以下适用于 terraform 版本 0.11.7。此解决方案使用地图功能。

resource "aws_instance" "web" {
  ...
  tags = "${map(
    "Name", "${var.role} ${var_env}",
    "role", "${var.app_role}",
    "${var.app_role}", "${var_env}"
  )}"
}
于 2018-08-06T14:54:03.193 回答
6

我最近也需要动态设置标签键，并设法使用zipmap：

locals {
  ec2_tag_keys = ["some/prefix/${var.some_var}", "another_tag"]
  ec2_tag_vals = ["some value", "another value"]
}

resource "aws_instance", "foo" {
  ...
  tags = "${zipmap(local.ec2_tag_keys, local.ec2_tag_vals)}"
}

这有点笨拙，但它确实有效。

于 2017-09-12T02:04:16.463 回答
1

我不确定它是什么时候添加的，但至少从 0.11.7 版本开始，Terraform 支持使用变量作为映射键。这是我当前如何使用它来选择 AWS 实例类型的示例：

在.tf文件中：

variable "environment" {}

...

variable "instance_types_webserver" {
  type = "map"

  default = {
    testing    = "t2.small"
    qa         = "t2.medium"
    staging    = "t2.xlarge"
    production = "t2.xlarge"
  }
}

...

resource "aws_opsworks_instance" "verification" {
  stack_id      = "${aws_opsworks_stack.verification.id}"
  layer_ids     = ["${aws_opsworks_custom_layer.verification.id}"]
  instance_type = "${var.instance_types_webserver["${var.environment}"]}"
  state         = "running"
  count         = 1
}

在.tfvars文件中：

...
environment = "testing"
...
于 2018-06-06T13:23:40.963 回答