0

我正在尝试自定义我们的开发人员指南 pdf以使其首页看起来不错。我完全可以在 Photoshop 中将所有内容作为图像进行处理，因为 asciidoc 在这里的能力似乎非常有限。

不幸的是，尽管到处寻找，我似乎找不到一种方法来自定义封面或将其替换为适用于 asciidoctor-fopub 的图像。

烦人的是，这个用例在项目的自述文件中特别提到了https://github.com/asciidoctor/asciidoctor-fopub（在自定义 XSL 模板下），但除了“它在 XSL 中”。作为不熟悉 docbook 的人，我不知道从哪里开始。

asciidoctor-pdf有一个包含图像的标签，但它会在我们的文档上显示并生成垃圾（ToC 会覆盖所有内容）。

4

1 回答 1

2

这可以使用 build/fopub/docbook/fo/ 下的 division.xsl 文件来完成

搜索“占位符模板”

并将下面的代码粘贴到那里，您将能够在生成的 fopub 中看到封面图片

<!-- Placeholder templates -->
<xsl:template name="front.cover">
  <xsl:call-template name="page.sequence">
    <xsl:with-param name="master-reference">titlepage-cover-image</xsl:with-param>
    <xsl:with-param name="content">
      <fo:block text-align="center">
     <fo:external-graphic src="url(path/to/cover.png)" content-height="250mm" content-width="176mm"/>
      </fo:block>
    </xsl:with-param>
  </xsl:call-template>
</xsl:template>

根据您的书籍要求更改高度和宽度。

完成后，您需要为封面上的图像留出边距以保持清晰。在 pagesetup.xsl 中添加以下内容

<fo:simple-page-master master-name="titlepage-cover-image"
                           page-width="{$page.width}"
                           page-height="{$page.height}"
                           margin-top="{$title.page.margin.top}"
                           margin-bottom="{$page.margin.bottom}">
      <xsl:attribute name="margin-{$direction.align.start}">
        <xsl:value-of select="$page.margin.inner"/>
  <xsl:if test="$fop.extensions != 0">
    <xsl:value-of select="concat(' - (',$title.margin.left,')')"/>
        </xsl:if>
      </xsl:attribute>
      <xsl:attribute name="margin-{$direction.align.end}">
        <xsl:value-of select="$page.margin.outer"/>
      </xsl:attribute>
      <xsl:if test="$axf.extensions != 0">
        <xsl:call-template name="axf-page-master-properties">
          <xsl:with-param name="page.master">titlepage-cover-image</xsl:with-param>
        </xsl:call-template>
      </xsl:if>
      <fo:region-body margin-bottom="{$body.margin.bottom}"
                      margin-top="{$title.body.margin.top}"
                      column-gap="{$column.gap.titlepage}"
                      column-count="{$column.count.titlepage}">
        <xsl:attribute name="margin-{$direction.align.start}">
          <xsl:value-of select="$body.margin.inner"/>
        </xsl:attribute>
        <xsl:attribute name="margin-{$direction.align.end}">
          <xsl:value-of select="$body.margin.outer"/>
        </xsl:attribute>
      </fo:region-body>
      <fo:region-before region-name="xsl-region-before-first"
                        extent="{$region.before.extent}"
                        precedence="{$region.before.precedence}"
                        display-align="before"/>
      <fo:region-after region-name="xsl-region-after-first"
                       extent="{$region.after.extent}"
                        precedence="{$region.after.precedence}"
                        display-align="after"/>
      <xsl:call-template name="region.inner">
        <xsl:with-param name="sequence">first</xsl:with-param>
        <xsl:with-param name="pageclass">titlepage</xsl:with-param>
      </xsl:call-template>
      <xsl:call-template name="region.outer">
        <xsl:with-param name="sequence">first</xsl:with-param>
        <xsl:with-param name="pageclass">titlepage</xsl:with-param>
      </xsl:call-template>
    </fo:simple-page-master>

然后在 fo-pdf.xsl 中添加变量以将您的正文上边距归零。

HTH。

于 2016-01-22T18:36:50.817 回答