0

我有一个用 do 生成的合成器：

(
SynthDef(\siny, { arg freq, outBus=0; Out.ar( outBus, SinOsc.ar(freq!2,0,0.2) ) } ).send(s);
SynthDef(\filter, { arg cFreq,q=0.8, inBus; Out.ar( 0, BPF.ar(In.ar(inBus), cFreq!2, 1/q ) ) } ).send(s);

)

(
~sourceOut = Bus.audio(s);
~sine_Group = ParGroup.new;
z = [100,500,1000,1500,250];

{
z.do({ arg val; Synth.head(~sine_Group, \siny, [\freq: val, \outBus: ~sourceOut]) });
z.do({ arg val; Synth.after(~sine_Group, \filter, [\inBus: ~sourceOut, \cFreq: 200] ) });

}.play;
)

现在，我的理解是，多个 Synth\siny 实例的输出在总线 ~sourceOut 中混合，并作为输入到 synth\filter

我真正想做的是在 \siny 和 \filter 的多个实例之间建立一对一的连接。我可以使用一组总线来连接它们吗？如果是这样，我该怎么做？

4

1 回答 1

1

是的你可以。在这里，我对您的代码进行了最低限度的修改。首先，我制作~sourceOut了一组总线而不是单个总线。其次，在do循环内部，我利用了 SuperCollider 中的主要迭代函数可以提供第二个index参数以及每个项目本身的事实。第三，我使用该index参数来选择所需的总线：

(
z = [100,500,1000,1500,250];
~sourceOut = z.collect{ Bus.audio(s) };
~sine_Group = ParGroup.new;

{
z.do({ arg val, index; Synth.head(~sine_Group, \siny, [\freq: val, \outBus: ~sourceOut[index]]) });
z.do({ arg val, index; Synth.after(~sine_Group, \filter, [\inBus: ~sourceOut[index], \cFreq: 200] ) });

}.play;
)

根据您的需要，您可能还想查看NodeProxy哪些对原型设计和实时编码有用，并提供一些技巧用于将合成器的输出相互插入。

于 2016-01-30T09:20:10.407 回答