0

我正在尝试将带有 uri 匹配器的 Grails 3.0.12 拦截器应用于 Spring Boot Actuator 提供的管理端点。我将执行器management.context_path属性设置为/admin。

UrlMappings.groovy 中映射的所有端点都被拦截，但由 Spring Boot Actuator 管理的端点没有。相反，我在日志中看到以下内容，表明拦截器被绕过：

DEBUG: org.springframework.boot.actuate.endpoint.mvc.EndpointHandlerMapping - Looking up handler method for path /admin/metrics
DEBUG: org.springframework.boot.actuate.endpoint.mvc.EndpointHandlerMapping - Returning handler method [public java.lang.Object org.springframework.boot.actuate.endpoint.mvc.EndpointMvcAdapter.invoke()]

这是我的拦截器：

class LoginInterceptor {

    def securityService

    int order = HIGHEST_PRECEDENCE

    LoginInterceptor() {
        match(uri: "/**")
    }

    boolean before() {
        if (!request.exception) {
            securityService.authenticateUser()
        }
        true
    }

    boolean after() { true }

    void afterView() { /* no-op */ }
}

这是 application.yml 中的管理配置

management:
  context_path: /admin

如何确保拦截执行器提供的端点？

4

1 回答 1

0

我确实找到了一种方法，方法是实现将 GrailsInterceptorHandlerInterceptorAdapter 设置为拦截器的 EndpointHandlerMappingCustomizer customize() 方法。

import org.grails.plugins.web.interceptors.GrailsInterceptorHandlerInterceptorAdapter
import org.springframework.boot.actuate.endpoint.mvc.EndpointHandlerMapping
import org.springframework.boot.actuate.endpoint.mvc.EndpointHandlerMappingCustomizer

class ActuatorInterceptor implements EndpointHandlerMappingCustomizer {
    GrailsInterceptorHandlerInterceptorAdapter interceptorAdapter

    @Override
    public void customize(EndpointHandlerMapping mapping) {
        Object[] interceptors = [ interceptorAdapter ]
        mapping.setInterceptors(interceptors)
    }
}

资源.groovy：

beans = {
    actuatorInterceptor(ActuatorInterceptor) {
        interceptorAdapter = ref('grailsInterceptorHandlerInterceptorAdapter')
    }
}

这不太理想，因为它特定于 Spring Boot Actuator，并且不适用于 Spring Cloud Config 端点。我希望看到一种更通用的方法来使用 Grails 拦截器拦截所有 URI 映射。

于 2016-02-02T05:17:45.470 回答