1

我正在尝试将 Matlab fmincon 优化函数转换为 julia。但没有太多的运气。

我认为可以使用 NLopt 或 IPopt。默认示例有效，但是当我尝试更改值时，它似乎没有迭代。

using NLopt
count = 0 # keep track of # function evaluations
function myfunc(x::Vector, grad::Vector)
    if length(grad) > 0
        grad[1] = 0
        grad[2] = 0.5/sqrt(x[2])
    end
    global count
    count::Int += 1
    println("f_$count($x)")

    sqrt(x[2])
end

function myconstraint(x::Vector, grad::Vector, a, b)
    if length(grad) > 0
        grad[1] = 3a * (a*x[1] + b)^2
        grad[2] = -1
    end
    (a*x[1] + b)^3 - x[2]
end

opt = Opt(:LD_MMA, 2)
lower_bounds!(opt, [-Inf, 0.])
xtol_rel!(opt,1e-4)

min_objective!(opt, myfunc)
inequality_constraint!(opt, (x,g) -> myconstraint(x,g,2,0), 1e-8)
inequality_constraint!(opt, (x,g) -> myconstraint(x,g,-1,1), 1e-8)

(minf,minx,ret) = optimize(opt, [1.234, 5.678])
println("got $minf at $minx after $count iterations (returned $ret)")

这个工作正常。它给出了 2 个结果和 11 次迭代

using NLopt
count = 0 # keep track of # function evaluations
function myfunc(x)
    x[1]^2 + 5*x[2] - 3
end
function myconstraint(x)
    100*x[1] + 2000*x[2] == 100
end

opt = Opt(:LD_MMA, 2)
lower_bounds!(opt, [0, 0])
upper_bounds!(opt,[10,5])
xtol_rel!(opt,1e-10)

min_objective!(opt, myfunc);
inequality_constraint!(opt, (x) -> myconstraint(x), 1e-10)

(minf,minx,ret) = optimize(opt, [0.1,0.1])

这不起作用，它只是给出一个结果和 0 次迭代

using NLopt
count = 0 # keep track of # function evaluations
function myfunc(x::Vector, grad::Vector)
    x[1]^2 + 5*x[2] - 3
end
function myconstraint(result::Vector, x::Vector, grad::Vector)
    100*x[1] + 2000*x[2] == 100
end

opt = Opt(:LD_MMA, 2)
lower_bounds!(opt, [0., 0.])
upper_bounds!(opt, [10.,5.])
xtol_rel!(opt,1e-4)

min_objective!(opt, myfunc)
inequality_constraint!(opt, (x,g) -> myconstraint(x), 1e-8)

(minf,minx,ret) = optimize(opt, [0., 0.])#even with [5.,10.]

这只是给了我一个结果和 0 次迭代。

有人知道我做错了什么吗？

4

1 回答 1

1

我很难根据评论马拉松重建你所做的事情，所以我想我只是提供代码来说明我将如何解决这个问题。请注意，以下代码假设您的不等式约束为100*x[1] + 2000*x[2] <= 100：

using NLopt
function myfunc(x::Vector{Float64}, grad::Vector{Float64})
    if length(grad) > 0
        grad[1] = 2 * x[1]
        grad[2] = 5
    end
    xOut = x[1]^2 + 5*x[2] - 3
    println("Obj func = " * string(xOut))
    return(xOut)
end
function myconstraint(x::Vector{Float64}, grad::Vector{Float64})
    if length(grad) > 0
        grad[1] = 100
        grad[2] = 2000
    end
    xOut = 100*x[1] + 2000*x[2] - 100
    println("Constraint val = " * string(xOut))
    return(xOut)
end
opt = Opt(:LD_MMA, 2)
lower_bounds!(opt, [0, 0])
upper_bounds!(opt,[10,5])
xtol_rel!(opt,1e-10)
min_objective!(opt, myfunc);
inequality_constraint!(opt, myconstraint, 1e-10)

(minf,minx,ret) = optimize(opt, [0.1,0.1])

我的代码和你的代码有三个主要区别：

  1. 我已经明确包含了梯度函数更新。这将使任何基于梯度的算法（MMA 是其中之一）的收敛程序更有效。

  2. 我在每一步都打印出我的目标函数和约束函数的值。这对于调试目的很有用，并有助于了解幕后发生的事情。

  3. 我在我的代码中已经非常清楚地表明我的约束函数的返回值是f(x)，其中约束由方程式定义f(x) <= 0。这是与 一起使用的适当语法NLopt。

您在评论中指出，当您尝试更改inequality_constraint!为equality_constraint!. 这是因为您选择的算法 (MMA) 仅支持不等式约束。NLopt可以在此处找到对算法的描述。笔记：

只有 MMA 和 SLSQP 支持任意非线性不等式约束，并且只有 SLSQP 支持非线性等式约束

因此，将您的算法切换为:LD_SLSQP，瞧，您现在可以将您的不等式约束切换为等式约束。

于 2016-01-26T22:49:44.007 回答