4

我编写了以下程序，我很困惑为什么当我编译程序时我收到一个错误，说 A-COL(1,1) 不是数值，而显示 A-COL(1,1) 给我 1。

   IDENTIFICATION DIVISION.
   PROGRAM-ID. TEST1.
   DATA DIVISION.
   WORKING-STORAGE SECTION.
   01 DIFF PIC 9(3).
       01 ARRAY.
           05 A-ROW OCCURS 99 TIMES.
               10 A-COL OCCURS 2 TIMES.
                   15 TABLE-CONTENT PIC 9(3).

   PROCEDURE DIVISION.
       MOVE 1 TO A-COL(1,1).
       MOVE 2 TO A-COL(2,1).
       DISPLAY A-COL(1,1).
       COMPUTE DIFF = A-COL(1,1) - A-COL(2,1).
       DISPLAY DIFF.
   STOP RUN.
4

2 回答 2

5

将 A-COL 定义更改为

"10 A-COL PIC 9(3) OCCURS 2 TIMES."

并删除TABLE-CONTENT.

组变量被认为是字母数字（X 类型），因此不能用于计算。

或者，您也可以这样做 - 使用实际数字字段引用地址位置。

PROCEDURE DIVISION.
   MOVE 1 TO TABLE-CONTENT(1,1).
   MOVE 2 TO TABLE-CONTENT(2,1).
   DISPLAY A-COL(1,1).
   COMPUTE DIFF = TABLE-CONTENT(1,1) - TABLE-CONTENT(2,1).
   DISPLAY DIFF.

你也可能想要DIFF签名。

附加信息

A-COL(1,1)显示“1”，因为它将数据存储为“1xx”，其中 x = 空间。那不是一个数值。当您在此处运行解决方案时，您会注意到显示行产生“001”。

于 2016-01-17T13:03:04.587 回答
2

保持您的工作存储结构相同。但是，您的数据元素不是 A-COL，而是 THE-CONTENT。所以使用THE-CONTENT，而不是A-COL。

   IDENTIFICATION DIVISION.
   PROGRAM-ID. TEST1.
   DATA DIVISION.
   WORKING-STORAGE SECTION.
   01  DIFF PIC S9(3).
   01  ARRAY.
       05  A-ROW 
           OCCURS 99 TIMES.
           10  A-COL 
               OCCURS 2 TIMES.
               15 TABLE-CONTENT            PIC 9(3).

   PROCEDURE DIVISION.
       MOVE 1                       TO TABLE-CONTENT ( 1 1 )
       MOVE 2                       TO TABLE-CONTENT ( 2 1 )
       DISPLAY 
               ">"
               TABLE-CONTENT ( 1 1 )
               "<"
       COMPUTE DIFF                 = TABLE-CONTENT ( 1 1 ) 
                                    - TABLE-CONTENT ( 2 1 )
       DISPLAY 
               ">"
               DIFF
               "<"
       STOP RUN
       .

你的结构更好，因为它更容易维护。如果你想重新定义表内容，你可以在不改变结构的情况下。如果您现在将结构“复杂化”，则不是这样。

是的，如果您将数字文字移动到组项，则执行字母数字 MOVE，结果将是您的文字左对齐并向右填充空格，或向右截断，或恰到好处，取决于文字的大小。

尽管从概念上讲，您的表中有“列”（COBOL 没有数组，但它有带有 OCCURS 的表），但请注意，您无法访问整个列。在存储中，您有 row-1-col-1、row-1-col-2、row-2-col-1、row-2-col-2 到 row-99-col-1、row-99-col -2。

任何算术（ADD、SUBTRACT、MULTIPLY、DIVIDE 和 COMPUTE）只能使用数字字段或文字作为源数据。一个字段包含“一个数字”是不够的，它必须是一个数字字段。

GIVING（ADD、SUBTRACT、MULTIPLY 和 DIVIDE）可以将结果放在特定类型的非数字字段中，即数字编辑字段中。这是一个带有 PICture 子句的字段，其中包含数字编辑 PICture 符号。

于 2016-01-17T20:16:30.500 回答