0

对于我的项目，我需要对一组我想知道 GPS 坐标的位置进行地理编码。

手动操作的位置数量太大，但不会太多，这样我就不会遇到谷歌对使用地理编码 API 的限制的问题。

对我来说最方便的方法是使用 OpenOffice Calc。

我找到了一个VBA 代码，它可以满足我的需要：

Function GetGeoData(sSearch as String) as String
   If Len(sSearch) = 0 Then Exit Function 'we dont need empty cells <img draggable="false" class="emoji" alt="" src="http://s.w.org/images/core/emoji/72x72/1f609.png">
   URL = "http://maps.googleapis.com/maps/api/geocode/xml?sensor=true&address="  'we will use the google maps api
   URL = URL & sSearch          'create the searchstring
   oSimpleFileAccess = createUnoService( "com.sun.star.ucb.SimpleFileAccess" ) 'this is the Sefvice in getting the data from the web
   On Error GoTo ErrorResponse
   oInputStream = oSimpleFileAccess.openFileRead(URL) 'use the URL
   oTextStream = createUnoService("com.sun.star.io.TextInputStream") 'get the data from the web
   oTextStream.InputStream = oInputStream 'this is the data
   aDelimiters = Array(ASC(">"),ASC("<")) 'as the stream is segmented with ">" and "<"
   sLastString = ""
   Do While NOT oTextStream.isEOF 'go through the google output
      sThisString = oTextStream.readString(aDelimiters,True) 
      Select Case sLastString 'now search for the entries
         Case "lat": 'latitudes
            sLat = sThisString  
            Case "lng": 'longitude
            sLon = sThisString
      End Select
      sLastString = sThisString
   Loop
   GetGeoData =  " Longitude: " & sLon & " Latitude: " &sLat 'this is our output in  the new cell
   oInputStream.closeInput()
   Exit Function
   ErrorResponse:
   GetGeoData = "no values found!!!"
End Function

然而，虽然对于确切的地址来说很好，但当涉及到谷歌称为多边形的定居点时，就会出现问题。在这种情况下，代码只保留它在 xml 信息中找到的最后一组坐标，但这对应于多边形的东北角。我很高兴拥有多边形的中心，它对应于谷歌地图生成的 xml 文档中的第一组坐标。

  • 谁能向我解释如何根据此代码在 xml 文件中选择特定节点？
  • 另一种解决方案是只保留第一组坐标。
4

2 回答 2

2

起初：永远不要XML只作为文本字符串。XML具有需要解析的有意义的数据结构。幸运的是，Openoffice APIXML已经提供了解析器。com.sun.star.xml.dom.DocumentBuilder https://www.openoffice.org/api/docs/common/ref/com/sun/star/xml/dom/DocumentBuilder.html

对你的问题：每个result都有geometry一个location。其中lat,lng将location是近似lat的lng或几何中心。另一个lat是lng视口或边界。

例如德国柏林：

  <geometry>
   <location>
    <lat>52.5200066</lat>
    <lng>13.4049540</lng>
   </location>
   <location_type>APPROXIMATE</location_type>
   <viewport>
    <southwest>
     <lat>52.3396296</lat>
     <lng>13.0891553</lng>
    </southwest>
    <northeast>
     <lat>52.6754542</lat>
     <lng>13.7611176</lng>
    </northeast>
   </viewport>
   <bounds>
    <southwest>
     <lat>52.3396296</lat>
     <lng>13.0891553</lng>
    </southwest>
    <northeast>
     <lat>52.6754542</lat>
     <lng>13.7611176</lng>
    </northeast>
   </bounds>
  </geometry>

所以只需要lat, lngfrom location。

但也有其他问题。如果有多个结果怎么办？例如，柏林不仅是德国的首都。

所以我的示例函数返回所有结果：

Function GetGeoData(sSearch as String) as String

 sResult = ""

 if len(sSearch) > 0 and sSearch <> "0" then

  sURI = "http://maps.googleapis.com/maps/api/geocode/xml?sensor=true&address="
  sURI = sURI & sSearch
  oDocumentBuilder = createUnoService("com.sun.star.xml.dom.DocumentBuilder")
  oDOMDocument = oDocumentBuilder.parseURI(sURI)

  oResults = oDOMDocument.getElementsByTagName("result")

  for i = 0 to oResults.length -1
   oResult = oResults.item(i)
   oformattedAddress = oResult.getElementsByTagName("formatted_address").item(0)
   sformattedAddress = oformattedAddress.getFirstChild().nodeValue

   oGeometry = oResult.getElementsByTagName("geometry").item(0)
   oLocation = oGeometry.getElementsByTagName("location").item(0)
   oLat = oLocation.getElementsByTagName("lat").item(0)
   sLat = oLat.getFirstChild().nodeValue
   oLng = oLocation.getElementsByTagName("lng").item(0)
   sLng = oLng.getFirstChild().nodeValue

   if i = 0 then 
    sResult = sResult & sformattedAddress & ": Lat:" & sLat & " Lng:" & sLng
   else
    sResult = sResult & "; " & sformattedAddress & ": Lat:" & sLat & " Lng:" & sLng    
   end if   

  next

 end if

 GetGeoData = sResult

End Function
于 2016-01-15T14:25:09.677 回答
0

听起来您正在寻找比在标签中匹配“<”和“>”更强大的东西。这在使用 XML 时经常发生，并且有许多专门的库来完成这项任务。

解析 XML 可以在 OpenOffice Basic 中使用 com.sun.star.xml.sax.Parser 接口完成。有关详细信息，请参阅https://wiki.openoffice.org/wiki/XML_and_Filter。

或者，许多语言都有 XML 解析库。Java 和 Python 具有 XML 解析库，也可以与 OpenOffice 一起使用。我个人在 OpenOffice 中使用最多的库是xml.dom.minidom。

于 2016-01-15T01:26:54.633 回答