这种转变:
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output omit-xml-declaration="yes" indent="yes"/>
<xsl:key name="kwrkTimeByNameTask" match="workTime"
use="concat(../name, '+', @taskID)"/>
<xsl:key name="kDateByName" match="date"
use="../name"/>
<xsl:key name="kwrkTimeByNameTaskDate" match="workTime"
use="concat(../name, '+', @taskID, '+', ../date)"/>
<xsl:template match="/">
<xsl:for-each select=
"*/*/workTime
[generate-id()
=
generate-id(key('kwrkTimeByNameTask',
concat(../name, '+', @taskID)
)[1]
)
]
">
<xsl:sort select="../name"/>
<xsl:sort select="@taskID" data-type="number"/>
<xsl:variable name="vcurTaskId" select="@taskID"/>
<Person>
<name><xsl:value-of select="../name"/></name>
<taskID><xsl:value-of select="@taskID"/></taskID>
<xsl:for-each select=
"key('kDateByName', ../name)
[key('kwrkTimeByNameTaskDate',
concat(../name, '+', current()/@taskID, '+', .)
)
]
">
<workTime>
<date><xsl:value-of select="."/></date>
<time>
<xsl:value-of select=
"key('kwrkTimeByNameTaskDate',
concat(../name, '+', $vcurTaskId, '+', .)
)"/>
</time>
</workTime>
</xsl:for-each>
</Person>
</xsl:for-each>
</xsl:template>
</xsl:stylesheet>
当应用于提供的 XML 时(从多个问题更正为格式良好):
<t>
<Person>
<name>John</name>
<date>June12</date>
<workTime taskID="1">34</workTime>
<workTime taskID="1">35</workTime>
<workTime taskID="2">12</workTime>
</Person>
<Person>
<name>John</name>
<date>June13</date>
<workTime taskID="1">21</workTime>
<workTime taskID="2">11</workTime>
<workTime taskID="2">14</workTime>
</Person>
</t>
产生想要的正确结果:
<Person>
<name>John</name>
<taskID>1</taskID>
<workTime>
<date>June12</date>
<time>34</time>
</workTime>
<workTime>
<date>June13</date>
<time>21</time>
</workTime>
</Person>
<Person>
<name>John</name>
<taskID>2</taskID>
<workTime>
<date>June12</date>
<time>12</time>
</workTime>
<workTime>
<date>June13</date>
<time>11</time>
</workTime>
</Person>
说明:
首先,我们workTime
../name
@taskID
通过使用 Muenchian 方法进行分组,获得具有唯一对的所有元素。
我们按../name
和@taskID
- 按此顺序对它们进行排序。
对于每个这样,workTime
我们得到所有date
../name
与this一起列出的元素workTime
,只留下这些元素中的那些,对于这些date
元素,有一个workTime
具有相同的../date
和../name
。
在上一步中,我们使用了两个不同的辅助键:按它们索引所有'kDateByName'
元素,而按它们、它们和它们索引所有元素。date
../name
'kwrkTimeByNameTaskDate'
workTime
../name
../date
@taskID
所以,下面的意思:
<xsl:for-each select=
"key('kDateByName', ../name)
[key('kwrkTimeByNameTaskDate',
concat(../name, '+', current()/@taskID, '+', .)
)
]
">
是:
对于每一个 date
for that name
,这样 a for workTime
that name
和date
( of the current for the outer )存在,执行此指令正文中的任何内容。@taskID
workTime
<xsl:for-each>
<xsl:for-each>